;-----------------
;    SCANNER      
; FUER DEN C-128  
;                 
;6.9.1986         
;                 
ORG $F7B0         
;(IN BANK 1)      
;-----------------
;                 
IMP PAS.SYST      
IMP PAS.MOD1      
;(UCALLF,XBSOUT)  
IMP PAS.MOD3      
;(FACVAR,UINT)    
;                 
LINE     EQU $FF45
ORGSRC   EQU 5130 
;(AUS SCR.SYST.S) 
;-----------------
;                 
;KONSTANTEN       
;                 
<ANFZ    EQU 34   
;GAENSEFUESSCHEN  
<HOCHK   EQU "'"  
;                 
<ALEN    EQU 13   
;LAENGE BEZEICHNER
;UND VAIRABLE ID  
<INFILE  EQU 2    
;LOG. FILENUMMER  
<OUTFILE EQU 3    
;LOG. FILENUMMER  
;-----------------
;                 
;Z-PAGE VARIABLEN 
;                 
<ZEIG    EQU $FC  
;WAEHREND DES     
;PROGRAMMES ZEIGER
;AUF SOURCE IM RAM
<CODE    EQU <TP  
<XREG    EQU <TP+1
;-----------------
;                 
;PASCALVARIABLEN  
;                 
NUMBER  DFD 0,0   
ZNR     DFD 0,0   
;ZEILENNUMMER     
;RELATIV ZUM      
;LFD. FILEANFANG  
CHAR    DFD 0,0   
POSI    DFD 0,0   
;FUER TABELLEN-   
;SUCHE (UPOSI)    
FLOAT             
DFD 0,0,0,0,0     
ID                
DFD 0,0,0,0,0,0   
DFD 0,0,0,0,0,0   
DFD 0,0,0         
;[0..ALEN]        
;                 
INDEX   DFD 0     
;ZEIGER AUF LFD.  
;ZEICHEN (ANZEIGE 
;FEHLERPOSITION)  
LBYTE   DFD 0     
HBYTE   DFD 0     
;                 
TSTFLG  DFD 0,0   
PARTST  DFD 0,0   
CHAIN   DFD 0,0   
;-----------------
;                 
;LOKALE VARAIBLEN 
;                 
XL      DFD 0     
;SATZLAENGE AUF   
;DEM LFD. FILE    
LAST    DFD 0,0   
;LETZTE ZEILE IM  
;RAM              
ZNR1    DFD 0,0   
;ZEILENNUMMER IM  
;RAM              
XL1     DFD 0     
;ZEILENLAENGE DES 
;DATASET IM RAM   
MEDIUM  DFD 0     
;0=>RAM,SONST FILE
;-----------------
KEYWORD           
DFD "ÁNDÁRRAY"    
DFD "ÂEGINÃASE"   
DFD "ÃONSTÄIVÄO"  
DFD "ÄOWNTOÅLSE"  
DFD "ÅNDÆILEÆOR"  
DFD "ÆORWARD"     
DFD "ÆUNCTION"    
DFD "ÇOTOÉFÉN"    
DFD "ÌABELÍODÎIL" 
DFD "ÎOTÏFÏR"     
DFD "ÐACKED"      
DFD "ÐROCEDURE"   
DFD "ÐROGRAM"     
DFD "ÒECORDÒEPEAT"
DFD "ÓETÔHENÔO"   
DFD "ÔYPEÕNTIL"   
DFD "ÖAR×HILE"    
DFD "×ITH"        
DFD 255           
;                 
KMMENT  DFD "RPC" 
<NKOMM  EQU 2     
;                 
SUFFIX            
DFD ",P,R",0      
;-----------------
XCLRCHN           
LDA #[CLRCHN      
LDY #]CLRCHN      
JMP UAYCALLF      
;-----------------
XBASIN            
LDA #[BASIN       
LDY #]BASIN       
;- - - - - - - - -
UAYCALLF          
;ROUTINE A/Y IM   
;ROM AUFRUFEN     
STA <FARPC+1      
STY <FARPC        
JMP UCALLF        
;-----------------
UTEST             
;C=1-> BUCHSTABE  
;      ODER ZAHL  
;                 
CMP #"["          
BCS TEST1         
CMP #"A"          
BCS TEST2         
;- - - - - - - - -
UTEST09           
;C=1-> ZAHL       
CMP #":"          
BCS TEST1         
CMP #"0"          
RTS               
TEST1 CLC         
TEST2 RTS         
;-----------------
GET1CHAR          
;HOLE DAS 1.      
;ZEICHEN DER      
;FOLGEZEILE       
JSR ULES          
LDX #255          
;- - - - - - - - -
GETCHAR           
;HOLE DAS NAECHSTE
;ZEICHEN          
;                 
INX               
;- - - - - - - - -
GET0CHAR          
;HOLE DAS LAUFENDE
;ZEICHEN          
;                 
LDA LINE,X        
BEQ GET1CHAR      
CMP #255          
BEQ ABORT         
RTS               
;* VERMEIDE LOOPS 
;* AM SOURCE-ENDE 
ABORT PLA         
PLA               
LDA #255          
JMP GETSA         
;                 
;-----------------
ULESRAM           
;HOLE NAECHSTES   
;ZEICHEN AUS DEM  
;SPEICHER         
LDX #<BANK0       
LDA #<ZEIG        
STA FETVEC        
JMP FETCH         
;-----------------
USKIP5            
LDA #5            
BNE SKIP0         
;- - - - - - - - -
USKIP             
;UEBERSPRINGE EINE
;ZEILE IM RAM     
LDA XL1           
SKIP0 CLC         
ADC <ZEIG         
STA <ZEIG         
BCC SKIP1         
INC <ZEIG+1       
SKIP1 RTS         
;-----------------
UINIT             
;<--- PASCAL      
;HOLE 1. SYMBOL   
;VOM BASIC-TEXT,  
;DER IN BANK 0    
;AB (ORGSRC) STEHT
;                 
LDY #0            
STY MEDIUM        
STY TSTFLG        
LDA #255          
STA ZNR1          
STA ZNR1+1        
LDA #[ORGSRC      
STA <ZEIG         
LDA #]ORGSRC      
STA <ZEIG+1       
JSR ULESRAM       
PHA               
INY               
JSR ULESRAM       
STA <ZEIG+1       
PLA               
STA <ZEIG         
DEY               
;(Y=0)            
JSR ULESRAM       
STA XL1           
INY               
STY PARTST        
STY CHAIN         
;                 
JSR ULESRAM       
STA LAST          
INY               
JSR ULESRAM       
STA LAST+1        
JSR USKIP5        
JSR USKIP         
JSR USKIP         
JSR USKIP         
;- - - - - - - - -
GET1SYM           
;HOLE 1. SYMBOL   
;DER FOLGEZEILE   
LDA #0            
STA LINE          
STA INDEX         
;- - - - - - - - -
GETSYM            
;<--- PASCAL      
;HOLE DAS NAECHSTE
;SYMBOL IM TEXT   
;                 
LDX INDEX         
GETS1             
;                 
JSR GET0CHAR      
CMP #" "          
BNE GETS3         
INX               
BNE GETS1         
;                 
GETS3 JSR UTEST   
BCC GETS31        
JMP GETS4         
;                 
;SONDERZEICHEN:   
;                 
GETS31 CMP #<ANFZ 
BEQ SONDER1       
CMP #<HOCHK       
BNE SONDER2       
SONDER1           
;STRING BIS A     
;ODER ZEILENENDE  
;LESEN            
STA <CODE         
TXA               
SEC               
ADC #[LINE        
STA NUMBER        
LDA #]LINE        
ADC #0            
STA NUMBER+1      
LDY #255          
STRNG0 INX        
INY               
LDA LINE,X        
BEQ STRNG1        
CMP <CODE         
BNE STRNG0        
DFD $2C           
STRNG1 LDY #255   
STY ID            
LDA #251          
INX               
JMP GETSA         
;                 
SONDER2           
CMP #":"          
BNE SONDER3       
LDA LINE+1,X      
CMP #"="          
BNE SONDERF       
LDA #170          
BNE SONDERR       
SONDER3 CMP #"<"  
BNE SONDER5       
LDA LINE+1,X      
CMP #"="          
BNE SONDER4       
LDA #171          
BNE SONDERR       
SONDER4 CMP #">"  
BNE SONDERF       
LDA #172          
BNE SONDERR       
SONDER5 CMP #">"  
BNE SONDER6       
LDA LINE+1,X      
CMP #"="          
BNE SONDERF       
LDA #173          
BNE SONDERR       
SONDER6 CMP #"."  
BNE SONDER7       
LDA LINE+1,X      
CMP #"."          
BNE SONDERF       
LDA #174          
BNE SONDERR       
SONDER7 CMP #"("  
BNE SONDERF       
LDA LINE+1,X      
CMP #"*"          
BEQ KOMMENT       
;                 
SONDERF           
;                 
LDA LINE,X        
INX               
DFD $2C           
;                 
SONDERR           
;                 
INX               
INX               
JMP GETSA         
;                 
KOMMENT           
;AKTIVE KOMMENTARE
;PRUEFEN:         
;                 
INX               
JSR GETCHAR       
CMP #"$"          
BNE KOMMENT9      
KOMMENT0          
JSR GETCHAR       
CMP #<ANFZ        
BNE KOMMENT1      
JMP UXCHNG        
;->INCLUDE FILE   
KOMMENT1          
LDY #<NKOMM       
KOMMENT2          
CMP KMMENT,Y      
BEQ KOMMENT3      
DEY               
BPL KOMMENT2      
BMI KOMMENT9      
;                 
KOMMENT3 TYA      
ASL               
TAY               
JSR GETCHAR       
CMP #"-"          
BNE KOMMENT4      
LDA #0            
BEQ KOMMENT5      
KOMMENT4          
CMP #"+"          
BNE KOMMENT9      
LDA #1            
KOMMENT5          
STA TSTFLG,Y      
JMP KOMMENT0      
;                 
KOMMENT8          
JSR GETCHAR       
KOMMENT9          
CMP #"*"          
BNE KOMMENT8      
LDA LINE+1,X      
CMP #")"          
BNE KOMMENT8      
INX               
INX               
JMP GETS1         
;                 
GETS4 CMP #"A"    
BCC GETS5         
;                 
;BEZEICHNER ODER  
;WORTSYMBOL:      
;                 
STX <XREG         
LDA #128          
STA <CODE         
LDY #0            
LDA KEYWORD,Y     
;                 
WSYM1             
AND #$7F          
WSYM2 CMP LINE,X  
BEQ WSYM4         
BCS WSYM5         
WSYM25 LDX <XREG  
WSYM3 INY         
LDA KEYWORD,Y     
BPL WSYM3         
INC <CODE         
BNE WSYM1         
WSYM4 INX         
INY               
LDA KEYWORD,Y     
BPL WSYM2         
DEX               
DEY               
;*** GLEICH ***   
;FALLS WORT       
;ZU ENDE, <CODE   
;UEBERGEBEN       
;                 
LDA LINE+1,X      
JSR UTEST         
BCS WSYM25        
INX               
LDA <CODE         
BNE GETSA         
;***UNGLEICH***   
;BEZEICHNER NACH  
;ID KOPIEREN      
;                 
WSYM5             
LDX <XREG         
LDA LINE,X        
LDY #0            
BEZ1 CPY #<ALEN+1 
BCS BEZ11         
STA ID,Y          
BEZ11 INY         
INX               
LDA LINE,X        
JSR UTEST         
BCS BEZ1          
LDA #" "          
BEZ13 CPY #<ALEN+1
BCS BEZ14         
STA ID,Y          
INY               
BNE BEZ13         
BEZ14 LDA #252    
BNE GETSA         
;                 
GETS5             
;ZAHLEN MIT ROM-  
;ROUTINEN LESEN   
JSR UZAHL         
                  
