PROGRAM SELECTION(INPUT,OUTPUT);                  
(*N. WIRTH: ALGORITHMEN UND DATENSTRUKTUREN     *)
(*S. 216   2.3.1985   FLORIAN MATTHES           *)
 CONST N=10;                                      
 TYPE INDEX=1..N;                                 
      OBJECT=RECORD V,W:INTEGER END;              
 VAR I:INDEX;                                     
     A:ARRAY[INDEX]OF OBJECT;                     
     LIMW,TOTV,MAXV:INTEGER;                      
     W1,W2,W3:INTEGER;                            
     S,OPTS:SET OF INDEX;                         
     Z:ARRAY[BOOLEAN]OF CHAR;                     
                                                  
 PROCEDURE TRY(I:INTEGER;TW,AV:INTEGER);          
  VAR AV1:INTEGER;                                
 BEGIN (*VERSUCHE DEN EINSCHLUSS VON OBJEKT I*)   
  IF TW+A[I].W<=LIMW THEN                         
   BEGIN S:=S+[I];                                
    IF I<N THEN TRY(I+1,TW+A[I].W,AV) ELSE        
     IF AV>MAXV THEN                              
      BEGIN MAXV:=AV;OPTS:=S END;                 
    S:=S-[I];                                     
   END;                                           
  (*VERSUCHE NUN OHNE OBJEKT I*)                  
  AV1:=AV-A[I].V;                                 
  IF AV1>MAXV THEN                                
   BEGIN                                          
    IF I<N THEN TRY(I+1,TW,AV1) ELSE              
     BEGIN MAXV:=AV1;OPTS:=S END                  
   END                                            
 END;(*TRY*)                                      
                                                  
BEGIN TOTV:=0;                                    
 FOR I:=1 TO N DO                                 
  WITH A[I] DO                                    
   BEGIN READ(W,V);TOTV:=TOTV+V END;              
 READ(W1,W2,W3);                                  
 Z[TRUE]:="*";Z[FALSE]:=".";                      
 WRITE(" GEWICHT:");                              
 FOR I:=1 TO N DO WRITE(A[I].W:4);WRITELN;        
 WRITE(" WERT:   ");                              
 FOR I:=1 TO N DO WRITE(A[I].V:4);WRITELN;        
 REPEAT                                           
  LIMW:=W1;MAXV:=0;S:=[];OPTS:=[];                
  TRY(1,0,TOTV);WRITE(LIMW);                      
  FOR I:=1 TO N DO WRITE("   ",Z[I IN OPTS]);     
  WRITELN;W1:=W1+W2                               
 UNTIL W1>W3;                                     
END.