;=================
;    PAS.MOD3     
; VERSION  C-128  
;                 
;REALS,SETS UND   
;STRINGS          
;=================
;                 
;11.11.1986       
;                 
IMP PAS.SYST      
IMP PAS.MOD1      
IMP PAS.MOD2      
;(NUR TRUE, FALSE,
; ENDMOD2)        
;                 
;=================
ORG ENDMOD2       
;=================
;                 
OPADR             
DFD OP1 ; +       
DFD OP2 ; -       
DFD OP3 ; *       
DFD OP4 ; /       
DFD OP5 ; ^       
DFD OP6 ; +/-     
;                 
DFD XABS          
DFD XSQRT         
DFD XLN           
DFD XEXP          
DFD XSIN          
DFD XCOS          
DFD XTAN          
DFD XATN          
;                 
;=================
LDFAC             
;(A,Y) -> <FAC    
;DABEI VORZEICHEN 
;EXPANDIEREN      
;                 
STA <B1           
STY <B1+1         
LDY #4            
LDA (<B1),Y       
STA <FAC+4        
DEY               
LDA (<B1),Y       
STA <FAC+3        
DEY               
LDA (<B1),Y       
STA <FAC+2        
DEY               
LDA (<B1),Y       
STA <FAC+5        
ORA #$80          
STA <FAC+1        
DEY               
LDA (<B1),Y       
STA <FAC          
STY <FACLSB       
;*****LOESCHE LSB 
RTS               
;-----------------
LDARG             
;(A,Y) -> <ARG    
;DABEI VORZEICHEN 
;EXPANDIEREN UND  
;FLAGS SETZEN:    
;                 
STA <B1           
STY <B1+1         
LDY #4            
LDA (<B1),Y       
STA <ARG+4        
DEY               
LDA (<B1),Y       
STA <ARG+3        
DEY               
LDA (<B1),Y       
STA <ARG+2        
DEY               
LDA (<B1),Y       
STA <ARG+5        
;**VORZEICHENVER- 
;**GLEICH ARG/FAC 
EOR <FAC+5        
STA <VZVGL        
;                 
LDA <ARG+5        
ORA #$80          
STA <ARG+1        
DEY               
LDA (<B1),Y       
STA <ARG          
LDA <FAC          
;*****ACCU BELEGEN
RTS               
;-----------------
FACVAR            
;FAC RUNDEN UND   
;NACH (<VAR)      
STA LCRD          
JSR FACRND        
STA LCRB          
LDY #4            
LDA <FAC+4        
STA (<VAR),Y      
DEY               
LDA <FAC+3        
STA (<VAR),Y      
DEY               
LDA <FAC+2        
STA (<VAR),Y      
DEY               
LDA <FAC+5        
ORA #$7F          
AND <FAC+1        
STA (<VAR),Y      
DEY               
LDA <FAC          
STA (<VAR),Y      
RTS               
;-----------------
ULOADA JSR AL2    
ULOAD LDY #4      
LOAD1 LDA (<B1),Y 
STA (<T),Y        
DEY               
BPL LOAD1         
JMP AL3           
;-----------------
USTORP JSR POP3   
USTORE LDY #4     
STORE1 LDA (<T),Y 
STA (<B1),Y       
DEY               
BPL STORE1        
JMP POP2          
;-----------------
UFLT              
;INTEGER->REAL    
;(<VAR) INDIZIERT 
JSR AL3           
LDY #1            
LDA (<VAR),Y      
TAX               
DEY               
LDA (<VAR),Y      
TAY               
TXA               
;A=H Y=L          
STA LCRD          
JSR INTFLP        
STA LCRB          
JMP FACVAR        
;-----------------
UINT              
;FAC->INTEGER     
;->(<VAR)         
STA LCRD          
JSR FLPINT        
STA LCRB          
LDY #0            
LDA <FAC+4        
;(L-BYTE ERG.)    
STA (<VAR),Y      
INY               
LDA <FAC+3        
;(H-BYTE ERG.)    
STA (<VAR),Y      
RTS               
;-----------------
ULDTOP            
;FAC :=TOP        
;A/Y =>SCND       
JSR POP3          
LDA <T            
LDY <T+1          
JSR LDFAC         
JSR POP5          
LDA <T            
LDY <T+1          
RTS               
;-----------------
USETVAR           
;                 
LDA <T            
STA <VAR          
LDY <T+1          
STY <VAR+1        
RTS               
;-----------------
UEXEC             
;BASIC-ROUTINE    
;AUFRUFEN         
LDY #0            
JSR PASFET        
ASL               
TAX               
LDA OPADR+1,X     
PHA               
LDA OPADR,X       
PHA               
LDA <FAC          
STA LCRD          
RTS               
;=================
SRL               
;L/H (LVL)        
JSR SUMP          
JSR USTORP        
JMP NEXT3         
;-----------------
SRS               
;STACK (LVL)      
JSR POP5          
JSR SUMT          
JSR AL2           
JSR USTORE        
JSR POP2          
JMP NEXT1         
;-----------------
SR0               
;L/H (LVL=0)      
JSR SUMB          
JSR USTORP        
JMP NEXT2         
;-----------------
SRA               
;ABSOLUT          
JSR POP5          
LDA (<T),Y        
STA <B1           
INY               
LDA (<T),Y        
STA <B1+1         
JSR AL2           
JSR USTORE        
JSR POP2          
JMP NEXT0         
;-----------------
LRL               
;L/H (LVL)        
JSR SUMP          
JSR ULOADA        
JMP NEXT3         
;-----------------
LRS               
;STACK (LVL)      
JSR SUMT          
JSR ULOAD         
JMP NEXT1         
;-----------------
LR0               
;L/H (LVL=0)      
JSR SUMB          
JSR ULOADA        
JMP NEXT2         
;-----------------
LRA               
;ABSOLUT          
LDA (<T),Y        
STA <B1           
INY               
LDA (<T),Y        
STA <B1+1         
JSR ULOAD         
JMP NEXT0         
;-----------------
LRC               
;5 BYTES AUS DEM  
;PROGRAMMCODE     
JSR AL2           
DEY               
;(YR=0)           
LRC1 JSR PASFET   
STA (<T),Y        
INY               
CPY #5            
BNE LRC1          
JSR AL3           
JMP NEXT5         
;-----------------
FLT               
;TOP     INT->REAL
JSR USETVAR       
JSR UFLT          
JMP NEXT0         
;-----------------
FLO               
;SCND    INT->REAL
;TOP VERSCHIEBEN  
SEC               
LDA <T            
SBC #3            
STA <B1           
LDA <T+1          
SBC #0            
STA <B1+1         
LDY #4            
FLO1 LDA (<B1),Y  
STA (<T),Y        
DEY               
BPL FLO1          
SEC               
LDA <B1           
SBC #2            
STA <VAR          
LDA <B1+1         
SBC #0            
STA <VAR+1        
JSR UFLT          
JMP NEXT0         
;-----------------
RND               
;RANDOM           
LDA (<T),Y        
STA <FAC          
STA <FAC+5        
LDA #[XRANDOM     
LDY #]XRANDOM     
JSR UCALLAY       
JSR USETVAR       
JSR FACVAR        
JSR AL3           
JMP NEXT0         
;-----------------
INT               
;REAL->INTEGER    
JSR POP3          
JSR USETVAR       
JSR LDFAC         
JSR UINT          
JMP NEXT0         
;-----------------
TRC               
;REAL->INTEGER    
JSR POP3          
JSR USETVAR       
JSR LDFAC         
LDA <FAC+5        
PHA               
LSR <FAC+5        
;(ABS, WEIL SIGN) 
JSR UINT          
PLA               
BPL TRC1          
LDA #0            
TAY               
SEC               
SBC (<T),Y        
STA (<T),Y        
TYA               
INY               
SBC (<T),Y        
STA (<T),Y        
TRC1 JMP NEXT0    
;-----------------
MON               
;(INDEX)          
SEC               
LDA <T            
SBC #3            
STA <VAR          
TAX               
LDA <T+1          
SBC #0            
STA <VAR+1        
TAY               
TXA               
JSR LDFAC         
JSR UEXEC         
;***ROM NOCH EIN- 
;***GESCHALTET!   
STA LCRB          
JSR FACVAR        
JMP NEXT1         
;-----------------
DYA               
;(INDEX)          
;FAC := TOP       
;ARG := SCND      
JSR ULDTOP        
STA <VAR          
STY <VAR+1        
JSR LDARG         
JSR UEXEC         
;***ROM NOCH EIN- 
;***GESCHALTET!   
STA LCRB          
JSR FACVAR        
JSR AL3           
JMP NEXT1         
;-----------------
VGL               
;(MASKE)          
;BIT:       210   
;BEDEUTUNG: <=>   
;                 
JSR ULDTOP        
;A/Y =>SCND       
JSR LDARG         
;                 
;FUER ROM-ROUTINE 
;VORZ. WIEDER     
;PACKEN:          
;                 
LDA <ARG+5        
ORA #$7F          
AND <ARG+1        
STA <ARG+1        
LDA #<ARG         
LDY #0            
;                 
STA LCRD          
JSR VGLFLT        
STA LCRB          
;ERG: $01 --> >   
;     $00 --> =   
;     $FF --> <   
BNE VGL1          
LDA #2            
BNE VGL3          
VGL1 BMI VGL2     
LDA #1            
DFD $2C           
VGL2 LDA #4       
VGL3              
;-->VON STRCMP    
;A=MASKE ERGEBNIS 
;                 
LDY #0            
STA <TP           
JSR PASFET        
AND <TP           
BEQ VGL4          
;***TRUE          
LDA #1            
VGL4 STA (<T),Y   
TYA               
INY               
STA (<T),Y        
JMP NEXT1         
;=================
MASK              
DFD %00000001     
DFD %00000010     
DFD %00000100     
DFD %00001000     
DFD %00010000     
DFD %00100000     
DFD %01000000     
DFD %10000000     
;                 
;-----------------
;                 
UMASK             
;AC -> MASKE      
;YR -> INDEX 0..11
TAX               
LSR               
LSR               
LSR               
TAY               
CPY #<SETLEN+1    
BCS MASK1         
TXA               
AND #7            
TAX               
LDA MASK,X        
RTS               
;UEBERLAUF:       
;LEERE MASKE      
MASK1 LDA #0      
RTS               
;-----------------
UEMPTY            
;LEERE MENGE      
;(AB <T)          
LDY #<SETLEN      
LDA #0            
EMPTY1            
STA (<T),Y        
DEY               
BPL EMPTY1        
RTS               
;-----------------
UISET             
;<T ->1. OPERAND  
;<TP->2. OPERAND  
;Y:=SETLEN        
LDA #246          
JSR POPA          
LDA <T            
STA <TP           
LDA <T+1          
STA <TP+1         
JSR POP12         
LDY #<SETLEN      
RTS               
;-----------------
NUL               
;LEERE MENGE      
JSR AL2           
JSR UEMPTY        
JMP GS11          
;-----------------
LSA               
;                 
LDA (<T),Y        
STA <TP           
INY               
LDA (<T),Y        
STA <TP+1         
LDY #<SETLEN      
LSA1 LDA (<TP),Y  
STA (<T),Y        
DEY               
BPL LSA1          
BMI GS11          
;-----------------
SSA               
;                 
JSR POP12         
LDA (<T),Y        
STA <TP           
INY               
LDA (<T),Y        
STA <TP+1         
JSR AL2           
LDY #<SETLEN      
SSA1 LDA (<T),Y   
STA (<TP),Y       
DEY               
BPL SSA1          
LDA #252          
JSR POPA          
JMP NEXT0         
;-----------------
GS1               
;TOP -> SET       
LDA (<T),Y        
PHA               
JSR UEMPTY        
PLA               
JSR UMASK         
ORA (<T),Y        
STA (<T),Y        
GS11 LDA #10      
JSR ALLOC         
JMP NEXT0         
;-----------------
GS2               
;SCND..TOP -> SET 
;**GEAENDERT!     
LDA (<T),Y        
STA <TP+1         
JSR POP2          
LDA (<T),Y        
STA <TP           
JSR UEMPTY        
GS21 LDA <TP+1    
CMP <TP           
BMI GS11          
JSR UMASK         
ORA (<T),Y        
STA (<T),Y        
DEC <TP+1         
JMP GS21          
;-----------------
UNI               
;                 
JSR UISET         
UNI1 LDA (<T),Y   
ORA (<TP),Y       
STA (<T),Y        
DEY               
BPL UNI1          
BMI GS11          
;-----------------
DIF               
;                 
JSR UISET         
DIF1 LDA (<TP),Y  
EOR #$FF          
AND (<T),Y        
STA (<T),Y        
DEY               
BPL DIF1          
BMI GS11          
;-----------------
ISC               
;                 
JSR UISET         
ISC1 LDA (<TP),Y  
AND (<T),Y        
STA (<T),Y        
DEY               
BPL ISC1          
BMI GS11          
;-----------------
SEQ               
;                 
JSR UISET         
SEQ1 LDA (<T),Y   
CMP (<TP),Y       
BNE FALSEQ        
DEY               
BPL SEQ1          
;                 
TRUEQ JMP TRUE    
FALSEQ JMP FALSE  
;-----------------
SLE               
;                 
JSR UISET         
SLE1 LDA (<TP),Y  
EOR #$FF          
AND (<T),Y        
BNE FALSEQ        
DEY               
BPL SLE1          
BMI TRUEQ         
;-----------------
SGE               
;                 
JSR UISET         
SGE1 LDA (<T),Y   
EOR #$FF          
AND (<TP),Y       
BNE FALSEQ        
DEY               
BPL SGE1          
BMI TRUEQ         
;-----------------
INN               
;                 
JSR POP12         
LDA (<T),Y        
JSR UMASK         
INY               
INY               
AND (<T),Y        
BEQ FALSEQ        
BNE TRUEQ         
;=================
;                 
;STRINGOPERATIONEN
;                 
;=================
;                 
<S1     EQU <TP   
<S2     EQU <TP+2 
;                 
<POS    EQU <TP+4 
<OLDLEN EQU <TP+5 
<NEWLEN EQU <TP+6 
<LENS1  EQU <TP+7 
;                 
<LEN    EQU <TP+6 
<NEWPOS EQU <TP+7 
;-----------------
MKSTR             
;ERGEBNISSTRING   
;AB (<T) AUF DEM  
;STACK MIT PSEUDO-
;ADRESSE BEENDEN  
LDY #0            
LDA (<T),Y        
TAX               
SEC               
ADC <T            
STA <T            
BCC MKSTR1        
INC <T+1          
MKSTR1 TXA        
STA (<T),Y        
TYA               
INY               
STA (<T),Y        
JMP NEXT0         
;-----------------
GETSTR            
;ADR --> (A/X)    
;YR:=0            
;KEIN POP FUER DIE
;ADRESSE!         
;                 
LDY #1            
LDA (<T),Y        
DEY               
TAX               
BNE GETSTR8       
;*****************
;VOM STACK        
;*****************
CLC               
LDA <T            
SBC (<T),Y        
STA <T            
BCS GETSTR1       
DEC <T+1          
GETSTR1           
LDX <T+1          
RTS               
;                 
GETSTR8           
LDA (<T),Y        
RTS               
;-----------------
GETVAL            
;HOLE WERT 0..255 
;NACH X.          
;YR:=1            
;                 
LDY #0            
LDA (<T),Y        
TAX               
INY               
LDA (<T),Y        
BEQ GETVAL1       
;- - - - - - - - -
ILL.VAL           
LDX #$1E          
JMP BASERR        
GETVAL1 JMP POP2  
;-----------------
GETNOT0           
JSR GETVAL        
CPX #0            
BEQ ILL.VAL       
RTS               
;-----------------
LEN               
;                 
JSR GETSTR        
STA <S1           
STX <S1+1         
LDA (<S1),Y       
;                 
;<--- VON POS     
LEN1 LDY #0       
STA (<T),Y        
TYA               
INY               
STA (<T),Y        
JMP NEXT0         
;-----------------
COPY              
;COPY (S1,POS,LEN)
;                 
JSR GETVAL        
STX <LEN          
JSR GETNOT0       
STX <POS          
JSR GETSTR        
STA <S1           
STX <S1+1         
;*****************
;KOPIERE          
;MINIMUM(LEN,     
;   LEN(S1)-POS+1)
;ZEICHEN:         
;*****************
;(Y=0)            
LDX #0            
SEC               
LDA (<S1),Y       
SBC <POS          
BCC CPY1          
;**NULLSTRING!    
TAX               
INX               
CPX <LEN          
BCC CPY1          
LDX <LEN          
;                 
CPY1 TXA          
STA (<T),Y        
BEQ CPY4          
;-->FERTIG        
;                 
CLC               
LDA <S1           
ADC <POS          
STA <S1           
BCC CPY2          
INC <S1+1         
CPY2              
;                 
;X=LAENGE >0      
;Y=0              
;                 
CPY3 LDA (<S1),Y  
INY               
STA (<T),Y        
DEX               
BNE CPY3          
;                 
CPY4 JMP MKSTR    
;-----------------
POS               
;POS(S1,S2)       
;                 
JSR GETSTR        
STA <S2           
STX <S2+1         
JSR POP2          
JSR GETSTR        
STA <S1           
STX <S1+1         
;(Y=0)            
STY <POS          
LDA (<S1),Y       
STA <LENS1        
LDA (<S2),Y       
TAX               
;                 
POS1              
;** X=LEN(S2)     
;** (RESTSTRING)  
INC <POS          
CPX <LENS1        
BCC POS5          
;--> ZU KURZ      
;                 
;VERGLEICHE BIS   
;UNTERSCHIED:     
LDY #1            
POS2 LDA (<S1),Y  
CMP (<S2),Y       
BNE POS3          
INY               
BNE POS2          
;                 
POS3  DEY         
INC <S2           
BNE POS4          
INC <S2+1         
POS4 DEX          
CPY <LENS1        
BCC POS1          
;** GEFUNDEN!     
;                 
LDA <POS          
DFD $2C           
POS5 LDA #0       
; A=LEN           
JMP LEN1          
;-----------------
CCT               
;CONCAT (S1 + S2) 
;WEGEN UEBER-     
;LAPPUNG VON S2   
;MUSS VORWAERTS   
;ODER RUECKWAERTS 
;KOPIERT WERDEN   
;                 
JSR GETSTR        
STA <S2           
STX <S2+1         
JSR POP2          
JSR GETSTR        
STA <S1           
STX <S1+1         
LDA (<S2),Y       
PHA               
;**NEUE LAENGE    
;**BESTIMMEN      
CLC               
LDA (<S1),Y       
STA <LENS1        
ADC (<S2),Y       
BCS STR.OVR       
STA <NEWLEN       
;LAGE VON S2      
;BERECHNEN:       
LDA <T            
ADC <LENS1        
STA <TP+4         
LDY <T+1          
BCC CCT0          
INY               
CCT0 STY <TP+5    
;* (TP+4)>=(S2)? *
CMP <S2           
TYA               
SBC <S2+1         
BCS CCT2          
;* NEIN: VORWAERTS
LDY #1            
PLA               
BEQ CCT8          
TAX               
;                 
CCT1 LDA (<S2),Y  
STA (<TP+4),Y     
INY               
DEX               
BNE CCT1          
BEQ CCT8          
;*JA: VON HINTEN  
CCT2 PLA          
BEQ CCT8          
TAY               
CCT3 LDA (<S2),Y  
STA (<TP+4),Y     
DEY               
BNE CCT3          
;                 
CCT8              
;KOPIERE S1       
LDY #0            
LDX <LENS1        
LDA <NEWLEN       
INX               
CCT9 STA (<T),Y   
INY               
LDA (<S1),Y       
DEX               
BNE CCT9          
JMP MKSTR         
;-----------------
STR.OVR           
LDA #5            
JMP ERROR         
;-----------------
INS               
;(MAXLEN)         
;INSERT(S1,V,POS) 
;                 
JSR GETNOT0       
STX <POS          
JSR GETSTR        
STA <S2           
STX <S2+1         
JSR POP2          
JSR GETSTR        
STA <S1           
STX <S1+1         
JSR POP2          
;(Y=0)            
LDA (<S2),Y       
STA <OLDLEN       
;                 
LDA (<S1),Y       
STA <LENS1        
BEQ INS6          
;--> FERTIG       
;                 
;*LAENGE PRUEFEN  
;*UND SCHREIBEN   
CLC               
ADC <OLDLEN       
BCS STR.OVR       
STA <NEWLEN       
STA (<S2),Y       
;(Y=0)            
JSR PASFET        
CMP <NEWLEN       
BCC STR.OVR       
;* POSITION HINTER
;* DEM STRINGENDE?
LDA <OLDLEN       
CMP <POS          
BCS INS2          
;** POS>OLDLEN  **
;KEINE VERSCHIE-  
;BUNG ERFORDERLICH
TAX               
INX               
STX <POS          
BNE INS3          
;                 
;LUECKE MACHEN:   
INS2              
LDY <OLDLEN       
LDA (<S2),Y       
LDY <NEWLEN       
STA (<S2),Y       
DEC <NEWLEN       
LDY <OLDLEN       
DEC <OLDLEN       
CPY <POS          
BNE INS2          
;                 
;<S1 AB <POS IN   
;<S2 KOPIEREN     
INS3 CLC          
LDA <S2           
ADC <POS          
STA <S2           
BCC INS4          
INC <S2           
INS4              
;                 
LDY <LENS1        
INS5 LDA (<S1),Y  
DEY               
STA (<S2),Y       
TYA               
BNE INS5          
;                 
INS6 JMP NEXT1    
;-----------------
DEL               
;DELETE(V,POS,LEN)
;                 
JSR GETVAL        
STX <LEN          
;                 
JSR GETNOT0       
STX <POS          
JSR GETSTR        
STA <S1           
STX <S1+1         
JSR POP2          
;                 
LDA (<S1),Y       
STA <OLDLEN       
CMP <POS          
BCC DELX          
;--> FERTIG       
;                 
LDA <LEN          
BEQ DELX          
;--> FERTIG       
CLC               
ADC <POS          
STA <NEWPOS       
;                 
;*NACH LINKS      
;*ZUSAMMENSCHIEBEN
DEL1              
LDY <NEWPOS       
CPY <OLDLEN       
BCC DEL2          
BNE DEL3          
DEL2 LDA (<S1),Y  
LDY <POS          
STA (<S1),Y       
INC <POS          
INC <NEWPOS       
BNE DEL1          
;                 
DEL3 LDX <POS     
DEX               
TXA               
LDY #0            
STA (<S1),Y       
;                 
DELX JMP NEXT0    
;-----------------
STRCMP            
;(MASKE)          
;BIT:       210   
;BEDEUTUNG: <=>   
;VERGLEICH S1-S2  
;                 
JSR GETSTR        
STA <S2           
STX <S2+1         
JSR POP2          
JSR GETSTR        
STA <S1           
STX <S1+1         
;                 
LDA (<S1),Y       
STA <LENS1        
LDA (<S2),Y       
STA <LEN          
;                 
CPS1 INY          
BEQ CPS.EQU       
LDA (<S1),Y       
CMP (<S2),Y       
BEQ CPS1          
;                 
PHP               
DEY               
CPY <LENS1        
BCC CPS2          
;**HINTER S1      
CPY <LEN          
;**HINTER S2?     
BCS CPS.EQU       
BCC CPS.LSS       
;                 
CPS2 CPY <LEN     
BCS CPS.GTR       
;**BEIDE INNERHALB
PLP               
PHP               
BCS CPS.GTR       
;                 
CPS.LSS LDA #1    
DFD $2C           
CPS.GTR LDA #4    
DFD $2C           
CPS.EQU LDA #2    
PLP               
;A=MASKE ERGEBNIS 
JMP VGL3          
;-----------------
STRMOV            
;(MAXLEN)         
JSR GETSTR        
STA <TP           
STX <TP+1         
JSR POP2          
;(Y=0)            
JSR UABS          
;(Y=1)            
DEY               
JSR PASFET        
CMP (<TP),Y       
BCS STRMOV1       
JMP STR.OVR       
;                 
STRMOV1           
LDA (<TP),Y       
TAX               
INX               
STRMOV2           
LDA (<TP),Y       
STA (<B1),Y       
INY               
DEX               
BNE STRMOV2       
JSR POP2          
JMP NEXT1         
;-----------------
LDSTR             
;(MAXLEN)         
;RESERVIERE PLATZ 
;FUER MAX. STRING 
;FALLS NUR ADRESSE
;VORHANDEN, STRING
;LADEN, TEST AUF  
;UEBERSCHREITUNG  
;VON MAXLEN       
INY               
LDA (<T),Y        
PHP               
JSR GETSTR        
;(Y=0)            
STA <B1           
STX <B1+1         
LDA (<B1),Y       
STA <TP           
PLP               
BEQ LDSTR2        
TAX               
;** AUFWAERTS     
;** KOPIEREN:     
INX               
LDSTR1 LDA (<B1),Y
STA (<T),Y        
INY               
DEX               
BNE LDSTR1        
                  
