;=================
;    PAS.BOOT     
; VERSION  C-128  
;                 
;INITIALISIERUNG  
;INTERPRETER IN   
;BANK 0           
;=================
;                 
;25.9.1986        
;U1: 1.7.1989     
;                 
;=================
IMP PAS.SYST      
IMP PAS.MOD1      
;(NUR INIT)       
;                 
ORG $1C01         
;(BASIC-START)    
;(IN BANK 0)      
;=================
;                 
;  GRAPHICCLR:    
;  BANK0:         
;  SYS (BOOT)     
;  FUER BASIC     
;  U1: >>>>       
DFD LLINK,1986    
DFD $DE,$9C,":"   
DFD $FE,$02,"0:"  
DFD $9E,"7200:"  
DFD "PASCAL 2.1",0
LLINK DFD 0,0     
;=================
BOOT              
LDA PASFET+6      
CMP #<P           
BEQ BOOT0         
;- - - - - - - - -
;*ROM EINBLENDEN  
;*PAS.LIB LADEN   
LDA #1            
;*NACH BANK1 LADEN
LDX #0            
STX MMUCR         
;*DATEINAME BANK0 
JSR SETBNK        
LDA #7            
LDX #[NAME        
LDY #]NAME        
JSR SETNAM        
LDA #0            
LDX #8            
LDY #1            
JSR SETLFS        
; A=0, DAHER LOAD 
LDX #[BASE        
LDY #]BASE        
JSR LOAD          
BCS BOOT7         
;- - - - - - - - -
BOOT0             
;                 
;STRINGKONSTANTEN 
;KOPIEREN         
;(BANK0 ->BANK1)  
;                 
STA LCRA          
LDY #0            
LDA #<T           
STA FETVEC        
LDA #<TP          
STA STAVEC        
;* ANFANG IN BANK0
LDA AKONST        
STA <T            
LDA AKONST+1      
STA <T+1          
;* ANFANG IN BANK1
LDA ZKONST        
STA <TP           
LDA ZKONST+1      
STA <TP+1         
;* KOPIERE        
BOOT1             
LDA <T            
CMP EKONST        
BNE BOOT2         
LDA <T+1          
CMP EKONST+1      
BEQ BOOT4         
;                 
BOOT2             
LDX #<BANK0       
JSR FETCH         
LDX #<BANK1       
JSR STASH         
;                 
INC <TP           
BNE BOOT3         
INC <TP+1         
BOOT3 INC <T      
BNE BOOT1         
INC <T+1          
BNE BOOT1         
;                 
BOOT4             
;* SPRUNG ZU INIT 
LDA #[INIT        
LDY #]INIT        
;*SPRUNG IN BANK 1
STA <FARPC+1; L!  
STY <FARPC;   H!  
LDA #[PCODE       
STA <FARA         
LDA #]PCODE       
STA <FARY         
;* START PCODE    
LDA #<BANK0       
;* BANK0 PCODE    
STA <FARX         
LDA #1            
;* BANK1 INIT     
STA <FARCNF       
STA LCRC          
JSR JSRFAR        
;-----------------
BOOT7             
STA LCRC          
JSR PRIMM         
DFD 7,13,"'"     
NAME              
DFD "PAS.LIB'"    
DFD " NOT FOUND " 
DFD "ON DISK!"    
DFD 13,0          
;                 
LDX #$80          
JMP (ERRPTR)      
;-----------------
ORGPC             
AKONST EQU ORGPC  
EKONST EQU ORGPC+2
ZKONST EQU ORGPC+4
PCODE  EQU ORGPC+6
;-----------------
EXP BOOT,ORGPC    
;                 
END