GETSA             
;SYMBOL IM AKKU   
;UEBERGEBEN UND   
;INDEX RETTEN:    
;                 
STX INDEX         
STA CHAR          
LDA #0            
STA CHAR+1        
RTS               
;-----------------
READ091           
INX               
;- - - - - - - - -
READ09            
;ZIFFERN UEBER-   
;LESEN. X ZEIGT   
;AUF FOLGEZEICHEN 
LDA LINE,X        
JSR UTEST09       
BCS READ091       
RTS               
;-----------------
UZAHL             
;LESEN ZAHL       
;AKKU:=253        
;=>INTEGER,WERT   
;  IN NUMBER      
;AKKU:=254        
;=>REAL,ADRESSE   
;  IN NUMBER      
;XR ENTHAELT DEN  
;   TEXTZEIGER    
;-----------------
TXA               
;*SETZE ZEIGER    
;*AUF STRINGANFANG
CLC               
ADC #[LINE        
STA <STRPTR       
LDA #0            
ADC #]LINE        
STA <STRPTR+1     
;*SUCHE ENDE DER  
;*ZAHL GEMAESS    
;*PASCAL-SYNTAX   
;*Y>0 => REAL     
LDY #0            
JSR READ09        
CMP #"."          
BNE ZAHL1         
;                 
LDA LINE+1,X      
JSR UTEST09       
BCC ZAHL5         
INY               
INX               
JSR READ09        
;                 
ZAHL1             
CMP #"E"          
BNE ZAHL5         
;                 
LDA LINE+1,X      
CMP #"+"          
BEQ ZAHL15        
CMP #"-"          
BNE ZAHL2         
ZAHL15            
LDA LINE+2,X      
JSR UTEST09       
BCC ZAHL5         
INX               
ZAHL2 JSR UTEST09 
BCC ZAHL5         
INX               
INY               
JSR READ09        
;                 
ZAHL5             
;*ZAHL AB INDEX   
;*BIS X-1 IN LINE 
TYA               
PHA               
STX INDEX         
LDA LINE,X        
PHA               
;*ENDE MARKIEREN  
LDA #0            
STA LINE,X        
;                 
;*UMWANDLUNG MIT  
;*ROM-ROUTINE     
;                 
LDA #[STRFLP1     
STA <FARPC+1      
LDA #]STRFLP1     
STA <FARPC        
JSR UCALLF        
;                 
LDX #[STRFLP      
STX <FARPC+1      
LDX #]STRFLP      
STX <FARPC        
LDX #1            
JSR UCALLF        
;                 
;MARKIERUNG WIEDER
;ENTFERNEN        
PLA               
LDX INDEX         
STA LINE,X        
PLA               
BNE ISREAL        
;                 
;*INTEGER:WERT IN 
;*NUMBER SPEICHERN
LDA #[NUMBER      
STA <VAR          
LDA #]NUMBER      
STA <VAR+1        
JSR UINT          
LDA #253          
BNE ZAHL6         
;*REAL: WERT NACH 
;*FLOAT PACKEN.   
;*NUMBER IST      
;*UNDEFINIERT!!   
ISREAL            
LDA #[FLOAT       
STA <VAR          
LDA #]FLOAT       
STA <VAR+1        
JSR FACVAR        
LDA #254          
;                 
ZAHL6 LDX INDEX   
RTS               
;-----------------
UXCHNG            
;UMSCHALTUNG      
;AUF FILE "......"
;X ENTHAELT INDEX 
;AUF NAMEN IN TAB 
;-----------------
INX               
STX <XREG         
;                 
LDA #[FCLOSE      
STA <FARPC+1      
LDA #]FCLOSE      
STA <FARPC        
LDA #<INFILE      
JSR UCALLF        
;                 
LDA #<INFILE      
LDX #8            
LDY #3            
STA <LOGFIL       
STX <DEVICE       
STY <SECOND       
;                 
LDY #0            
LDX <XREG         
;"....",P,R       
XCH1 LDA LINE,X   
CMP #<ANFZ        
BEQ XCH2          
STA LINE,Y        
INY               
INX               
CPY #17           
BNE XCH1          
XCH2 LDX #0       
XCH3 LDA SUFFIX,X 
BEQ XCH4          
STA LINE,Y        
INY               
INX               
BNE XCH3          
;                 
XCH4 TYA          
LDX #[LINE        
LDY #]LINE        
STA <LENGTH       
STX <FILNAM       
STY <FILNAM+1     
LDA #1            
STA <NAMBNK       
;                 
LDA #[FOPEN       
STA <FARPC+1      
LDA #]FOPEN       
STA <FARPC        
JSR UCALLF        
;                 
LDX #<INFILE      
LDA #[CHKIN       
LDY #]CHKIN       
JSR UAYCALLF      
;                 
JSR XBASIN        
JSR XBASIN        
JSR XBASIN        
STA XL            
;                 
;* 4+3*XL BYTES   
;* UEBERLESEN     
JSR XBASIN        
LDX #3            
STX <XREG         
XCH5 LDX XL       
INX               
XCH6 JSR XBASIN   
DEX               
BNE XCH6          
DEC <XREG         
BNE XCH5          
;                 
JSR XCLRCHN       
LDA #255          
STA MEDIUM        
STA ZNR           
STA ZNR+1         
;**RELATIV ZUM    
;**FILE-ANFANG    
;**NEUER ZEILEN-  
;**ANFANG         
JMP GET1SYM       
;-----------------
ULESF             
;LIEST EINE ZEILE 
;DES PROGRAMMES   
;VOM FILE <INFILE 
;NACH LINE        
;0  -> ZEILENENDE 
;AM  TEXTENDE     
;MEDIUM:=0        
;-----------------
INC ZNR           
BNE LESF1         
INC ZNR+1         
LESF1 LDX #<INFILE
LDA #[CHKIN       
LDY #]CHKIN       
JSR UAYCALLF      
LDX #0            
;                 
LESF2 JSR XBASIN  
STA LINE,X        
INX               
CPX XL            
BNE LESF2         
LDA #0            
STA LINE,X        
JSR XCLRCHN       
LDA <ST           
BEQ LESF5         
;**RUECKSCHALTEN  
LDA #0            
STA MEDIUM        
;                 
LESF5 JMP LESR    
;-----------------
ULES              
;LESEROUTINE/ALLG.
;                 
;LIEST EINE ZEILE 
;DES PROGRAMMES   
;NACH LINE        
;0  -> ZEILENENDE 
;255-> TEXTENDE   
;-----------------
LDA MEDIUM        
BNE ULESF         
;                 
INC ZNR1          
BNE LES1          
INC ZNR1+1        
LES1 LDA ZNR1     
STA ZNR           
LDX ZNR1+1        
STX ZNR+1         
CMP LAST          
BNE LES2          
CPX LAST+1        
BNE LES2          
;**PROGRAMMENDE   
LDA #255          
STA LINE          
LDA #0            
STA LINE+1        
BEQ LESR          
;                 
LES2 LDY #0       
LES3 JSR ULESRAM  
STA LINE,Y        
INY               
CPY XL1           
BNE LES3          
;                 
LDA #0            
STA LINE,Y        
JSR USKIP         
;-----------------
LESR              
;LISTING AUSGEBEN 
;                 
LDX #<OUTFILE     
LDA #[CKOUT       
LDY #]CKOUT       
JSR UAYCALLF      
LDX #0            
LESR1 LDA LINE,X  
BEQ LESR2         
JSR XBSOUT        
INX               
BNE LESR1         
LESR2 LDA #13     
JSR XBSOUT        
JMP XCLRCHN       
;-----------------
UVORBEL           
;<--- PASCAL      
;VORBELEGUNG DER  
;BEZEICHNERTABELLE
;STACK:           
; +8 ->TABBEZ[0]  
;(<B) ALS BASIS   
LDY #8            
LDA (<B),Y        
STA <TABB         
INY               
LDA (<B),Y        
STA <TABB+1       
LDA #[BEZTAB      
STA <J            
LDA #]BEZTAB      
STA <J+1          
;                 
VORBEL1           
LDY #0            
LDA (<J),Y        
BEQ VORBELX       
VORBEL2           
LDA (<J),Y        
PHA               
AND #$7F          
STA (<TABB),Y     
INY               
PLA               
BPL VORBEL2       
;                 
CLC               
TYA               
ADC <J            
STA <J            
BCC VORBEL3       
INC <J+1          
VORBEL3 CLC       
LDA <TABB         
ADC #<ALEN+1      
STA <TABB         
BCC VORBEL1       
INC <TABB+1       
BNE VORBEL1       
VORBELX RTS       
;-----------------
UPOSI             
;<--- PASCAL      
;TABELLENSUCHE    
;STACK:           
;+12-> ID         
;+10-> TABBEZ[TX] 
;+8 -> TX         
;(<B ALS BASIS)   
;                 
<J      EQU <TP   
<TABB   EQU <TP+2 
<ID     EQU <TP+4 
;                 
LDA #255          
STA POSI          
STA POSI+1        
;KOPIERE PARAMETER
;TX         ->J   
;TABBEZ[TX] ->TABB
;ID         ->ID  
;                 
LDY #13           
POSI0 LDA (<B),Y  
;**STA <J-11,Y    
DFD $99,<J-8,0    
DEY               
CPY #7            
BNE POSI0         
;                 
;NUR LEGALE       
;NAMEN ZULASSEN:  
;                 
LDY #0            
LDA (<ID),Y       
BMI POSIQ         
CMP #"*"          
BEQ POSIQ         
;                 
POSI1             
;FOR J:=TX        
;DOWNTO 0         
SEC               
LDA <J            
SBC #1            
STA <J            
BCS POSI2         
DEC <J+1          
BMI POSIQ         
POSI2 SEC         
LDA <TABB         
SBC #<ALEN+1      
STA <TABB         
BCS POSI4         
DEC <TABB+1       
;                 
POSI4 LDY #0      
POSI5             
LDA (<ID),Y       
CMP (<TABB),Y     
BNE POSI1         
INY               
CPY #<ALEN+1      
BNE POSI5         
;**GEFUNDEN       
LDA <J            
STA POSI          
LDA <J+1          
STA POSI+1        
POSIQ             
RTS               
;-----------------
BEZTAB            
DFD "FALSÅ"       
DFD "TRUÅ"        
DFD "BOOLEAÎ"     
DFD "MAXINÔ"      
DFD "INTEGEÒ"     
DFD "CHAÒ"        
DFD "REAÌ"        
DFD "*NIÌ"        
DFD "*STRINÇ"     
DFD "*SEÔ"        
DFD "TEXÔ"        
DFD "STRINÇ"      
DFD "INPUÔ"       
DFD "OUTPUÔ"      
DFD "BYTÅ"        
DFD "BANË"        
;                 
DFD "OPEÎ"        
DFD "CLOSÅ"       
DFD "GEÔ"         
DFD "PUÔ"         
DFD "WRITÅ"       
DFD "WRITELÎ"     
DFD "REAÄ"        
DFD "READLÎ"      
DFD "GETKEÙ"      
DFD "POKÅ"        
DFD "SYÓ"         
DFD "HALÔ"        
DFD "NE×"         
DFD "MARË"        
DFD "RELEASÅ"     
DFD "SLO×"        
DFD "FASÔ"        
DFD "INSERÔ"      
DFD "DELETÅ"      
;                 
DFD "ORÄ"         
DFD "CHÒ"         
DFD "SUCÃ"        
DFD "PREÄ"        
DFD "PEEË"        
DFD "EOLÎ"        
DFD "EOÆ"         
DFD "STATUÓ"      
DFD "KEYPRESSEÄ"  
DFD "ODÄ"         
DFD "ABÓ"         
DFD "SQRÔ"        
DFD "LÎ"          
DFD "EXÐ"         
DFD "SIÎ"         
DFD "COÓ"         
DFD "TAÎ"         
DFD "ARCTAÎ"      
DFD "INÔ"         
DFD "ROUNÄ"       
DFD "TRUNÃ"       
DFD "POWEÒ"       
DFD "SQÒ"         
DFD "ADDÕ"        
DFD "RANDOÍ"      
DFD "HBYTÅ"       
DFD "SIZEOÆ"      
DFD "ADÒ"         
DFD "CONCAÔ"      
DFD "COPÙ"        
DFD "LENGTÈ"      
DFD "POÓ"         
DFD "VAÌ"         
DFD "STÒ"         
;                 
DFD "GRAPHIÃ"     
DFD "PAINÔ"       
DFD "DISPLAÙ"     
DFD "BOØ"         
DFD "CIRCLÅ"      
DFD "DRA×"        
DFD "LOCATÅ"      
DFD "COLOÒ"       
DFD "SCNCLÒ"      
DFD "WINDO×"      
DFD "WIDTÈ"       
DFD "SOUNÄ"       
DFD "VOÌ"         
DFD "FILTEÒ"      
DFD "PLAÙ"        
DFD "TEMPÏ"       
DFD "ENVELOPÅ"    
;DFD "MOVESPÒ"    
;DFD "SPRITÅ"     
;DFD "SPRCOLOÒ"   
;DFD "SPRSAÖ"     
;DFD "GSHAPÅ"     
;DFD "SSHAPÅ"     
;                 
DFD "RWINDO×"     
DFD "RGÒ"         
DFD "RCLÒ"        
DFD "RDOÔ"        
DFD "POÔ"         
DFD "PEÎ"         
DFD "JOÙ"         
;DFD "BUMÐ"       
;DFD "RSPRCLÒ"    
;DFD "RSPRPOÓ"    
;DFD "RSPRITÅ"    
DFD 0             
;-----------------
ENDSCAN           
;-----------------
EXP NUMBER,ZNR,   
CHAR,POSI,FLOAT,  
ID,               
INDEX,LBYTE,HBYTE,
TSTFLG,PARTST,    
CHAIN,UINIT,      
GETSYM,UPOSI,     
UVORBEL,ENDSCAN   
END