LDSTR2 LDY #0     
JSR PASFET        
CMP <TP           
BCS LDSTR3        
LDA #5            
JMP ERROR         
;                 
LDSTR3 SEC        
SBC #1            
JSR ALLOC         
JMP NEXT1         
;-----------------
LDCHSTR           
;CHAR -> STRING;  
LDA (<T),Y        
INY               
STA (<T),Y        
TYA               
DEY               
STA (<T),Y        
JMP MKSTR         
;-----------------
LDARSTR           
;(LEN)            
;ARRAY OF CHAR    
;-->STRING        
JSR PASFET        
TAX               
JSR UABS          
DEY               
TXA               
INX               
LDARSTR1          
STA (<T),Y        
LDA (<B1),Y       
INY               
DEX               
BNE LDARSTR1      
INC <P            
BNE LDARSTR2      
INC <P+1          
LDARSTR2 JMP MKSTR
;=================
ENDMOD3           
;=================
EXP SRL,SRS,SR0,  
SRA,LRL,LRS,LR0,  
LRA,LRC,FLT,FLO,  
INT,MON,DYA,VGL,  
NUL,LSA,SSA,GS1,  
GS2,UNI,DIF,ISC,  
SEQ,SLE,SGE,INN,  
UINT,FACVAR,      
LDFAC,TRC,RND,    
MKSTR,GETSTR,     
LEN,COPY,POS,CCT, 
INS,DEL,STRCMP,   
STRMOV,LDSTR,     
LDCHSTR,LDARSTR,  
ENDMOD3           
;                 
END