;=================
;    SCR.SYST     
; SCREEN-EDITOR   
; VERSION C-128   
;=================
;                 
;10.9.1986        
;                 
;SYSTEMROUTINEN   
;EINBINDUNG BASIC 
;EINBINDUNG PASCAL
;=================
ORG $1400         
;                 
<MAXME1  EQU 57   
MEMTOP   EQU $A07 
;                 
RAMBANK  EQU *    
COMPCODE EQU $9B00
; ANFANG COMPILER 
;=ENDE RAM BANK 1 
INTERPR  EQU $508 
;LABEL INIT AUS   
;PAS.MOD1.S       
;=================
MMUCR   EQU $FF00 
LCRA    EQU $FF01 
LCRB    EQU $FF02 
LCRC    EQU $FF03 
;                 
PCRA    EQU $D501 
PCRB    EQU $D502 
PCRC    EQU $D503 
;PCRA..C MUESSEN  
;BEIM PROGRAMM-   
;START VORBELEGT  
;WERDEN           
;                 
;A = NUR ROM / IO 
;B = NUR RAM      
;C = NUR RAM / IO 
;                 
VICREG  EQU 53280 
SCREEN  EQU $0400 
COLOR   EQU $D800 
;                 
VDC     EQU $D600 
COLOR80 EQU $0800 
;ATTRIBUTE IM     
;VDC-PRIVAT-RAM   
;                 
;=================
;                 
<FARCNF EQU 2     
<FARPC  EQU 3     
;(H/L !)          
<FARA   EQU 6     
<FARX   EQU 7     
<FARY   EQU 8     
;                 
<M4080  EQU $D7   
;FLAG 40/80 MODUS 
;$00 = 40         
;$80 = 80         
;                 
ERRPTR  EQU $300  
UMWPNT  EQU $302  
;(UMWANDLUNG IN   
;BASIC-TOKENS)    
REPEAT  EQU $A22  
BASTOP  EQU $1210 
;                 
JMPFAR  EQU $FF71 
PRIMM   EQU $FF7D 
XCHKIN  EQU $FFC6 
XCHKOUT EQU $FFC9 
XCHRIN  EQU $FFCF 
XCHROUT EQU $FFD2 
XCLOSE  EQU $FFC3 
XCLRCHN EQU $FFCC 
XGETIN  EQU $FFE4 
XLOAD   EQU $FFD5 
XOPEN   EQU $FFC0 
XPFKEY  EQU $FF65 
XREADST EQU $FFB7 
XSAVE   EQU $FFD8 
XSETBNK EQU $FF68 
XSETLFS EQU $FFBA 
XSETMSG EQU $FF90 
XSETNAM EQU $FFBD 
XSWAP   EQU $FF5F 
;                 
;=================
;DIE FOLGENDEN    
;ROUTINEN WERDEN  
;BEIM SYSTEMSTART 
;AB DER GENANNTEN 
;ADRESSE KOPIERT  
;                 
COLTAB            
DFD 6; RAND 40    
DFD 3; HINTERG.40 
DFD 4             
;HINTRERG./RAND 80
DFD 1; KOPF 40    
DFD 0; TEXT 40    
DFD 15;KOPF 80    
DFD 0; TEXT 80    
DFD  "?";DIALOG 40
DFD  "?";DIALOG 80
;                 
DEFDRV  DFD 8     
ORGSRC  DFD $8000 
ENDOBJ  DFD $2000 
TEMPFLG DFD 0     
RSMEFLG DFD 0     
;                 
LAENGE  DFD 0     
NAME              
DFD 0,0,0,0,0,0   
DFD 0,0,0,0,0,0   
DFD 0,0,0,0       
;                 
BYTES3  DFD 0,0,0 
BYTES2  DFD 0,0   
FIRSTSTART DFD 0  
DFD 0,0,0,0,0     
;**ERWEITERUNGEN**
;-----------------
;BIOS INTERFACE   
;-----------------
CHKIN             
STA LCRA          
JSR XCHKIN        
STA LCRB          
RTS               
;                 
CHKOUT            
STA LCRA          
JSR XCHKOUT       
STA LCRB          
RTS               
;                 
CHRIN             
STA LCRA          
JSR XCHRIN        
STA LCRB          
RTS               
;                 
CHROUT            
STA LCRA          
JSR XCHROUT       
STA LCRB          
RTS               
;                 
CLOSE             
STA LCRA          
JSR XCLOSE        
STA LCRB          
RTS               
;                 
CLRCHN            
STA LCRA          
JSR XCLRCHN       
STA LCRB          
RTS               
;                 
GETIN             
STA LCRA          
JSR XGETIN        
STA LCRB          
RTS               
;                 
LOAD              
STA LCRA          
JSR XLOAD         
STA LCRB          
RTS               
;                 
OPEN              
STA LCRA          
JSR XOPEN         
STA LCRB          
RTS               
;                 
PFKEY             
STA LCRA          
JSR XPFKEY        
STA LCRB          
RTS               
;                 
READST            
STA LCRA          
JSR XREADST       
STA LCRB          
RTS               
;                 
SAVE              
STA LCRA          
JSR XSAVE         
STA LCRB          
RTS               
;                 
SETLFS            
STA LCRA          
JSR XSETLFS       
;**  AUCH BANK 0/0
;**  DEFINIEREN   
LDA #0            
TAX               
JSR XSETBNK       
STA LCRB          
RTS               
;                 
SETMSG            
STA LCRA          
JSR XSETMSG       
STA LCRB          
RTS               
;                 
SETNAM            
STA LCRA          
JSR XSETNAM       
STA LCRB          
RTS               
;                 
SWAP              
STA LCRA          
JSR XSWAP         
STA LCRB          
RTS               
;-----------------
UIZPAG            
;** MODIFIZERTER  
;** KALTSTART     
;** RETURN-ADDRESS
;** RETTEN        
PLA               
STA BYTES2        
PLA               
STA BYTES2+1      
;                 
LDA #0            
STA MMUCR         
LDX #2            
IZPAG2 LDA $1C00,X
STA BYTES3,X      
DEX               
BPL IZPAG2        
;                 
JSR $417A         
JSR $4251         
JSR $4045         
LDA ENDOBJ        
STA BASTOP        
LDA ENDOBJ+1      
STA BASTOP+1      
;                 
LDA #[COMPCODE    
STA <MAXME1       
LDA #]COMPCODE    
STA <MAXME1+1     
;                 
JSR $51FD         
;CLR LOESCHT      
;RET-ADRESSE!     
;                 
LDX #2            
IZPAG3            
LDA BYTES3,X      
STA $1C00,X       
DEX               
BPL IZPAG3        
;                 
LDA BYTES2+1      
PHA               
LDA BYTES2        
PHA               
RTS               
;-----------------
GOBASIC           
;                 
JSR UIZPAG        
JSR $419B         
;(COPYRIGHT..)    
LDA #[UMWNEU      
STA UMWPNT        
LDA #]UMWNEU      
STA UMWPNT+1      
GOBA0             
;** FKT.TASTEN:   
;                 
LDX #$4C          
GOBA1 LDA $CEA8,X 
STA $1000,X       
DEX               
BPL GOBA1         
;                 
JMP $401C         
;-----------------
STOP.IT           
;<-- EINSPRUNG BEI
;RUN/STOP&RESTORE 
LDA #$3F          
STA MMUCR         
;**JMP MENUEC     
NOP               
NOP               
NOP               
;-----------------
COMPILER          
;AUFRUF COMPILER  
;VOM MENUE AUS:   
JSR UIZPAG        
;                 
LDA #[(COMPCODE+6)
STA <FARA         
LDA #](COMPCODE+6)
STA <FARY         
LDX #1            
STX <FARCNF       
;**INTERPRETER IST
;**IN BANK 1      
LDX #$7F          
;**PCODE IN BANK 1
STX <FARX         
LDA #[INTERPR     
STA <FARPC+1      
LDA #]INTERPR     
STA <FARPC        
;                 
LDA #[C.RET       
STA ERRPTR        
LDA #]C.RET       
STA ERRPTR+1      
;                 
JMP JMPFAR        
C.RET             
;<--- COMPILER    
LDA TEMPFLG       
BMI KILL          
BEQ STOP.IT       
STA RSMEFLG       
BNE STOP.IT       
;-----------------
UMWNEU            
;ERWEITERTE UM-   
;WANDLUNSROUTINE  
LDX #$FF          
STX $3C           
JSR $4F93         
LDA $200          
CMP #"*"          
BEQ UMWNEU1       
JMP $4DCD         
UMWNEU1           
LDA $201          
CMP #"*"          
BEQ KILL          
;                 
LDA #$3F          
STA MMUCR         
;********JMP MENUE
NOP               
NOP               
NOP               
;-----------------
KILL              
;PASCAL-SYSTEM    
;LOESCHEN -->BASIC
JSR UIZPAG        
JSR $419B         
;(COPYRIGHT..)    
JSR PRIMM         
DFD "SYSTEM "    
DFD "SWITCHED OFF"
DFD 0             
LDA #$FF          
STA <MAXME1+1     
STA MEMTOP+1      
LDA #0            
STA <MAXME1       
STA MEMTOP        
JMP GOBA0         
;=================
ENDSYST           
;                 
EXP *             
;                 
END