;=================
;    PAS.MOD4     
; VERSION  C-128  
;                 
;FILES UND SYSTEM 
;=================
;                 
;25.9.1986        
;                 
IMP PAS.SYST      
IMP PAS.MOD1      
IMP PAS.MOD2      
;(INCT)           
IMP PAS.MOD3      
;(LDFAC,          
;GETSTR,UINT,     
;FACVAR ENDMOD3)  
;=================
ORG ENDMOD3       
;=================
DEFAULT           
DFD 0,0; STATUS   
DFD 0,0; AKKU     
DFD 0,0; X REG.   
DFD 0,0; Y REG.   
;-----------------
FAST              
;                 
LDA #[XFAST       
LDY #]XFAST       
BNE SLOW1         
;-----------------
SLOW              
;                 
LDA #[XSLOW       
LDY #]XSLOW       
SLOW1             
JSR UCALLAY       
JMP NEXT0         
;-----------------
USYSREGS          
;* RETTE DIE      
;* CPU-REGISTER   
;* NACH (A/X)     
STA <TP           
STX <TP+1         
LDY #3            
SYSREGS1          
DFD $B9,<FARST,0  
;LDA <FARST,Y     
PHA               
LDA (<TP),Y       
DFD $99,<FARST,0  
;STA <FARST,Y     
PLA               
STA (<TP),Y       
DEY               
BPL SYSREGS1      
RTS               
;-----------------
XGETCFG           
LDX BANK          
STA LCRD          
JSR GETCFG        
STA LCRB          
TAX               
DEY               
RTS               
;-----------------
SYS               
;ADRESSE /        
;REGISTER (EVTL.0)
;                 
LDA (<T),Y        
STA <TP           
INY               
LDA (<T),Y        
TAX               
ORA <TP           
BNE SYS1          
LDA #[DEFAULT     
STA <TP           
LDX #]DEFAULT     
;                 
SYS1 LDA <TP      
JSR USYSREGS      
LDA <TP           
PHA               
LDA <TP+1         
PHA               
;                 
LDA BANK          
STA <FARCNF       
;                 
JSR POP2          
LDY #0            
LDA (<T),Y        
STA <FARPC+1; L!  
INY               
LDA (<T),Y        
STA <FARPC;   H!  
JSR UCALL         
CLI               
CLD               
;***DECIMAL/IRQ:=0
PLA               
TAX               
PLA               
JSR USYSREGS      
;                 
JSR POP2          
JMP NEXT0         
;-----------------
POK               
;ADRESSE / WERT   
;                 
LDA (<T),Y        
PHA               
JSR POP2          
LDA (<T),Y        
STA <TP           
INY               
LDA (<T),Y        
STA <TP+1         
LDA #<TP          
STA STAVEC        
;                 
JSR XGETCFG       
PLA               
JSR STASH         
;                 
JSR POP2          
JMP NEXT0         
;-----------------
PEK               
;ADRESSE          
;                 
LDA (<T),Y        
STA <TP           
INY               
LDA (<T),Y        
STA <TP+1         
LDA #<TP          
STA FETVEC        
;                 
JSR XGETCFG       
JSR FETCH         
STA (<T),Y        
TYA               
INY               
STA (<T),Y        
;                 
JMP NEXT0         
;-----------------
VAL               
;                 
JSR GETSTR        
;(Y=0)            
STA <STRPTR       
STX <STRPTR+1     
;                 
LDA (<STRPTR),Y   
TAY               
INC <STRPTR       
BNE VAL0          
INC <STRPTR+1     
VAL0              
;*MIT 0 BEENDEN   
LDA (<STRPTR),Y   
PHA               
LDA #0            
STA (<STRPTR),Y   
TYA               
PHA               
;                 
LDA <T            
STA <VAR          
LDA <T+1          
STA <VAR+1        
STA LCRD          
JSR STRFLP1       
LDX #1            
JSR STRFLP        
STA LCRB          
JSR FACVAR        
;                 
PLA               
TAY               
PLA               
STA (<STRPTR),Y   
;                 
JSR AL3           
JMP NEXT0         
;-----------------
STR               
;X,M,N            
LDA #249          
JSR POPA;  7 BYTES
LDA <T            
LDY <T+1          
JSR LDFAC         
LDY #7            
LDA (<T),Y        
STA <N            
LDY #5            
LDA (<T),Y        
STA <M            
JSR UWRREAL       
JMP MKSTR         
;-----------------
USET              
;FILE-POINTER     
;SETZEN           
;AC=XR=FILENR     
LDY #0            
STY <ST           
LDA (<T),Y        
STA <F            
INY               
LDA (<T),Y        
STA <F+1          
JSR POP2          
LDY #<FILENR      
LDA (<F),Y        
TAX               
RTS               
;-----------------
INITT             
;<TP  :=ANFANG    
;<TP+2:=ENDE      
;(YR:=0)          
CLC               
LDA <F            
LDX <F+1          
ADC #<BUFFER      
STA <TP           
BCC INITT1        
INX               
INITT1 CLC        
LDY #0            
ADC (<T),Y        
STA <TP+2         
TXA               
STA <TP+1         
INY               
ADC (<T),Y        
STA <TP+3         
JSR POP2          
DEY               
RTS               
;-----------------
RDEND             
;LESEN-ENDE:      
;C=0 KEIN FEHLER  
;    AC=LETZTES   
;C=1 FEHLER       
;    AC=STATUS    
;                 
BCS RDNOK         
;XR=BYTE          
;(STATUS=0)       
;EOF   :=0        
TAX               
LDA #0            
BEQ INIBUF        
;-----------------
RDNOK             
;EOLN:=TRUE       
;EOF :=TRUE       
;STATUS SETZEN    
LDA #1            
LDX #13           
;-----------------
INIBUF            
;A -> EOF         
;X -> LETZTES     
;     ZEICHEN     
;EOLN,FALLS CR    
;STATUS SETZEN    
;                 
LDY #<EOF         
STA (<F),Y        
LDY #<STATUS      
LDA <ST           
STA (<F),Y        
LDA #0            
LDY #<EOF+1       
STA (<F),Y        
LDY #<BUFFER+1    
STA (<F),Y        
LDY #<EOLN+1      
STA (<F),Y        
DEY               
CPX #13           
BNE INIBUF1       
LDX #" "          
LDA #1            
INIBUF1           
STA (<F),Y        
TXA               
LDY #<BUFFER      
STA (<F),Y        
RTS               
;-----------------
UBLANK            
;(<T),Y - X       
;VORAUSGEHENDE    
;LEERZEICHEN      
;AUSGEBEN         
STX <TP+4         
SEC               
LDA (<T),Y        
SBC <TP+4         
;- - - - - - - - -
UBLANKX           
BCC BLANK2        
TAX               
BEQ BLANK2        
LDA #" "          
BLANK1 JSR XBSOUT 
DEX               
BNE BLANK1        
BLANK2 JMP POP2   
;-----------------
GETCH             
;BASIN            
;TEST AUF FEHLER  
;EVTL. ECHO       
;                 
LDA #[BASIN       
STA <FARPC+1      
LDA #]BASIN       
STA <FARPC        
JSR UCALLF        
;                 
TAX               
LDA <ST           
BNE GETCH2        
TXA               
CMP #13           
BNE GETCH1        
LDA <INDEV        
BNE GETCH0        
;(0=> TASTATUR)   
TXA               
JSR XBSOUT        
GETCH0 TXA        
GETCH1 CLC        
RTS               
GETCH2 SEC        
RTS               
;                 
;=================
SIC               
;                 
JSR USET          
BEQ SIC1          
LDA #[CHKIN       
STA <FARPC+1      
LDA #]CHKIN       
STA <FARPC        
JSR UCALLF        
BCS SOC1          
SIC1 JMP NEXT0    
;-----------------
SOC               
;                 
JSR USET          
BEQ SIC1          
LDA #[CKOUT       
STA <FARPC+1      
LDA #]CKOUT       
STA <FARPC        
JSR UCALLF        
BCC SIC1          
SOC1 JMP IOERR    
;-----------------
CLR               
;                 
LDA #[CLRCHN      
STA <FARPC+1      
LDA #]CLRCHN      
STA <FARPC        
JSR UCALLF        
JMP NEXT0         
;-----------------
CLS               
;                 
JSR USET          
LDX #[FCLOSE      
STX <FARPC+1      
LDX #]FCLOSE      
STX <FARPC        
JSR UCALLF        
LDY #<FILENR      
LDA #0            
STA (<F),Y        
;FUER STD.FILES   
;INPUT/OUTPUT     
JMP NEXT0         
;-----------------
OPN               
;TP  :=ADR(NAME)  
LDA (<T),Y        
INY               
ORA (<T),Y        
BEQ OPN1          
;** MIT NAME      
JSR GETSTR        
;(Y=0)            
STA <TP           
STX <TP+1         
CLC               
ADC #1            
STA <FILNAM       
BCC OPN0          
INX               
OPN0 STX <FILNAM+1
LDA (<TP),Y       
;                 
OPN1 STA <LENGTH  
JSR POP2          
LDY #0            
LDA (<T),Y        
STA <SECOND       
JSR POP2          
LDA (<T),Y        
STA <DEVICE       
JSR POP2          
;                 
;DESKRIPTOR ADR:  
;                 
JSR USET          
;                 
LDX #1            
STX <NAMBNK       
;                 
STX <TP           
;SUCHE UNGENUTZTE 
;FILENUMMER       
OPN4 INC <TP      
LDX <TP           
STA LCRD          
JSR LOOKUP        
STA LCRB          
;(Z=1 => BELEGT)  
BEQ OPN4          
;                 
LDA <TP           
LDY #<FILENR      
STA (<F),Y        
STA <LOGFIL       
LDA #[FOPEN       
STA <FARPC+1      
LDA #]FOPEN       
STA <FARPC        
JSR UCALLF        
BCC PUT3          
;EOF:=FALSE       
;(ST=0)           
JMP IOERR         
;-----------------
PUT               
;                 
JSR INITT         
PUT1 LDA (<TP),Y  
JSR XBSOUT        
JSR INCT          
BNE PUT1          
PUT2 LDA #1       
DFD $2C           
PUT3 LDA #0       
;                 
;AC -> EOF        
;STATUS LESEN     
;                 
LDY #<EOF         
STA (<F),Y        
LDA #0            
INY               
STA (<F),Y        
LDA <ST           
LDY #<STATUS      
STA (<F),Y        
JMP NEXT0         
;-----------------
GET               
;EOF:=TRUE,FALLS  
;BEIM LETZTEN     
;LESEN ST<>0      
;                 
JSR INITT         
GET1              
LDA #[BASIN       
STA <FARPC+1      
LDA #]BASIN       
STA <FARPC        
JSR UCALLF        
STA (<TP),Y       
JSR INCT          
BNE GET1          
LDY #<STATUS      
LDA (<F),Y        
BNE PUT2          
BEQ PUT3          
;=================
WRR               
;X,M,N            
LDA #249          
JSR POPA;  7 BYTES
LDA <T            
LDY <T+1          
JSR LDFAC         
LDY #7            
LDA (<T),Y        
STA <N            
LDY #5            
;                 
WRR1              
LDA (<T),Y        
STA <M            
JSR UWRREAL       
LDA #0            
PHA               
LDA <T            
LDX <T+1          
JMP WRAX          
;(DORT POP2)      
;-----------------
WRI               
;X,M   (N:=0)     
JSR POP2          
LDA (<T),Y        
STA <TP           
INY               
LDA (<T),Y        
LDY <TP           
STA LCRD          
JSR INTFLP        
STA LCRB          
LDA #0            
STA <N            
LDY #2            
BNE WRR1          
;-----------------
WRC               
;                 
JSR POP2          
LDX #1            
LDY #2            
JSR UBLANK        
LDY #2            
LDA (<T),Y        
DFD $2C           
;-----------------
WRL               
;WRITELN          
LDA #13           
TAX               
JSR XBSOUT        
;- - - - - - - - -
WREND             
;SCHREIBEN ENDE:  
;XR=LAST          
;EOF:=TRUE        
LDA #1            
JSR INIBUF        
JMP NEXT0         
;-----------------
WRS               
;                 
LDA (<T),Y        
PHA               
;                 
JSR POP2          
JSR GETSTR        
;                 
WRAX              
STA <TP           
STX <TP+1         
LDY #0            
LDA (<TP),Y       
STA <TP+2         
SEC               
PLA               
SBC (<TP),Y       
JSR UBLANKX       
;(INCL. POP!)     
;(Y=0)            
WRS1 CPY <TP+2    
BEQ WREND         
INY               
LDA (<TP),Y       
JSR XBSOUT        
JMP WRS1          
;-----------------
WRB               
;                 
LDA (<T),Y        
PHA               
JSR POP2          
LDA (<T),Y        
ASL               
TAY               
LDA BOOLS,Y       
LDX BOOLS+1,Y     
BNE WRAX          
;=================
BOOLS             
DFD ISFALSE,ISTRUE
ISFALSE           
DFD 5,"FALSE"     
ISTRUE            
DFD 4,"TRUE"      
;                 
FLAG DFD 0        
;0 =>  RDI        
;SONST RDR        
;=================
RDR               
;                 
INY               
;- - - - - - - - -
RDI               
STY FLAG          
;                 
LDY #0            
;ZEICHEN BIS BLANK
;ODER CR IN TABI  
;ABLEGEN          
;                 
RDI1 JSR GETCH    
BCS RDI6          
CMP #" "          
BEQ RDI1          
CMP #13           
BEQ RDI1          
RDI4 STA TABI,Y   
INY               
JSR GETCH         
BCS RDI6          
CMP #" "          
BEQ RDI5          
CMP #13           
BNE RDI4          
RDI5 CLC          
RDI6 PHP          
PHA               
LDA #0            
STA TABI,Y        
;                 
JSR AL2           
LDA <T            
STA <VAR          
LDY <T+1          
STY <VAR+1        
;                 
LDA #[TABI        
STA <STRPTR       
LDA #]TABI        
STA <STRPTR+1     
;                 
;STRING AUS       
;BANK 1 LESEN:    
;                 
STA LCRD          
JSR STRFLP1       
LDX #1            
JSR STRFLP        
STA LCRB          
LDA FLAG          
BNE RDI8          
;                 
JSR UINT          
STA LCRB          
JMP RDI9          
RDI8              
JSR FACVAR        
JSR AL3           
;                 
RDI9 PLA          
PLP               
JSR RDEND         
JMP NEXT0         
;-----------------
RDC               
;                 
JSR GETCH         
JSR RDEND         
JSR AL2           
LDY #<BUFFER      
LDA (<F),Y        
LDY #0            
STA (<T),Y        
TYA               
INY               
STA (<T),Y        
JMP NEXT0         
;-----------------
RDL               
;                 
LDY #<EOLN        
LDA (<F),Y        
BNE RDL2          
RDL0 JSR GETCH    
BCS RDL1          
CMP #13           
BNE RDL0          
CLC               
RDL1 JSR RDEND    
RDL2 JMP NEXT0    
;-----------------
RDS               
;                 
JSR AL2           
DEY               
;(Y=0)            
RDS1 JSR GETCH    
BCS RDS3          
CMP #13           
BEQ RDS2          
INY               
STA (<T),Y        
JMP RDS1          
;                 
RDS2 CLC          
RDS3 PHP          
PHA               
TYA               
LDY #0            
STA (<T),Y        
PLA               
PLP               
JSR RDEND         
JMP MKSTR         
;-----------------
KEY               
;                 
JSR AL2           
LDA #[GETKEY      
LDY #]GETKEY      
JSR UCALLAY       
LDY #0            
STA (<T),Y        
TYA               
INY               
STA (<T),Y        
JMP NEXT0         
;=================
;REELLE ZAHLEN    
;FORMATIEREN:     
;        ----     
;654321.01234     
;ALSO 1.NACHKOMMA 
;HAT INDEX 0      
;=================
<XREG EQU <B1     
<YREG EQU <B1+1   
<POS  EQU $72     
<M    EQU <VAR    
<N    EQU <VAR+1  
<VORK EQU $49     
<EXP  EQU $5F     
;-----------------
USIZE             
; <VORK BESTIMMEN 
; <XREG = VORZ.   
; <YREG <0,FALLS 0
LDA #" "          
BIT <FAC+5        
BPL SIZE0         
LDA #"-"          
SIZE0 STA <FAC+5  
STA <XREG         
;                 
LDA #0            
STA <YREG         
STA <VORK         
LDX <FAC          
BNE SIZE1         
INC <VORK         
DEC <YREG         
RTS               
;                 
SIZE1             
CPX #$80          
BEQ SIZE2         
BCS SIZE4         
SIZE2             
LDA #$21          
LDY #$8E          
JSR $8A08         
LDA #$F7 ;-9      
STA <VORK         
;                 
SIZE4 LDA #$1C    
LDY #$8E          
JSR $8C87         
BEQ SIZE8         
BPL SIZE6         
SIZE5 LDA #$17    
LDY #$8E          
JSR $8C87         
BEQ SIZE51        
BPL SIZE7         
SIZE51 JSR $8B17  
DEC <VORK         
BNE SIZE5         
SIZE6 JSR $8B38   
INC <VORK         
BNE SIZE4         
SIZE7 JSR $8A0E   
SIZE8 JSR $8CC7   
;                 
CLC               
LDA <VORK         
ADC #9            
STA <VORK         
RTS               
;-----------------
UDIGIT            
;                 
LDY <YREG         
LDX <XREG         
DIGIT1 LDA <FAC+4 
CLC               
ADC $8F7E,Y       
STA <FAC+4        
LDA <FAC+3        
ADC $8F7D,Y       
STA <FAC+3        
LDA <FAC+2        
ADC $8F7C,Y       
STA <FAC+2        
LDA <FAC+1        
ADC $8F7B,Y       
STA <FAC+1        
INX               
BCS DIGIT2        
BPL DIGIT1        
BMI DIGIT3        
DIGIT2 BMI DIGIT1 
;                 
DIGIT3 TXA        
BCC DIGIT4        
EOR #$FF          
ADC #10           
DIGIT4 ADC #$2F   
PHA               
EOR #$FF          
AND #$80          
STA <XREG         
INY               
INY               
INY               
INY               
CPY #$24          
BEQ DIGIT5        
CPY #$3C          
BNE DIGIT6        
DIGIT5 LDY #255   
;** ENDE          
DIGIT6 STY <YREG  
PLA               
AND #$7F          
RTS               
;-----------------
UWRNUM            
;VORZEICHEN   = A 
;POS IN ZAHL  = X 
;POS IN STRING= Y 
;BIS X = <N       
;ZIFFERN DRUCKEN  
;                 
STA (<T),Y        
INY               
;                 
LDA #$80          
STA <XREG         
;                 
WRNUM1            
LDA #"0"          
CPX <VORK         
BEQ WRNUM2        
BPL WRNUM3        
WRNUM2            
BIT <YREG         
BMI WRNUM3        
;                 
STX <M            
STY <POS          
JSR UDIGIT        
LDX <M            
LDY <POS          
;                 
WRNUM3            
CPX #0            
BNE WRNUM4        
PHA               
LDA #"."          
STA (<T),Y        
INY               
PLA               
WRNUM4            
STA (<T),Y        
INY               
;                 
DEX               
CPX <N            
BNE WRNUM1        
RTS               
;-----------------
UWRREAL           
;M  := # VORKOMMA 
;N  := # NACHKOMMA
;FAC:= REALZAHL   
;N<0 ->EXP-FORMAT 
;STRING AB (<T)   
;MIT LAENGE IN 0  
STA LCRD          
LDA <N            
PHA               
BEQ WRREAL2       
BPL WRREAL1       
;M:=M+N-5         
CLC               
LDA <M            
ADC <N            
SEC               
SBC #5            
STA <M            
JMP WRREAL2       
;                 
WRREAL1           
;M:=M-N-1         
;N:=-N            
CLC               
LDA <M            
SBC <N            
STA <M            
LDA #0            
SEC               
SBC <N            
STA <N            
WRREAL2           
;                 
JSR USIZE         
;                 
PLA               
PHA               
BPL WRREAL21      
LDX <VORK         
LDA #1            
STA <VORK         
DEX               
STX <EXP          
;                 
;EVTL. LEADING    
;BLANKS:          
;                 
WRREAL21 LDY #1   
;                 
LDA <VORK         
CMP #1            
BPL WRREAL3       
LDA #1            
WRREAL3 STA <POS  
;                 
LDX <M            
LDA #" "          
DEX               
WRREAL4 DEX       
CPX <POS          
BMI WRREAL5       
STA (<T),Y        
INY               
BNE WRREAL4       
;                 
WRREAL5 LDX <POS  
LDA <XREG         
JSR UWRNUM        
PLA               
BPL WRREAL9       
;EXPONENT:        
LDA #"E"          
STA (<T),Y        
INY               
;                 
LDX #"+"          
LDA <EXP          
BPL WRREAL6       
LDA #0            
SEC               
SBC <EXP          
LDX #"-"          
WRREAL6 PHA       
TXA               
STA (<T),Y        
INY               
;                 
PLA               
LDX #$2F          
SEC               
WRREAL7 INX       
SBC #10           
BCS WRREAL7       
ADC #$3A          
INY               
STA (<T),Y        
DEY               
TXA               
STA (<T),Y        
INY               
INY               
WRREAL9 DEY       
TYA               
LDY #0            
STA (<T),Y        
STA LCRB          
RTS               
;=================
ENDMOD4           
;=================
EXP SIC,SOC,CLR,  
CLS,OPN,PUT,GET,  
WRR,WRI,WRC,WRL,  
WRS,RDR,RDI,RDC,  
RDL,WRB,RDS,      
SLOW,FAST,        
SYS,POK,PEK,STR,  
VAL,KEY,ENDMOD4   
END