;=================
;   SCR.MOD6      
; SCREEN-EDITOR   
; VERSION C-128   
;=================
;                 
;25.9.1986        
;                 
;=================
;CURSORBEWEGUNGEN 
;HAUPTPROGRAMM    
;EINBINDUNG PASCAL
;=================
;                 
IMP SCR.SYST      
IMP SCR.DECL      
IMP SCR.CST       
IMP SCR.MOD1      
IMP SCR.MOD2      
IMP SCR.MOD3      
IMP SCR.MOD4      
IMP SCR.MOD5      
;                 
;LADE DIE GLOBALEN
;LABELS           
;                 
;=================
ORG ENDMOD5       
;                 
;=================
;CURSORSTEUERUNG  
;=================
UP                
;                 
LDA <SZEIL        
BEQ UP1           
DEC <SZEIL        
JMP UPREV         
UP1 LDX #<MXLIN   
DEX               
LDA <SSPAL        
JMP UCSPR         
;-----------------
DOWN              
;                 
INC <SZEIL        
LDA <SZEIL        
CMP #<MXLIN       
BEQ DOWN1         
JMP UNEXT         
DOWN1 LDX #0      
LDA <SSPAL        
JMP UCSPR         
;-----------------
LEFT              
;                 
LDA <SSPAL        
BEQ LEFT1         
DEC <SSPAL        
RTS               
LEFT1 LDX <MXCOL  
DEX               
STX <SSPAL        
RTS               
;-----------------
RIGHT             
;CURSOR NACH      
;RECHTS. BEACHTE  
;TEXTMODUS        
;                 
INC <SSPAL        
LDA <SSPAL        
CMP <MXCOL        
BNE SKIP2         
BIT <TEFLAG       
BPL SKIP1         
JSR UTEST         
BCC SKIP1         
JMP QRIGHT        
;                 
SKIP              
;CURSOR AUF BILD  
;NACH RECHTS      
;                 
INC <SSPAL        
LDY <SSPAL        
CPY <MXCOL        
BNE SKIP2         
SKIP1             
LDY #0            
STY <SSPAL        
SKIP2 RTS         
;-----------------
RETRN             
;                 
JSR UTEST         
BCC RETRN1        
BIT <TEFLAG       
BMI UCRLF         
RETRN1 LDA #0     
STA <SSPAL        
JMP DOWN          
;- - - - - - - - -
UCRLF             
;                 
JSR UAPOS         
LDA APOS          
BEQ UCRLF1        
JSR CRLF          
JSR UMOVE         
UCRLF1 JMP UNPOS  
;-----------------
CRLF              
;ASPAL AUF DEN    
;NAECHSTEN        
;ZEILENBEGINN     
;                 
LDY <LBND         
STY <ASPAL        
LDY AZEIL+<MXIND  
LDX AZEIL         
INX               
BNE CRLF1         
INY               
CRLF1 CPX TXTBOT  
BNE CRLF2         
CPY TXTBOT        
BNE CRLF2         
LDX #0            
LDY #0            
CRLF2 STX AZEIL   
STY AZEIL+<MXIND  
RTS               
;-----------------
UDSPCMD           
;KOMMANDOZEILE AUS
;TAB ANZEIGEN     
JSR HOME1         
LDY #0            
DSPCMD1 LDA TAB,Y 
JSR USETR         
INY               
CPY <SCRLC        
BNE DSPCMD1       
RTS               
;-----------------
SCNCLR            
;                 
LDY #0            
LDA #" "          
SCNCLR1 STA TAB,Y 
INY               
CPY <SCRLC        
BNE SCNCLR1       
JSR UDSPCMD       
LDA #255          
STA <COMFLG       
BNE HOME1         
;- - - - - - - - -
HOME              
;                 
LDA <SSPAL        
ORA <SZEIL        
BNE HOME1         
LDA <SCRLC        
LDX #<SCRLL       
JMP UCSPR         
HOME1 LDA #0      
TAX               
JMP UCSPR         
;-----------------
UPOS              
;BESTIMME CURSOR- 
;POSITION:        
;******C=1********
;(<TP),Y ZEIGT IN 
;TEXT (Y=<TSPAL)  
;X=FELDLAENGE     
;A=0:TEXT         
;A=1:TAB          
;A=2:BND          
;A=3:MSK          
;A=4 COMMAND      
;                 
;A=5 SCROLL       
;A=6 ZAHLBEREICH  
;*****C=0*********
;A=255            
;GESPERRT         
;                 
JSR UTEST         
BCS IN.TEXT       
LDY <SSPAL        
LDA <SZEIL        
BNE POS1          
CPY <SCRLC        
BCS IN.SCRL       
;**********COMMAND
LDA <COMFLG       
BNE POS0          
JSR SCNCLR        
POS0              
LDY <SSPAL        
STY <TSPAL        
LDA #[TAB         
LDX #]TAB         
STA <TP           
STX <TP+1         
LDX <SCRLC        
LDA #4            
SEC               
RTS               
;*****************
IN.SCRL           
LDA #5            
SEC               
RTS               
;*****************
IN.TEXT           
JSR UTZEIL        
JSR UTSPAL        
JSR UTP           
LDX <TXTLEN       
LDY <TSPAL        
LDA #0            
SEC               
RTS               
;*****************
POS1              
CPY #<ZAHL        
BCS POS2          
CMP <TOPFLG       
BEQ IN.ZAHL       
CMP <SCTOP        
BCC POSA          
CMP <SCBOT        
BCC IN.ZAHL       
;********BLOCKIERT
POSA LDA #255     
CLC               
RTS               
;*****************
IN.ZAHL           
LDA #6            
SEC               
RTS               
;*****************
POS2              
CPY <SCLEN        
BCS POSA          
CMP <MSKFLG       
BNE POS3          
;************MASKE
LDA MASK          
LDX MASK+<MXIND   
LDY #3            
BNE POS5          
POS3 CMP <BNDFLG  
BNE POS4          
;*************BNDS
LDA BNDS          
LDX BNDS+<MXIND   
LDY #2            
JMP POS5          
POS4 CMP <TABFLG  
BNE POSA          
;*************TABS
LDA TABU          
LDX TABU+<MXIND   
LDY #1            
POS5              
STA <TP           
STX <TP+1         
STY <YREG         
JSR UTSPAL        
LDX <TXTLEN       
LDA <YREG         
SEC               
RTS               
;-----------------
UENTER            
;                 
LDA <LFD          
STA (<TP),Y       
;- - - - - - - - -
UDISPLAY          
;                 
LDY <SSPAL        
LDA <LFD          
JMP USET          
;-----------------
ZEICH             
;SETZT ZEICHEN A  
;VON TASTATUR     
;AN LFD. POS.     
;                 
STA <LFD          
JSR UPOS          
BCC ZEICHX        
BNE ZEICH2        
;** IM TEXT       
JSR UENTER        
BIT <TEFLAG       
BMI ZEICH0        
JMP SKIP          
;                 
ZEICH0            
;** TEXT MODUS    
LDY <TSPAL        
INY               
CPY <RBND         
BNE ZEICH1        
JMP RETRN         
ZEICH1 JMP RIGHT  
;                 
ZEICH2            
CMP #5            
BEQ ZEICH3        
CMP #6            
BEQ ZEICH4        
;** TEXT,PROFILE  
;** ODER COMMAND  
JSR UENTER        
JMP RIGHT         
;                 
ZEICH3            
;** SCROLL        
JSR UDISPLAY      
JSR SKIP          
CPY #0            
BEQ ZEICHX        
LDA #" "          
JMP USET          
;                 
ZEICH4            
;** LINE COMM.    
JSR UDISPLAY      
JSR SKIP          
CPY #<ZAHL        
BEQ ZEICHX        
LDA #" "          
JMP USET          
ZEICHX RTS        
;-----------------
SRETRN            
;SHIFT RETURN     
;FALLS NICHT FIND-
;BEFEHL GEFUNDEN  
;                 
JSR UAPOS         
BNE SRETR9        
BIT <TEFLAG       
BPL SRETR9        
LDA APOS          
BEQ SRETR9        
LDA TABU          
STA <IND          
LDA TABU+<MXIND   
STA <IND+1        
LDY <ASPAL        
SRETR1 INY        
CPY <RBND         
BCS SRETR2        
LDA (<IND),Y      
CMP #" "          
BEQ SRETR1        
STY <ASPAL        
JMP SRETR3        
SRETR2            
JSR CRLF          
SRETR3            
JSR UMOVE         
SRETR9            
JMP UNPOS         
;-----------------
QUP               
; BILD HOCH       
JSR UAPOS         
SEC               
LDA ANFZEI        
SBC <SCRLV        
TAX               
LDA ANFZEI+<MXIND 
SBC #0            
BCS QUP1          
LDA #0            
TAX               
QUP1              
STA ANFZEI+<MXIND 
STX ANFZEI        
JMP UNPOS         
;-----------------
QDOWN             
; BILD RUNTER     
;                 
JSR UAPOS         
CLC               
LDA ANFZEI        
ADC <SCRLV        
TAX               
LDA ANFZEI+<MXIND 
ADC #0            
CMP TXTBOT+<MXIND 
BCC QDOWN1        
BNE QDOWN0        
CPX TXTBOT        
BCC QDOWN1        
QDOWN0            
LDX TXTBOT        
LDA TXTBOT+<MXIND 
QDOWN1            
STX ANFZEI        
STA ANFZEI+<MXIND 
JMP UNPOS         
;-----------------
QLEFT             
; BILD LINKS      
;                 
JSR UAPOS         
SEC               
LDA <ANFSPA       
SBC <SCRLH        
BCS QLEFT1        
LDA #0            
QLEFT1 STA <ANFSPA
JMP UNPOS         
;-----------------
QRIGHT            
; BILD RECHTS     
;                 
JSR UAPOS         
CLC               
LDA <ANFSPA       
ADC <SCRLH        
BCS QRGHT1        
CMP <TXTLEN       
BCC QRGHT2        
QRGHT1 LDX <TXTLEN
DEX               
TXA               
QRGHT2            
STA <ANFSPA       
JMP UNPOS         
;-----------------
DELETE            
;LOESCHE ZEICHEN  
;LINKS VOM CURSOR 
;CURSOR NACH LINKS
;                 
JSR UAXPOS        
BCC DEL2          
CMP #5            
BCS DEL2          
CPY #0            
BEQ DEL2          
;                 
STX <YREG         
DEL1              
LDA (<TP),Y       
DEY               
STA (<TP),Y       
INY               
INY               
CPY <YREG         
BNE DEL1          
LDA #" "          
DEY               
STA (<TP),Y       
JSR UNXPOS        
JMP LEFT          
DEL2 RTS          
;-----------------
INSERT            
;FUEGE LEERZEICHEN
;BEIM CURSOR EIN  
;                 
JSR UAXPOS        
BCC INS4          
CMP #5            
BCS INS4          
;                 
STY <YREG         
TXA               
TAY               
DEY               
LDA (<TP),Y       
CMP #" "          
BNE INS3          
;** ZEILE VOLL    
;                 
INS1 CPY <YREG    
BEQ INS2          
DEY               
LDA (<TP),Y       
INY               
STA (<TP),Y       
DEY               
BNE INS1          
INS2 LDA #" "     
STA (<TP),Y       
INS3 JMP UNXPOS   
INS4 RTS          
;-----------------
UAXPOS            
;MERKE CURSOR FUER
;ZEILENKORREKTUR  
;                 
LDA <SSPAL        
STA <XSPAL        
LDA <SZEIL        
STA <XZEIL        
JSR UPOS          
STA <LFD          
RTS               
;-----------------
UNXPOS            
;RESTAURIERE DIE  
;ZEILE UND DIE    
;CURSORPOSITION   
;A = 4 KOPFZEILE, 
;SONST PROFILE    
;ODER TEXT        
;                 
LDA <LFD          
CMP #4            
BNE NXPOS1        
JSR UDSPCMD       
JMP NXPOS2        
NXPOS1 LDA <XZEIL 
JSR ZEILE         
NXPOS2 LDA <XSPAL 
LDX <XZEIL        
JMP UCSPR         
;-----------------
DOFIND            
;WIEDERHOLE FIND- 
;KOMMANDO         
;                 
JSR UAPOS         
JSR RFIND         
JMP UNPOS         
;-----------------
DOCHANG           
;WIEDERHOLE       
;CHANGE-KOMMANDO  
;                 
JSR UAPOS         
JSR RCHNG         
JMP UNPOS         
;-----------------
UDEFINE           
; RUN/STOP GELESEN
;                 
LDA <RECFLG       
BNE DEFINE4       
;                 
JSR UAXPOS        
LDA <COMFLG       
BNE DEFINE0       
JSR SCNCLR        
DEFINE0           
JSR HOME1         
LDA #[MSG0        
STA <IND          
LDA #]MSG0        
JSR UWTOP         
DEFINE1 JSR GETIN 
CMP #""; STOP    
BEQ DEFINE2       
SEC               
SBC #"1"          
BCC DEFINE1       
CMP #4            
BCS DEFINE1       
;                 
TAX               
LDA PFTAB,X       
LDX #0            
STX <RECLEN       
STA <RECFLG       
DEFINE2 LDA #4    
STA <LFD          
;                 
;ERZWINGE WIEDER- 
;AUFBAU KOPFZEILE 
;                 
JMP UNXPOS        
;                 
DEFINE4           
;******* DEFINIERE
LDA #0            
LDX <RECFLG       
STA <RECFLG       
LDY <RECLEN       
DEY               
LDA #[KEYSTR      
STA <IND          
LDA #]KEYSTR      
STA <IND+1        
LDA #<MYBANK      
STA <IND+2        
LDA #<IND         
JMP PFKEY         
;-----------------
FUNKT             
;WARTE AUF EINE   
;TASTE. SETZE     
;ZEICHEN ODER     
;FUEHRE EINE      
;FUNKTION AUS     
;                 
JSR UCURSR        
FUNKT1            
JSR GETIN         
BEQ FUNKT1        
STA <LFD          
LDY <RECFLG       
BEQ FUNKT15       
LDY <RECLEN       
CPY #<LKEYSTR     
;****** UEBERLAUF!
BCS UDEFINE       
STA KEYSTR,Y      
INC <RECLEN       
FUNKT15           
JSR UCURSR        
LDA <LFD          
;                 
LDX #16           
;** LAENGE        
;** KEYTAB        
FUNKT2            
CMP KEYTAB,X      
BEQ FUNKT3        
DEX               
BPL FUNKT2        
JMP ZEICH         
FUNKT3            
TXA               
ASL               
TAX               
LDA KSPRTAB,X     
STA <IND          
LDA KSPRTAB+1,X   
STA <IND+1        
JMP (<IND)        
;-----------------
KEYTAB            
;TABELLE ALLER    
;ASCII-CODES      
;DER FUNKTIONS-   
;TASTEN;          
DFD 141,13,20,148 
DFD "“‘?…†‡ˆ‰Š"
DFD ""           
;-----------------
PFTAB             
DFD 9;  SHIFT/RUN 
DFD 10; HELP      
DFD 6;  F6        
DFD 8;  F8        
;-----------------
KSPRTAB           
DFD SRETRN,RETRN  
DFD DELETE,INSERT 
DFD HOME,SCNCLR   
DFD UP,DOWN       
DFD LEFT,RIGHT    
DFD QUP,QDOWN     
DFD QLEFT,QRIGHT  
DFD DOFIND,DOCHANG
DFD UDEFINE       
;-----------------
;VORBELEGUNG DER  
;TASTEN:          
DEFAULT           
DFD 133,137,134   
DFD 138,135,139   
DFD 136,140       
DFD 131,132       
;=================
UAPOS             
;APOS = 255:      
;CURSORPOSITION   
;STEHT IN ASPAL   
;UND AZEIL(L/H)   
;APOS = 0:        
;CURSOR WAR       
;NICHT IM TEXT    
;                 
;BILD KOMPLETT    
;AUSWERTEN!       
;A<>0, FALLS FIND 
;                 
JSR UTEST         
BCC APOS1         
;**********IM TEXT
JSR UTZEIL        
JSR UTSPAL        
JSR UTP           
LDA <TSPAL        
STA <ASPAL        
LDA <TZEIL        
STA AZEIL         
LDA <TZEIL+1      
STA AZEIL+<MXIND  
LDA #255          
JMP APOS2         
;                 
APOS1             
;*******AUSSERHALB
LDA <SZEIL        
STA <XZEIL        
LDA #0            
STA <XSPAL        
;                 
APOS2 STA APOS    
LDA #0            
STA <FEHLER       
STA <FNDFLG       
;                 
JSR ULCOM         
JSR URTAB         
JSR URSCRL        
;                 
JSR UPRIM         
;                 
LDA <FEHLER       
BNE APOS3         
JSR URBND         
BCS APOS3         
JSR UEXLCO        
;                 
APOS3 LDA <FNDFLG 
RTS               
;=================
UNPOS             
;DER CURSOR       
;SPRINGT AUF      
;ALTE TEXTPOS.,   
;FALLS DIESE      
;NOCH AUF DEM     
;NEUEN BILD       
;IST. SONST AN    
;DIE LINKE        
;OBERE ECKE       
;                 
;BILDAUFBAU       
;                 
LDA #0            
STA <COMFLG       
;                 
JSR UTOP          
;                 
JSR UBILD         
LDA APOS          
BEQ NPOS1         
JSR UONSCR        
JMP UCSPR         
NPOS1 LDA <XSPAL  
LDX <XZEIL        
JMP UCSPR         
;=================
;HAUPTSCHLEIFE    
;MAINX UND MAIN2  
;CLC FALLS OK     
;=================
QUIT SEC          
RTS               
;                 
MAINX             
;*****************
;<----------      
;AUFRUF NEUER NAME
;X=LAENGE IN TAB  
;*****************
CPX #0            
BEQ QUIT          
CPX #17           
BCS QUIT          
STX LAENGE        
MAIN0             
LDA TAB,X         
STA NAME,X        
DEX               
BPL MAIN0         
LDA #0            
LDX LAENGE        
JSR ULOAD         
BCC MAIN2         
LDA TAB           
CMP #"6"          
BNE QUIT          
LDA TAB+1         
CMP #"2"          
BNE QUIT          
;** FILE NOT FOUND
;** NEUES DATASET 
JSR UDISKI        
;**  BLINKEN AUS! 
MAIN1 LDA #[MSG2  
LDY #]MSG2        
JSR ZINPUT        
BCS QUIT          
BEQ MAIN1         
CPY #0            
BNE MAIN1         
CMP #137          
BCS MAIN1         
STA <LFD          
;*****************
;MIT SATZLAENGE   
;INITIALISIEREN:  
;*****************
LDX MEMTOP        
LDY MEMTOP+1      
STX <IND          
STY <IND+1        
LDY #0            
LDA <LFD          
STA (<IND),Y      
INY               
LDA #0            
STA (<IND),Y      
INY               
STA (<IND),Y      
LDA #5            
JSR PLUSA         
JSR UINITP        
MAIN2             
;*****************
;<----------      
;AUFRUF ALTER NAME
;NAME,LAENGE SIND 
;GUELTIG          
;*****************
LDX MEMTOP        
LDY MEMTOP+1      
STX <IND          
STY <IND+1        
LDY #0            
LDA (<IND),Y      
STA <TXTLEN       
INY               
LDA (<IND),Y      
STA TXTBOT        
INY               
LDA (<IND),Y      
STA TXTBOT+<MXIND 
LDA <IND          
LDX <IND+1        
CLC               
ADC #5            
BCC MAIN5         
INX               
MAIN5             
STA MASK          
STX MASK+<MXIND   
JSR PLUS          
STA BNDS          
STX BNDS+<MXIND   
JSR PLUS          
STA TABU          
STX TABU+<MXIND   
JSR PLUS          
STA <BASIS        
STX <BASIS+1      
LDA TXTBOT        
LDY TXTBOT+<MXIND 
JSR TPADR         
LDA <TP           
STA <ENDE         
LDA <TP+1         
STA <ENDE+1       
LDA #0            
STA ANFZEI        
STA ANFZEI+<MXIND 
STA <ANFSPA       
STA <RECFLG       
;*****************
; BND UND TAB     
; INITIALISIEREN! 
;*****************
JSR UPROF         
JSR URBND         
JSR URTAB         
;*****************
;JETZT ERST DIE   
;ANFANGSWERTE:    
;*****************
JSR URESET        
JSR UTXTON        
;*******KONSTANTEN
LDA #255          
STA FLAG+$13      
STA FLAG+$14      
LDA #0            
STA <ENDFLG       
STA <XZEIL        
STA <XSPAL        
STA APOS          
STA <SCRLM        
STA <FEHLER       
STA <CODE         
JSR UCOLOR        
JSR UNPOS         
MAIN6 JSR FUNKT   
LDA <ENDFLG       
BEQ MAIN6         
JSR UWHEAD        
CLC               
RTS               
;-----------------
PLUS              
;(A,X) UM SATZ-   
;LAENGE ERHOEHEN  
;                 
CLC               
ADC <TXTLEN       
BCC PLUS1         
INX               
PLUS1 RTS         
;-----------------
PLUSA             
;<IND UM AKKU     
;INKREMENTIEREN   
CLC               
ADC <IND          
STA <IND          
BCC PLUSA1        
INC <IND+1        
PLUSA1 RTS        
;=================
;SCHALE EDITOR    
;=================
UINITMMU          
;PRAEKONF.REGISTER
;VORBELEGEN:      
;                 
LDA #%00111110    
STA MMUCR         
;**SYSTEM-IO      
;**EINBLENDEN     
STA PCRC          
LDA #%00000000    
STA PCRA          
LDA #%00111111    
STA PCRB          
;**KONFIGURATION  
;**64K RAM WAEHLEN
STA MMUCR         
RTS               
;-----------------
UDEFAU            
;FUNKTIONSTASTEN  
;RUECKSETZEN      
;                 
LDX #10           
DEFAU1 STX <XREG  
LDY #1            
CLC               
TXA               
ADC #[(DEFAULT-1) 
STA <IND          
LDA #](DEFAULT-1) 
ADC #0            
STA <IND+1        
LDA #<MYBANK      
STA <IND+2        
LDA #<IND         
JSR PFKEY         
LDX <XREG         
DEX               
BNE DEFAU1        
RTS               
;-----------------
COLD              
JSR UIRAMBANK     
;ORGSRC           
;...WERDEN KOPIERT
;                 
;****** START TEXT
LDX ORGSRC        
STX MEMTOP        
LDY ORGSRC+1      
STY MEMTOP+1      
;- - - - - - - - -
MENUE             
;*****************
;<-----           
;EINTRITT VON     
;BASIC AUS        
;*****************
JSR UINITMMU      
JSR UDEFAU        
;                 
MENUEC            
;*****************
;<---VOM COMPILER 
;    UND BEI BREAK
;*****************
JSR UINITMMU      
JSR UIWIDTH       
MENUE1            
;** ERRORPOINTER  
;** AUF BEREICH AB
;** $1400 UMSETZEN
;** (FUER RESTORE)
LDA #[STOP.IT     
STA ERRPTR        
LDA #]STOP.IT     
STA ERRPTR+1      
;                 
JSR UCOLREG       
LDA #0            
JSR SETMSG        
;                 
LDX #[PHYSTOP     
LDY #]PHYSTOP     
STX <TMEM         
STY <TMEM+1       
;*******TITELBILD:
LDA #[MSG1        
LDY #]MSG1        
JSR UINPUT        
LDA TAB           
CMP #"?"          
BEQ MENUE2        
CMP #"$"          
BEQ MENUE5        
CMP #"@"          
BEQ MENUE6        
CMP #"*"          
BEQ MENUE9        
LDA <LFD          
BNE MENUE1        
; KEIN * ODER     
; ? IM NAMEN!     
JSR MAINX         
BCC MENUE3        
;                 
MENUE0            
;** RESUME SPERREN
LDA #0            
STA RSMEFLG       
BEQ MENUE1        
;                 
MENUE2            
;** RESUME AUS-   
;** FUEHREN       
LDA RSMEFLG       
BEQ MENUE1        
JSR MAIN2         
BCS MENUE0        
;                 
MENUE3            
;** RESUME ERLAUBT
LDA #1            
STA RSMEFLG       
BNE MENUE1        
;                 
MENUE5            
JMP COMPILER      
;*****************
;--> COMPILER     
;RUECKKEHR UEBER  
;MENUEC           
;*****************
MENUE6            
;** DIRECTORY     
;** NAME AB TAB,1 
LDX #1            
JSR UDIRECT       
JMP MENUE1        
;                 
MENUE9            
;*****************
;--> BASIC        
;RUECKKEHR UEBER  
;MENUE            
;*****************
JMP GOBASIC       
;-----------------
UIRAMBANK         
RTS               
;ENTFAELLT!       
;=================
ENDMOD6           
;=================
;                 
EXP COLD,MENUE,   
MENUEC,ENDMOD6    
;                 
END