;=================
;    PAS.MOD5     
; VERSION  C-128  
;                 
;GRAFIKPROZEDUREN 
;UND -FUNKTIONEN  
;=================
;                 
;25.9.1986        
;U1: 1.7.1989     
;                 
IMP PAS.SYST      
IMP PAS.MOD1      
IMP PAS.MOD3      
;(GETSTR)         
IMP PAS.MOD4      
;(NUR ENDMOD4)    
;                 
;=================
;                 
ORG ENDMOD4       
;                 
;=================
XSCOLOR  EQU $9E40
XAKTPOS  EQU $9DF2
XPAINT   EQU $61D6
XBOX     EQU $62D0
XCIRCLE1 EQU $66DA
XCIRCLE2 EQU $671F
XCHAR    EQU $682D
XDRAW    EQU $9B30
XCOLOR   EQU $69EE
XSCNCLR1 EQU $6A7B
XSCNCLR2 EQU $6A92
XWIDTH   EQU $71B9
XGETSIZE EQU $FFED
XSWAP    EQU $FF5F
XTEMPO   EQU $6FDA
XVOL     EQU $71C8
XPLAY    EQU $6DE9
XSOUND   EQU $726B
XFILTER  EQU $70B2
XENV1    EQU $70C4
XENV2    EQU $70E8
XENV3    EQU $7103
XENV4    EQU $7124
XENV5    EQU $713B
XENV6    EQU $714E
;                 
CHRGOT   EQU $386 
SNDTAB   EQU $1220
FILTAB   EQU $1234
;                 
<POINTER EQU $24  
<GRFPAG  EQU $76  
<TEMP    EQU $77  
<PAINTF  EQU $8B  
<COLORR  EQU $83  
;                 
<XWLO    EQU $E6  
<YWLO    EQU $E5  
<XWRU    EQU $E7  
<YWRU    EQU $E4  
;=================
EXT               
;ERWEITERTE       
;STANDARDPROZ.    
;AUFRUFEN         
JSR PASFET        
ASL               
TAX               
LDA EXTTAB+1,X    
PHA               
LDA EXTTAB,X      
PHA               
INC <P            
BNE EXT1          
INC <P+1          
EXT1 RTS          
;                 
EXTTAB            
DFD GRAPHIC-1; 0  
DFD PAINT-1;   1  
DFD DISPLAY-1; 2  
DFD BOX-1;     3  
DFD CIRCLE-1;  4  
DFD DRAWTO-1;  5  
DFD LOCATE-1;  6  
DFD COLOR-1;   7  
DFD SCNCLR-1;  8  
DFD WINDOW-1;  9  
DFD WIDTH-1;   10 
DFD SOUND-1;   11 
DFD VOL-1;     12 
DFD FILTER-1;  13 
DFD PLAY-1;    14 
DFD TEMPO-1;   15 
DFD ENVELOPE-1;16 
;-----------------
UCOLOR            
;FARBE LESEN; Y:=4
LDY #2            
LDA (<T),Y        
TAX               
STA LCRD          
JSR XSCOLOR       
STA LCRB          
LDY #4            
;- - - - - - - - -
CHKPAGE           
;PRUEFE AUF PAGE  
LDA <GRFPAG       
BEQ PAGERR        
RTS               
PAGERR LDX #$23   
JMP BASERR        
;-----------------
UGETXY            
;X/Y-KOORDINATEN  
;AB (<T),Y NACH   
;$1131,X          
JSR UGETINT       
;- - - - - - - - -
UGETINT           
;L/H AB (<T),Y    
;NACH $1131,X     
LDA (<T),Y        
JSR UGRFSTA       
INY               
INX               
LDA (<T),Y        
JSR UGRFSTA       
INY               
INX               
RTS               
;-----------------
UCALLAXY          
;AUFRUF DER ROM-  
;ROUTINE (A/X) MIT
;X:=(<T),Y        
STX <TP           
PHA               
LDA (<T),Y        
TAX               
LDY <TP           
PLA               
JMP UCALLAY       
;-----------------
USETSTR           
;STRINGZEIGER     
;FUER BASIC SETZEN
JSR GETSTR        
STA <POINTER      
STX <POINTER+1    
LDA (<POINTER),Y  
INC <POINTER      
BNE SETSTR1       
INC <POINTER+1    
SETSTR1 RTS       
;=================
AKT               
;HOLE POSITION DES
;PIXELCURSORS ALS 
;X/Y AUF DEN STACK
;                 
LDA #[(GRFTAB-2)  
STA FETVEC        
LDA #](GRFTAB-2)  
STA FETVEC+1      
LDX #<BANK0       
LDY #2            
;                 
AKT1 JSR FETCH    
STA (<T),Y        
INY               
CPY #6            
BNE AKT1          
JSR AL4           
JMP NEXT0         
;-----------------
PAINT             
;FARBE,X,Y,MODUS  
LDA #248          
JSR POPA;  8 BYTES
JSR UCOLOR        
LDX #4            
JSR UGETXY        
;MERKE POSITION   
LDA #[XAKTPOS     
LDY #]XAKTPOS     
JSR UCALLAY       
;                 
LDY #8            
LDA (<T),Y        
LSR               
ROR               
STA <PAINTF       
BPL PAINT1        
LDA <COLORR       
BEQ PAINTX        
PAINT1            
;*SCRATCH-AREA    
;*ZWISCHEN <B1 UND
;*<TOP FUER PAINT 
CLC               
LDA <T            
ADC #2            
STA <B1           
LDA <T+1          
ADC #0            
STA <B1+1         
;** STOP-TASTE    
;** SPERREN       
LDA STOPVEC       
PHA               
LDA STOPVEC+1     
PHA               
LDA #[MAKENE      
LDY #]MAKENE      
STA STOPVEC       
STY STOPVEC+1     
;                 
LDA #[XPAINT      
STA <FARPC+1; L   
LDA #]XPAINT      
STA <FARPC;   H   
LDA #14           
STA <FARCNF;  !   
STA LCRD          
JSR JSRFAR        
STA LCRB          
PLA               
STA STOPVEC+1     
PLA               
STA STOPVEC       
;                 
PAINTX JMP NEXT0  
;-----------------
DISPLAY           
;FARBE,X,Y,STRING,
;MODUS            
LDA (<T),Y        
ROR               
ROR               
LDX #12           
JSR UGRFSTA       
;-> $113D         
JSR POP2          
JSR USETSTR       
;(ADRESSE NOCH DA)
LDX #61           
JSR UGRFSTA       
;(LAENGE)         
DISP0             
LDA #248          
JSR POPA;  8 BYTES
;                 
LDY #2            
LDA (<T),Y        
TAX               
STA LCRD          
JSR XSCOLOR       
STA LCRB          
;(KEIN TEST AUF   
; GRAPHIC-AREA)   
LDX #$29          
LDY #$1A          
LDA <HIRES        
BNE DISP1         
STA LCRD          
JSR XGETSIZE      
STA LCRB          
INY               
INX               
DISP1             
STX <TP           
STY <TP+1         
LDY #4            
LDA (<T),Y        
CMP <TP           
BCS ILL.QU0       
LDX #$2D          
JSR UGRFSTA       
LDY #6            
LDA (<T),Y        
CMP <TP+1         
BCS ILL.QU0       
LDX #$2E          
JSR UGRFSTA       
LDA #[XCHAR       
LDY #]XCHAR       
JSR UCALLAY       
JMP NEXT0         
;-----------------
ILL.QU0 JMP ILL.QU
;-----------------
BOX               
;FARBE,X1,Y1,X2,Y2
;WINKEL,AUSMAL    
LDA #242          
JSR POPA; 14 BYTES
JSR UCOLOR        
LDX #$1F          
JSR UGETXY        
LDX #$2B          
JSR UGETXY        
LDX #$23          
JSR UGETINT       
LDA #[XBOX        
LDX #]XBOX        
JSR UCALLAXY      
JMP NEXT0         
;-----------------
CIRCLE            
;(0 -> YR DA)     
;(1 -> WAEHLE YR  
; FUER RUND)      
;FARBE,X,Y,XR,YR, 
;VON,BIS,WINKEL,  
;SCHRITT          
JSR PASFET        
PHA               
;                 
LDA #238          
JSR POPA; 18 BYTES
JSR UCOLOR        
LDX #$1F          
JSR UGETXY        
;LDX #$21         
JSR UGETINT       
PLA               
BEQ CIRCLE1       
;********* OHNE YR
LDY #8            
LDA (<T),Y        
INY               
INY               
STA (<T),Y        
DEY               
LDA (<T),Y        
INY               
BIT <HIRES        
BPL CIRCLE0       
PHA               
LDA (<T),Y        
ASL               
STA (<T),Y        
PLA               
ROL               
CIRCLE0 INY       
STA (<T),Y        
DEY               
;                 
CIRCLE1           
;(Y=10, X=$23)    
JSR UGETINT       
; HOLE 'VON'      
LDX #$2B          
JSR UGETINT       
; HOLE 'BIS'      
;LDX #$2D         
JSR UGETINT       
;                 
LDA #[XCIRCLE1    
STA <FARPC+1;    L
LDA #]XCIRCLE1    
STA <FARPC;      H
LDA (<T),Y        
STA <TEMP         
INY               
LDA (<T),Y        
LDY <TEMP         
;Y/A=WINKEL (L/H) 
JSR UFORCE        
;HOLE SCHRITT:    
LDY #18           
LDA #[XCIRCLE2    
LDX #]XCIRCLE2    
JSR UCALLAXY      
JMP NEXT1         
;-----------------
UFORCE            
;AUFRUF <FARPC    
;MIT A,X,Y        
;MANIPULIERE      
;CHRGOT ZUR RUECK-
;KEHR:            
STX <TP+1         
STY <TP+2         
;                 
TSX               
STX <TP           
PHA               
LDX #5            
FORCE1            
LDA NEWGOT,X      
STA CHRGOT,X      
DEX               
BPL FORCE1        
;                 
PLA               
LDX <TP+1         
LDY <TP+2         
JSR UCALLF        
;<----            
FORCE2            
;RESTAURIEREN     
LDX <TP           
TXS               
LDX #5            
FORCE3            
LDA OLDGOT,X      
STA CHRGOT,X      
DEX               
BPL FORCE3        
RTS               
;-----------------
NEWGOT            
STA LCRB          
JMP FORCE2        
OLDGOT            
DFD $8D,$01,$FF   
DFD $A0,$00,$B1   
;-----------------
DRAWTO            
;FARBE,X,Y        
LDA #250          
JSR POPA;  6 BYTES
JSR UCOLOR        
LDX #4            
JSR UGETXY        
LDA #[XDRAW       
LDY #]XDRAW       
JSR UCALLAY       
JMP NEXT0         
;-----------------
LOCATE            
;X,Y              
LDA #252          
JSR POPA;  4 BYTES
JSR CHKPAGE       
LDY #2            
LDX #4            
JSR UGETXY        
LDA #[XAKTPOS     
LDY #]XAKTPOS     
JSR UCALLAY       
JMP NEXT0         
;-----------------
COLOR             
;REGISTER,FARBE   
LDA #252          
JSR POPA;  4 BYTES
LDY #2            
LDA (<T),Y        
CMP #7            
BCS ILL.QU1       
STA <TEMP         
;                 
LDA #[XCOLOR      
STA <FARPC+1;    L
LDA #]XCOLOR      
STA <FARPC;      H
;                 
LDY #4            
LDA (<T),Y        
TAX               
JSR UFORCE        
JMP NEXT0         
;-----------------
SCNCLR            
;MODUS            
;(<0 -> AKT. BILD)
JSR POP2          
LDY #3            
; U1: <T NICHT <TP
LDA (<T),Y        
BNE SCNCLR1       
LDY #2            
LDA #[XSCNCLR2    
LDX #]XSCNCLR2    
JSR UCALLAXY      
JMP NEXT0         
;<---VON GRAPHIC  
SCNCLR1           
;AKTUELLEN SCHIRM 
LDA #[XSCNCLR1    
LDY #]XSCNCLR1    
JSR UCALLAY       
JMP NEXT0         
;-----------------
GRAPHIC           
;MODUS,LOESCH,TEXT
LDA #250          
JSR POPA;  6 BYTES
LDY #2            
LDA (<T),Y        
TAX               
CPX #5            
BEQ GRAPHIC4      
ILL.QU1 BCS ILL.QU
LDA GRF,X         
STA <HIRES        
BEQ GRAPHIC1      
;#################
;LDA #[BASMOVE    
;LDY #]BASMOVE    
;JSR UCALLAY      
;<P IST BEIM      
;PROGRAMMSTART    
;BEREITS OK       
;#################
BIT <HIRES        
BVC GRAPHIC3      
GRAPHIC1          
BIT <M4080        
BPL GRAPHIC3      
;                 
GRAPHIC2          
LDA #[XSWAP       
LDY #]XSWAP       
JSR UCALLAY       
GRAPHIC3          
;****$A34 AENDERN:
LDA #<TP          
STA STAVEC        
LDA #$34          
STA <TP           
LDA #$0A          
STA <TP+1         
LDY #6            
LDA (<T),Y        
CMP #$1A          
BCS ILL.QU        
ASL               
ASL               
ASL               
ADC #$30          
LDX #<BANK0       
JSR STASH         
;                 
LDY #4            
LDA (<T),Y        
CMP #2            
BCS ILL.QU        
TAY               
BNE SCNCLR1       
JMP NEXT0         
;                 
GRAPHIC4          
BIT <M4080        
BMI GRAPHIC3      
LDA <HIRES        
AND #$BF          
STA <HIRES        
JMP GRAPHIC2      
;                 
GRF               
DFD 0,$20,$60     
DFD $A0,$E0       
;-----------------
ILL.QU LDX #$E    
JMP BASERR        
;-----------------
WIDTH             
;BREITE           
LDA #[XWIDTH      
LDX #]XWIDTH      
BNE TEMPO1        
;-----------------
TEMPO             
;                 
LDA #[XTEMPO      
LDX #]XTEMPO      
TEMPO1            
JSR UCALLAXY      
TEMPO2 JSR POP2   
JMP NEXT0         
;-----------------
VOL               
;                 
LDA #[XVOL        
LDX #]XVOL        
BNE TEMPO1        
;=================
CHK1BYT           
JSR POPA          
LDY #2            
;- - - - - - - - -
CHKBYT            
;WERT 0..X-1 ->X  
STX <B1           
LDA (<T),Y        
TAX               
CMP <B1           
BCS ILL.QU        
INY               
LDA (<T),Y        
BNE ILL.QU        
INY               
RTS               
;-----------------
USETSND           
LDA #[SNDTAB      
STA UGRFSTA+4     
LDA #]SNDTAB      
STA UGRFSTA+5     
RTS               
;-----------------
URESSND           
LDA #[GRFTAB      
STA UGRFSTA+4     
LDA #]GRFTAB      
STA UGRFSTA+5     
RTS               
;=================
WINDOW            
;XLO,YLO,XRU,YRU, 
;LOESCH           
LDA #246; 10 BYTES
LDX #40           
BIT <M4080        
BPL WIND1         
LDX #80           
WIND1 JSR CHK1BYT 
STX <XWLO         
LDX #25           
JSR CHKBYT        
STX <YWLO         
LDX #40           
BIT <M4080        
BPL WIND2         
LDX #80           
WIND2 JSR CHKBYT  
CPX <XWLO         
BCC ILL.QU        
STX <XWRU         
LDX #25           
JSR CHKBYT        
CPX <YWLO         
BCC ILL.QU        
STX <YWRU         
LDX #2            
JSR CHKBYT        
LDA #$13;     HOME
CPX #0            
BEQ WIND3         
LDA #$93;      CLR
WIND3 JSR XBSOUT  
JMP NEXT0         
;-----------------
PLAY              
;                 
JSR USETSTR       
;(ADRESSE NOCH DA)
STA <TEMP         
;(LAENGE)         
LDA #[XPLAY       
LDY #]XPLAY       
JSR UCALLAY       
JMP TEMPO2        
;-----------------
FILTER            
;FREQUENZ,TIEFP.  
;BANDP.,HOCHP.,   
;RESONANZ         
;                 
LDA #<TP+4        
STA FETVEC        
LDA #[FILTAB      
STA <TP+4         
LDA #]FILTAB      
STA <TP+5         
;** ALTE FILTER-  
;** WERTE LADEN:  
LDY #3            
FIL1 LDX #<BANK0  
JSR FETCH         
DFD $99,<TP,0     
;STA <TP,Y        
DEY               
BPL FIL1          
;                 
LDA #246          
JSR POPA; 10 BYTES
LDY #3            
LDA (<T),Y        
CMP #8            
BCS FIL2          
;                 
PHA               
DEY               
LDA (<T),Y        
STA <TP           
STA <TP+1         
PLA               
LSR               
ROR <TP+1         
LSR               
ROR <TP+1         
LSR               
ROR <TP+1         
;                 
FIL2              
LDA #%10000       
STA <TP+4         
LDY #5            
;                 
FIL3 LDA (<T),Y   
BMI FIL6          
DEY               
LDA (<T),Y        
INY               
CMP #1            
BCC FIL4          
BEQ FIL4          
BNE ILL.QU3       
FIL4 LDA <TP+3    
ORA <TP+4         
BCS FIL5          
EOR <TP+4         
FIL5 STA <TP+3    
;                 
FIL6 INY          
INY               
ASL <TP+4         
BPL FIL3          
;                 
;(Y=11,RESONANZ)  
LDA (<T),Y        
BMI FIL9          
DEY               
LDX #$10          
JSR CHKBYT        
TXA               
ASL               
ASL               
ASL               
ASL               
STA <TP+4         
LDA <TP+2         
AND #15           
ORA <TP+4         
STA <TP+2         
;                 
FIL9              
LDA #[XFILTER     
LDY #]XFILTER     
JSR UCALLAY       
JMP NEXT0         
;-----------------
ILL.QU3 JMP ILL.QU
;-----------------
ENVELOPE          
;NUMMER,ANSCHLAG, 
;ABSCHWELL,HALTE, 
;AUSKLING,WELLE,  
;IMPULSBREITE     
;                 
LDA #242          
JSR POPA; 14 BYTES
LDY #2            
STY <TP+4         
LDA #[XENV1       
LDY #]XENV1       
JSR NIBBLE        
;                 
LDA #[XENV2       
LDY #]XENV2       
JSR NIBBLE        
;                 
LDA #[XENV3       
LDY #]XENV3       
JSR NIBBLE        
;                 
LDA #[XENV2       
LDY #]XENV2       
JSR NIBBLE        
;                 
LDA #[XENV3       
LDY #]XENV3       
JSR NIBBLE        
;                 
LDA #[XENV4       
LDY #]XENV4       
JSR NIBBLE        
;                 
LDY #15           
LDA (<T),Y        
BMI ENV8          
;                 
PHA               
DEY               
LDA #[XENV5       
STA <FARPC+1;    L
LDA #]XENV5       
STA <FARPC;      H
LDA (<T),Y        
TAY               
PLA               
JSR UCALLF        
JMP NEXT0         
;                 
ENV8              
LDA #[XENV6       
LDY #]XENV6       
JSR UCALLAY       
JMP NEXT0         
;=================
NIBBLE            
;1 NIBBLE MIT     
;FORCE UEBERGEBEN 
STA <FARPC+1;    L
STY <FARPC;      H
LDY <TP+4         
LDA (<T),Y        
CMP #16           
BCS ILL.QU3       
TAX               
INY               
;                 
CLC               
LDA (<T),Y        
BNE NIBBLE1       
SEC               
NIBBLE1           
PHP               
PLA               
STA <FARST        
INY               
STY <TP+4         
;(X=NIBBLE,C=1/0) 
JMP UFORCE        
;-----------------
SOUND             
;STIMME,FREQUENZ, 
;DAUER,RICHTUNG,  
;MAXFREQ,STUFE,   
;WELLE,IMP.BREITE 
JSR USETSND       
;                 
LDX #4            
LDA #240; 16 BYTES
JSR CHK1BYT       
DEX               
TXA               
LDX #$61          
JSR UGRFSTA       
;(Y=4,FREQ.)      
LDX #$85          
JSR UGETINT       
LDY #4            
LDX #$8C          
JSR UGETINT       
;(Y=6,DAUER)      
LDX #$83          
JSR UGETINT       
;(Y=8,RICHTUNG)   
LDX #3            
JSR CHKBYT        
TXA               
LDX #$89          
JSR UGRFSTA       
AND #1            
BEQ SOUND1        
;*ABNEHMENDE:     
;*STUFE:=-STUFE   
LDY #12           
SEC               
LDA #0            
SBC (<T),Y        
STA (<T),Y        
INY               
LDA #0            
SBC (<T),Y        
STA (<T),Y        
;                 
SOUND1            
LDY #10           
;MAXFREQ          
LDX #$87          
JSR UGETINT       
;(Y=12,STUFE)     
LDX #$8A          
JSR UGETINT       
;(Y=14,WELLE)     
LDX #4            
JSR CHKBYT        
LDA SOUNDS,X      
LDX #$90          
JSR UGRFSTA       
;(Y=16,IMP.BREITE)
LDX #$8E          
JSR UGETINT       
DEY               
LDA (<T),Y        
CMP #$10          
BCS ILL.QU2       
LDA #[XSOUND      
LDY #]XSOUND      
JSR UCALLAY       
JSR URESSND       
JMP NEXT0         
;- - - - - - - - -
SOUNDS            
DFD $11,$21       
DFD $41,$81       
;-----------------
ILL.QU2 JMP ILL.QU
;-----------------
IFK               
;INTEGER-ARGUMENT 
;(CODE)           
JSR PASFET        
ASL               
TAX               
LDA (<T),Y        
STA <TP           
INY               
LDA (<T),Y        
BNE ILL.QU2       
LDA FKTTAB,X      
LDY FKTTAB+1,X    
LDX <TP           
JSR UCALLAY       
;ERG. IN FAC      
;-> INTEGER       
STA LCRD          
JSR FLPINT        
STA LCRB          
LDY #0            
LDA <FAC+4;      L
STA (<T),Y        
INY               
LDA <FAC+3;      H
STA (<T),Y        
JMP NEXT1         
;-----------------
FKTTAB            
DFD $840D; RWINDOW
;                 
DFD $8185; RGR    
DFD $819E; RCLR   
DFD $9B0F; RDOT   
DFD $8253; POT    
DFD $82B4; PEN    
DFD $8206; JOY    
;                 
;DFD $8382; BUMP  
;DFD $8367;RSPRCLR
;=================
ENDMOD5           
;                 
EXP AKT,IFK,EXT,  
ENDMOD5           
;                 
END