;=================
;    PAS.MOD2     
; VERSION  C-128  
;                 
;PROGRAMMABLAUF-  
;STEUERUNG        
;OPERATIONEN FUER 
;SKALARE TYPEN    
;(NICHT REAL)     
;=================
;                 
;30.8.1986        
;                 
IMP PAS.SYST      
IMP PAS.MOD1      
;                 
;=================
ORG ENDMOD1       
;                 
;=================
STL               
;L/H (LVL)        
JSR SUMP          
;(Y=1)            
LDA (<T),Y        
STA (<B1),Y       
STL9 DEY          
LDA (<T),Y        
STA (<B1),Y       
JSR POP2          
JMP NEXT3         
;-----------------
SBL               
;L/H (LVL)        
JSR SUMP          
;(Y=1)            
JMP STL9          
;-----------------
STS               
;STACK (LVL)      
JSR POP2          
JSR SUMT          
JSR POP2          
LDY #5            
LDA (<T),Y        
LDY #1            
STA (<B1),Y       
STS9 LDY #4       
LDA (<T),Y        
LDY #0            
STA (<B1),Y       
JMP NEXT1         
;-----------------
SBS               
;STACK (LVL)      
JSR POP2          
JSR SUMT          
JSR POP2          
JMP STS9          
;-----------------
ST0               
;L/H (LVL=0)      
JSR SUMB          
;(Y=1)            
LDA (<T),Y        
STA (<B1),Y       
DEY               
ST09 LDA (<T),Y   
STA (<B1),Y       
JSR POP2          
JMP NEXT2         
;-----------------
SB0               
;L/H (LVL=0)      
JSR SUMB          
;(Y=1)            
DEY               
BEQ ST09          
;-----------------
ST                
; ABSOLUT         
JSR POP2          
JSR UABS          
LDY #3            
LDA (<T),Y        
LDY #1            
STA (<B1),Y       
ST9               
; (Y=1)           
INY               
LDA (<T),Y        
LDY #0            
STA (<B1),Y       
JSR POP2          
JMP NEXT0         
;-----------------
SB                
; ABSOLUT         
JSR POP2          
JSR UABS          
;(Y=1)            
JMP ST9           
;-----------------
LDL               
;L/H (LVL)        
JSR SUMP          
JSR UCOPYA        
JMP NEXT3         
;-----------------
LDS               
;STACK (LVL)      
JSR SUMT          
;(Y=1)            
JSR UCOPY         
JMP NEXT1         
;-----------------
LD0               
;L/H (LVL=0)      
JSR SUMB          
JSR UCOPYA        
JMP NEXT2         
;-----------------
LD                
;ABSOLUT          
JSR UABS          
JSR UCOPY         
JMP NEXT0         
;=================
UCOPYBA JSR AL2   
UCOPYB            
;YR MUSS 1 SEIN   
LDA #0            
STA (<T),Y        
DEY               
LDA (<B1),Y       
STA (<T),Y        
RTS               
;                 
LBL               
;L/H (LVL)        
JSR SUMP          
JSR UCOPYBA       
JMP NEXT3         
;-----------------
LBS               
;STACK (LVL)      
JSR SUMT          
;(Y=1)            
JSR UCOPYB        
JMP NEXT1         
;-----------------
LB0               
;L/H (LVL=0)      
JSR SUMB          
JSR UCOPYBA       
JMP NEXT2         
;-----------------
LB                
;ABSOLUT          
JSR UABS          
JSR UCOPYB        
JMP NEXT0         
;=================
LDC               
; L/H             
JSR AL2           
JSR PASFET        
STA (<T),Y        
DEY               
JSR PASFET        
STA (<T),Y        
JMP NEXT2         
;-----------------
LCB               
; L               
JSR AL2           
DEY               
JSR PASFET        
STA (<T),Y        
TYA               
INY               
STA (<T),Y        
JMP NEXT1         
;-----------------
LC0               
;                 
JSR AL2           
LDA #0            
STA (<T),Y        
DEY               
STA (<T),Y        
JMP NEXT0         
;-----------------
HBY               
;HBYTE            
INY               
LDA (<T),Y        
PHA               
LDA #0            
STA (<T),Y        
DEY               
PLA               
STA (<T),Y        
JMP NEXT0         
;-----------------
POP               
;                 
JSR POP2          
JMP NEXT0         
;-----------------
ALC               
;L/H              
CLC               
JSR PASFET        
ADC <T            
STA <T            
INY               
JSR PASFET        
ADC <T+1          
STA <T+1          
CMP <TOP+1        
BCC ALC1          
JMP STACKO        
ALC1 JMP NEXT2    
;-----------------
FDL               
;L/H (LVL)        
LDY #2            
JSR UBASE         
JSR AL2           
DEY               
CLC               
JSR PASFET        
ADC <B1           
STA (<T),Y        
INY               
JSR PASFET        
ADC <B1+1         
STA (<T),Y        
JMP NEXT3         
;-----------------
FDS               
;STACK (LVL)      
LDY #0            
JSR UBASE         
CLC               
LDA (<T),Y        
ADC <B1           
STA (<T),Y        
INY               
LDA (<T),Y        
ADC <B1+1         
STA (<T),Y        
JMP NEXT1         
;-----------------
FD0               
;L/H              
JSR AL2           
DEY               
CLC               
JSR PASFET        
ADC <B            
STA (<T),Y        
INY               
JSR PASFET        
ADC <B+1          
STA (<T),Y        
JMP NEXT2         
;-----------------
JCD               
;L/H              
JSR POP2          
LDY #2            
LDA (<T),Y        
BEQ JCD1          
LDY #0            
BEQ JUMP          
JCD1 JMP NEXT2    
;-----------------
JNC               
;L/H              
JSR POP2          
LDY #2            
LDA (<T),Y        
BNE JCD1          
TAY               
;-----------------
JP                
;UNBED. SPRUNG    
;(Y IST 0)        
;- - - - - - - - -
JUMP              
;SPRUNG AN DIE    
;DURCH (<P),Y     
;INDIZIERTE POS.  
;                 
JSR PASFET        
TAX               
INY               
JSR PASFET        
STA <P+1          
STX <P            
JMP NEXT0         
;-----------------
JML               
;SPRUNG MIT LVL-  
;ANPASSUNG        
;STACKPOINTER :=  
;BASE             
LDY #2            
JSR UBASE         
;(Y=0)            
LDA <B1           
STA <B            
STA <T            
LDA <B1+1         
STA <B+1          
STA <T+1          
JMP JUMP          
;-----------------
JMC               
;VERGLEICHE DIE   
;KONSTANTEN:      
;                 
LDA (<T),Y        
STA <B1           
INY               
LDA (<T),Y        
STA <B1+1         
INY               
JSR PASFET        
ASL               
;C=0              
ADC #2            
TAX               
TAY               
JMC1 JSR PASFET   
CMP <B1+1         
BNE JMC2          
DEY               
JSR PASFET        
CMP <B1           
BNE JMC3          
INX               
TXA               
JMP NEXT          
;                 
JMC2 DEY          
JMC3 CPY #3       
BNE JMC1          
LDY #0            
JMP JUMP          
;-----------------
FOR1              
;L/H DIRECTION    
;                 
LDY #2            
JSR PASFET        
LDY #0            
TAX               
BNE FOR1UP        
;**DOWNTO         
JSR ULS           
BMI FORX          
BPL FORCONT       
;                 
FOR1UP            
;**TO             
JSR UGT           
BMI FORX          
;**WEITER:        
;**DUPLIZIERE     
;**DEN ZAEHLWERT  
FORCONT LDY #0    
LDA (<T),Y        
LDY #4            
STA (<T),Y        
LDY #1            
LDA (<T),Y        
LDY #5            
STA (<T),Y        
JSR AL4           
JMP NEXT3         
;                 
FORX JSR POP2     
LDY #0            
JMP JUMP          
;-----------------
LBYTE DFD 255,1   
HBYTE DFD 255,0   
; (-1,+1)         
FOR2              
;L/H DIRECTION    
;                 
LDY #2            
JSR PASFET        
TAX               
SEC               
LDA <T            
SBC #2            
STA <TP           
LDA <T+1          
SBC #0            
STA <TP+1         
;                 
CLC               
LDY #0            
LDA (<TP),Y       
ADC LBYTE,X       
STA (<TP),Y       
INY               
LDA (<TP),Y       
ADC HBYTE,X       
STA (<TP),Y       
DEY               
JMP JUMP          
;-----------------
MST               
;MARK STACK       
LDA #<HEAD        
JSR ALLOC         
JMP NEXT0         
;-----------------
CUP               
;L/H LVL          
;CALL USER-PROC.  
;<TP INDIZIERT DEN
;SEGMENTDESCRIPOR 
;<T  OBERHALB DER 
;PARAMETER        
;<P  ->UPRO-ANFANG
;                 
LDA <P+1          
PHA               
LDA <P            
PHA               
LDY #2            
JSR UBASE         
;(NACH <B1)       
;(YR=0)           
JSR PASFET        
TAX               
INY               
JSR PASFET        
STX <P            
STA <P+1          
DEY               
;(YR=0)           
;>>> GEAENDERT <<<
;BERECHNE ADRESSE:
; <T - (<P),Y     
SEC               
JSR PASFET        
EOR #$FF          
ADC <T            
STA <TP           
INY               
JSR PASFET        
EOR #$FF          
ADC <T+1          
STA <TP+1         
;*STATIC LINK:    
LDY #<SL          
LDA <B1           
STA (<TP),Y       
INY               
LDA <B1+1         
STA (<TP),Y       
;*DYNAMIC LINK:   
INY               
LDA <B            
STA (<TP),Y       
INY               
LDA <B+1          
STA (<TP),Y       
;*RETURN ADDRESS: 
INY               
PLA               
STA (<TP),Y       
INY               
PLA               
STA (<TP),Y       
LDA <TP           
STA <B            
LDA <TP+1         
STA <B+1          
JMP NEXT2         
;-----------------
RPR               
;RUECKKEHR VON    
;PROZEDUR/FUNKTION
;                 
LDA <B            
STA <T            
LDA <B+1          
STA <T+1          
;- - - - - - - - -
REST              
;LOESCHE SEGMENT  
;(FOLGE DL)       
LDY #<RA+1        
LDA (<B),Y        
STA <P+1          
DEY               
LDA (<B),Y        
STA <P            
DEY               
LDA (<B),Y        
TAX               
DEY               
LDA (<B),Y        
STA <B            
STX <B+1          
;WEIL AUFRUF UEBER
;CALL (3 BYTES):  
JMP NEXT3         
;-----------------
ERR               
;ERR N            
JSR PASFET        
JMP ERROR         
;-----------------
TST               
;BEREICHSTEST     
;FUER TOS         
;TOS>=UG  UND     
;OG >=TOS         
JSR PASFET        
STA <TP           
LDA (<T),Y        
CMP <TP           
INY               
JSR PASFET        
STA <TP           
LDA (<T),Y        
SBC <TP           
BVC TST1          
EOR #$80          
TST1 BMI TST9     
INY               
JSR PASFET        
LDY #0            
CMP (<T),Y        
LDY #3            
JSR PASFET        
LDY #1            
SBC (<T),Y        
BVC TST2          
EOR #$80          
TST2 BMI TST9     
JMP NEXT4         
TST9              
;X:=0, SO DASS DIE
;WERTE TOS,UG,OG  
;AUSGEGEBEN WERDEN
LDX #0            
LDA #6            
JMP ERROR1        
;=================
ADD               
;                 
JSR POP2          
CLC               
LDY #2            
LDA (<T),Y        
LDY #0            
ADC (<T),Y        
STA (<T),Y        
LDY #3            
LDA (<T),Y        
LDY #1            
ADC (<T),Y        
STA (<T),Y        
BVS SUB1          
ADD1 JMP NEXT0    
;-----------------
ADU               
;ADD UNSIGNED OHNE
;OVERFLOW TEST    
JSR POP2          
CLC               
LDY #2            
LDA (<T),Y        
LDY #0            
ADC (<T),Y        
STA (<T),Y        
LDY #3            
LDA (<T),Y        
LDY #1            
ADC (<T),Y        
STA (<T),Y        
JMP NEXT0         
;-----------------
SUB               
;                 
JSR POP2          
SEC               
LDA (<T),Y        
LDY #2            
SBC (<T),Y        
LDY #0            
STA (<T),Y        
INY               
LDA (<T),Y        
LDY #3            
SBC (<T),Y        
LDY #1            
STA (<T),Y        
BVC ADD1          
SUB1 JMP OVERFL   
;-----------------
UVORZ             
;LAEDT ARGUMENTE  
;BILDET ABSOLUT-  
;BETRAEGE DER     
;ARGUMENTE        
;<TP+4 ZAEHLT DIE 
;      VZWECHSEL  
;<TP+5 VORZEICHEN 
;      ARG1       
;(YR:=0)          
JSR POP2          
LDY #3            
VORZ0 LDA (<T),Y  
;=================
;STA <TP,Y        
DFD $99,<TP,0     
;=================
DEY               
BPL VORZ0         
INY               
LDX #0            
LDA <TP+1         
STA <TP+5         
BPL VORZ1         
SEC               
TYA               
SBC <TP           
STA <TP           
TYA               
SBC <TP+1         
STA <TP+1         
INX               
VORZ1 LDA <TP+3   
BPL VORZ2         
SEC               
TYA               
SBC <TP+2         
STA <TP+2         
TYA               
SBC <TP+3         
STA <TP+3         
INX               
VORZ2 STX <TP+4   
RTS               
;-----------------
MUL               
;                 
JSR UVORZ         
STY <TP+6         
STY <TP+7         
LDX #16           
MUL0              
LSR <TP+1         
ROR <TP           
BCC MUL2          
CLC               
LDA <TP+6         
ADC <TP+2         
STA <TP+6         
LDA <TP+7         
ADC <TP+3         
STA <TP+7         
BVC MUL2          
MUL1 JMP OVERFL   
MUL2 ASL <TP+2    
ROL <TP+3         
BPL MUL3          
LDA <TP           
ORA <TP+1         
BNE MUL1          
BEQ DIV0          
MUL3 DEX          
BNE MUL0          
BEQ DIV0          
;-----------------
DIVMOD            
;DIVISION MIT     
;REST OHNE        
;VORZEICHEN       
;(YR:=0)          
;                 
JSR UVORZ         
LDA <TP+2         
ORA <TP+3         
BNE DIVMOD1       
JMP DIVISI        
DIVMOD1           
LDA <TP           
STY <TP           
ASL               
STA <TP+6         
LDA <TP+1         
STY <TP+1         
ROL               
STA <TP+7         
LDX #16           
DIVMOD2           
ROL <TP           
ROL <TP+1         
SEC               
LDA <TP           
SBC <TP+2         
TAY               
LDA <TP+1         
SBC <TP+3         
BCC DIVMOD3       
STY <TP           
STA <TP+1         
DIVMOD3           
ROL <TP+6         
ROL <TP+7         
DEX               
BNE DIVMOD2       
LDY #0            
RTS               
;-----------------
DIV               
;                 
JSR DIVMOD        
DIV0  ROR <TP+4   
BCC DIV1          
TYA               
SBC <TP+6         
STA <TP+6         
TYA               
SBC <TP+7         
STA <TP+7         
DIV1 LDA <TP+6    
STA (<T),Y        
INY               
LDA <TP+7         
STA (<T),Y        
JMP NEXT0         
;-----------------
MOD               
;                 
JSR DIVMOD        
LDA <TP+5         
BPL MOD1          
SEC               
TYA               
SBC <TP           
STA <TP           
TYA               
SBC <TP+1         
STA <TP+1         
MOD1 LDA <TP      
STA (<T),Y        
INY               
LDA <TP+1         
STA (<T),Y        
JMP NEXT0         
;-----------------
UND               
;AND FUNKTION     
;                 
JSR POP2          
LDY #2            
LDA (<T),Y        
LDY #0            
AND (<T),Y        
STA (<T),Y        
LDY #3            
LDA (<T),Y        
LDY #1            
AND (<T),Y        
STA (<T),Y        
JMP NEXT0         
;-----------------
OR                
;                 
JSR POP2          
LDY #2            
LDA (<T),Y        
LDY #0            
ORA (<T),Y        
STA (<T),Y        
LDY #3            
LDA (<T),Y        
LDY #1            
ORA (<T),Y        
STA (<T),Y        
JMP NEXT0         
;-----------------
INV               
;LOGISCHES NOT    
LDA (<T),Y        
BEQ TRUE          
BNE FALSE         
;-----------------
EQ                
;                 
JSR POP2          
LDA (<T),Y        
LDY #2            
CMP (<T),Y        
BNE FALSE         
DEY               
LDA (<T),Y        
LDY #3            
CMP (<T),Y        
BNE FALSE         
BEQ TRUE          
;-----------------
NE                
;                 
JSR POP2          
LDA (<T),Y        
LDY #2            
CMP (<T),Y        
BNE TRUE          
DEY               
LDA (<T),Y        
LDY #3            
CMP (<T),Y        
BNE TRUE          
BEQ FALSE         
;-----------------
UGT               
; N=1 -> SKND>TOS 
;                 
JSR POP2          
LDY #2            
LDA (<T),Y        
LDY #0            
CMP (<T),Y        
LDY #3            
LDA (<T),Y        
LDY #1            
SBC (<T),Y        
BVC GT1           
EOR #$80          
GT1 RTS           
;-----------------
GT                
;                 
JSR UGT           
BPL FALSE         
;                 
TRUE LDA #1       
DFD $2C           
FALSE LDA #0      
LDY #0            
STA (<T),Y        
TYA               
INY               
STA (<T),Y        
JMP NEXT0         
;-----------------
ULS               
;N=1 => SKND>TOS  
JSR POP2          
LDA (<T),Y        
LDY #2            
CMP (<T),Y        
DEY               
LDA (<T),Y        
LDY #3            
SBC (<T),Y        
BVC LS1           
EOR #$80          
LS1 RTS           
;-----------------
LS                
;                 
JSR ULS           
BPL FALSE         
BMI TRUE          
;-----------------
LE                
;                 
JSR POP2          
LDY #2            
LDA (<T),Y        
LDY #0            
CMP (<T),Y        
LDY #3            
LDA (<T),Y        
LDY #1            
SBC (<T),Y        
BVC LE1           
EOR #$80          
LE1 BPL TRUE      
BMI FALSE         
;-----------------
GE                
;                 
JSR POP2          
LDA (<T),Y        
LDY #2            
CMP (<T),Y        
DEY               
LDA (<T),Y        
LDY #3            
SBC (<T),Y        
BVC GE1           
EOR #$80          
GE1 BPL TRUE      
BMI FALSE         
;-----------------
NOT               
;INTEGER NOT      
LDA (<T),Y        
EOR #255          
STA (<T),Y        
INY               
LDA (<T),Y        
EOR #255          
STA (<T),Y        
JMP NEXT0         
;-----------------
ABI               
;                 
INY               
LDA (<T),Y        
BPL CHS1          
DEY               
;- - - - - - - - -
CHS               
;                 
SEC               
TYA               
SBC (<T),Y        
STA (<T),Y        
TYA               
INY               
SBC (<T),Y        
STA (<T),Y        
CHS1 JMP NEXT0    
;                 
;=================
USETTP            
;<TP  :=SECOND    
;<TP+2:=SECOND+LEN
;<TP+4:=TOP       
;(Y:=0)           
JSR POP2          
CLC               
LDA (<T),Y        
STA <TP           
JSR PASFET        
ADC <TP           
STA <TP+2         
INY               
LDA (<T),Y        
STA <TP+1         
JSR PASFET        
ADC <TP+1         
STA <TP+3         
INY               
LDA (<T),Y        
STA <TP+4         
INY               
LDA (<T),Y        
STA <TP+5         
LDY #0            
RTS               
;-----------------
INCT              
;WEITERZAEHLEN    
;(AUCH FUER PUT   
; UND GET)        
INC <TP           
BNE INCT1         
INC <TP+1         
INCT1 INC <TP+4   
BNE INCT2         
INC <TP+5         
INCT2 LDA <TP     
CMP <TP+2         
BNE INCT3         
LDA <TP+1         
CMP <TP+3         
INCT3 RTS         
;-----------------
MOV               
;(LEN)            
JSR USETTP        
JSR POP2          
MOV1              
LDA (<TP+4),Y     
STA (<TP),Y       
JSR INCT          
BNE MOV1          
JMP NEXT2         
;-----------------
NEW;              
;LAENGE->ADRESSE  
SEC               
LDA <TOP          
SBC (<T),Y        
STA (<T),Y        
STA <TOP          
INY               
LDA <TOP+1        
SBC (<T),Y        
STA (<T),Y        
STA <TOP+1        
CMP <T+1          
BCC NEW1          
BEQ NEW1          
JMP NEXT0         
NEW1 LDA #4       
JMP ERROR         
;=================
ENDMOD2           
;=================
;                 
EXP STL,STS,ST0,  
ST,LDL,LDS,LD0,LD,
SBL,SBS,SB0,      
SB,LBL,LBS,LB0,LB,
LDC,LCB,LC0,HBY,  
POP,ALC,          
FDL,FDS,FD0,      
JCD,JNC,JP,JML,   
JMC,MST,CUP,RPR,  
ERR,TST,FOR1,FOR2,
ADD,ADU,SUB,MUL,  
DIV,MOD,UND,OR,   
INV,EQ,NE,GT,LS,  
LE,GE,NOT,ABI,    
CHS,MOV,NEW,      
TRUE,FALSE,INCT,  
ENDMOD2           
;                 
END