;=================
;   SCR.MOD4      
; SCREEN-EDITOR   
; VERSION C-128   
;=================
;                 
;13.8.1986        
;                 
;=================
;INPUT,OUTPUT,COPY
;DIRECTORY        
;=================
;                 
IMP SCR.DECL      
IMP SCR.SYST      
IMP SCR.CST       
IMP SCR.MOD1      
IMP SCR.MOD2      
IMP SCR.MOD3      
;                 
;LADE DIE GLOBALEN
;LABELS           
;                 
;=================
ORG ENDMOD3       
;                 
;=================
;EINGABE/AUSGABE  
;=================
UILINE            
;FUEGT EINE ZEILE 
;BEI ZNRL+17...   
;EIN. SETZT <TP   
;C=1 => FEHLER    
;                 
LDA FLAG+17       
CMP #2            
LDA ZNRL+17       
LDY ZNRH+17       
LDX #1            
BCS ILINE1        
JSR UINSA         
PHP               
INC ZNRL+17       
BNE ILINE2        
INC ZNRH+17       
BNE ILINE2        
ILINE1 JSR UINSB  
PHP               
ILINE2            
LDA <TZEIL        
LDY <TZEIL+1      
JSR TPADR         
PLP               
RTS               
;-----------------
DEFLT             
;SETZE DEFAULT    
;POSITON          
;(VOR ZEILE 0)    
LDA FLAG+17       
BNE DEFLT1        
LDA #2            
STA FLAG+17       
LDA #0            
STA ZNRL+17       
STA ZNRH+17       
DEFLT1 RTS        
;-----------------
COPY              
;KOPIERT TEILE    
;AUS EINEM        
;DATASET AUF      
;DER DISKETTE     
;MIT GERAETE-     
;ADRESSE A        
;                 
STA <FZAEHL       
JSR DEFLT         
LDA #[MSG3        
LDY #]MSG3        
JSR UINPUT        
;** NUR * ODER ?  
;** ==>ABBRUCH    
BCC COPY0         
CPX #1            
BEQ COPYQ         
COPY0 TXA         
LDX #[TAB         
LDY #]TAB         
JSR SETNAM        
LDA #1            
LDX <FZAEHL       
LDY #0            
JSR SETLFS        
LDA #1            
JSR CLOSE         
JSR OPEN          
BCC *+5           
JMP ENDX          
LDX #1            
JSR CHKIN         
;*****************
;STARTADRESSE     
;UEBERLESEN:      
;ABBRUCH,FALLS    
;FILE NOT FOUND   
;*****************
JSR CHRIN         
JSR CHRIN         
JSR READST        
BNE COPYQ         
;                 
JSR CHRIN         
STA <TSPAL        
JSR CHRIN         
STA <FZAEHL       
JSR CHRIN         
STA <FZAEHL+1     
JSR CLRCHN        
LDA <TSPAL        
CMP <TXTLEN       
BEQ COPY1         
;**   VERSCHIEDENE
;**    SATZLAENGE!
LDA #[MSG4        
LDY #]MSG4        
JSR UINPUT        
CPX #1            
BNE COPYQ         
LDA TAB           
CMP #"C"          
BEQ COPY1         
;                 
COPYQ             
;********** CANCEL
JMP ENDQ          
;                 
COPY1             
LDA #0            
STA <TZEIL        
STA <TZEIL+1      
LDA #[MSG5        
LDY #]MSG5        
JSR UINPUT        
BCS COPY3         
;************* ALL
LDX #0            
JSR URZAHL        
LDA <ERG          
STA <TZEIL        
LDA <ERG+1        
STA <TZEIL+1      
LDA #[MSG6        
LDY #]MSG6        
JSR UINPUT        
BCS COPY1         
LDX #0            
JSR URZAHL        
LDX <ERG          
LDY <ERG+1        
CPY <FZAEHL+1     
BCC COPY4         
BNE COPY3         
CPX <FZAEHL       
BCC COPY4         
COPY3             
;******** BIS ENDE
LDX <FZAEHL       
LDY <FZAEHL+1     
DEX               
CPX #255          
BNE COPY4         
DEY               
;                 
COPY4 SEC         
TXA               
SBC <TZEIL        
TAX               
TYA               
SBC <TZEIL+1      
BCC COPY1         
STX <FZAEHL       
STA <FZAEHL+1     
;** DIFFERENZ     
;** IN FZAEHL     
COPY5 CLC         
LDA <TZEIL        
ADC #3            
STA <MND          
LDA <TZEIL+1      
ADC #0            
STA <MND+1        
LDA <TSPAL        
STA <MOR          
JSR UMULTI        
CLC               
LDA <ERG          
ADC #1            
PHA               
LDA <ERG+1        
ADC #0            
PHA               
LDX #1            
JSR CHKIN         
PLA               
TAY               
PLA               
TAX               
;*****************
;STATUSZEILEN     
;ETC. UEBERLESEN  
;*****************
BEQ COPY7         
COPY6 JSR CHRIN   
DEX               
CPX #255          
BNE COPY6         
COPY7 DEY         
LDX #255          
CPY #255          
BNE COPY6         
;                 
COPY8             
JSR UILINE        
BCC COPY9         
JMP ENDE          
COPY9 LDY #0      
COPY11 JSR CHRIN  
STA (<TP),Y       
INY               
CPY <TXTLEN       
BEQ COPY13        
CPY <TSPAL        
BNE COPY11        
LDA #" "          
COPY12            
STA (<TP),Y       
INY               
CPY <TXTLEN       
BNE COPY12        
BEQ COPY14        
COPY13            
CPY <TSPAL        
BEQ COPY14        
JSR CHRIN         
INY               
BNE COPY13        
COPY14            
DEC <FZAEHL       
LDA <FZAEHL       
CMP #255          
BNE COPY8         
DEC <FZAEHL+1     
LDA <FZAEHL+1     
CMP #255          
BNE COPY8         
JMP ENDQ          
;-----------------
DIALOG            
;FUER SEQ. I/O    
;SETZT NAME,      
;PRIMAER- UND     
;SEKUNDAERADR.    
;AUF FILE #1      
;(INCL. OPEN)     
;C=1 => FEHLER    
;    X=0: CANCEL  
;SONST SYSERROR   
;                 
LDA #[MSG7        
LDY #]MSG7        
JSR ZINPUT        
LDX #0            
BCS DIA9          
STA <FZAEHL       
LDA #[MSG8        
LDY #]MSG8        
JSR ZINPUT        
BCC DIA1          
LDA #255          
DIA1 TAY          
LDX <FZAEHL       
LDA #1            
JSR SETLFS        
LDA #[MSG9        
LDY #]MSG9        
JSR UINPUT        
TXA               
LDX #[TAB         
LDY #]TAB         
JSR SETNAM        
JSR OPEN          
BCC DIA3          
;*****************
;SYSTEM ERROR...  
;*****************
STA <FEHLER       
LDX #255          
STX <CODE         
SEC               
RTS               
;                 
DIA3 LDA #[MSG10  
LDY #]MSG10       
JSR ZINPUT        
LDY #255          
BCC DIA4          
LDY #0            
DIA4 STA <FZAEHL  
STY <FZAEHL+1     
CLC               
DIA9 RTS          
;*****************
;FZAEHL+1 = 0     
;=>KEIN DELIM.    
;SONST:           
;FZAEHL=>DELIM.   
;-----------------
UOUT              
;SEQ. OUTPUT      
;                 
JSR DIALOG        
BCC OUT1          
CPX #0            
BEQ *+5           
JMP ENDE          
JMP ENDQ          
OUT1              
;*****************
; TRUNCATE        
; JA =>MMFLAG<>0  
;*****************
LDA #[MSG11       
LDY #]MSG11       
JSR UINPUT        
BCS OUT1          
CPX #1            
BNE OUT1          
LDA TAB           
CMP #"Y"          
BEQ OUT2          
CMP #"N"          
BNE OUT1          
LDA #0            
OUT2              
STA <MMFLAG       
LDA #0            
TAY               
JSR TPADR         
LDX #1            
JSR CHKOUT        
BCC OUT4          
JMP ENDX          
;                 
OUT4              
LDA <TP+1         
CMP <ENDE+1       
BCC OUT5          
LDA <TP           
CMP <ENDE         
BCC OUT5          
JMP ENDQ          
OUT5 LDY <TXTLEN  
LDA <MMFLAG       
BEQ OUT8          
OUT6 DEY          
LDA (<TP),Y       
CMP #" "          
BNE OUT7          
CPY #0            
BNE OUT6          
BEQ OUT10         
OUT7 INY          
OUT8 STY <LFD     
LDY #0            
OUT9 LDA (<TP),Y  
JSR CHROUT        
INY               
CPY <LFD          
BNE OUT9          
OUT10             
LDA <FZAEHL+1     
BEQ OUT11         
LDA <FZAEHL       
JSR CHROUT        
OUT11 CLC         
LDA <TP           
ADC <TXTLEN       
STA <TP           
BCC OUT4          
INC <TP+1         
BNE OUT4          
;-----------------
UIN               
;SEQ. INPUT       
;                 
JSR DIALOG        
BCC IN1           
CPX #0            
BNE *+5           
JMP ENDQ          
JMP ENDE          
;                 
IN1               
JSR DEFLT         
LDX #1            
JSR CHKIN         
LDA #0            
STA <MMFLAG       
;                 
IN2               
JSR UILINE        
BCS ENDE          
;                 
LDY #0            
LDX <FZAEHL+1     
IN3 JSR CHRIN     
PHA               
JSR READST        
CMP #1            
PLA               
BCS IN5           
CPX #0            
BEQ IN4           
CMP <FZAEHL       
BEQ IN6           
IN4 STA (<TP),Y   
INY               
CPY <TXTLEN       
BNE IN3           
BEQ IN8           
IN5 INC <MMFLAG   
IN6 LDA #" "      
IN7 STA (<TP),Y   
INY               
CPY <TXTLEN       
BNE IN7           
IN8 LDA <MMFLAG   
BEQ IN2           
BNE ENDQ          
;                 
ENDX STA <FEHLER  
LDA #255          
STA <CODE         
SEC               
BCS ENDE          
;                 
ENDQ CLC          
;                 
ENDE PHP          
JSR CLRCHN        
LDA #0            
STA FLAG+17       
LDA #1            
JSR CLOSE         
JSR UCOLOR        
PLP               
RTS               
;-----------------
UDIRECT           
;DIRECTORY ZEIGEN 
;NAME IN TAB+X    
;MIT (0) BEENDET  
;ZERSTOERT TAB!   
;                 
DEX               
LDY #0            
LDA #"$"          
STA TAB,Y         
DIR0 INX          
INY               
LDA TAB,X         
STA TAB,Y         
BNE DIR0          
;** Y=LAENGE      
TYA               
LDX #[TAB         
LDY #]TAB         
JSR SETNAM        
LDA #1            
JSR CLOSE         
LDA #1            
LDX DEFDRV        
LDY #96           
;SEKUNDAERADR.    
JSR SETLFS        
JSR OPEN          
BCS DIRERR        
;                 
LDX #1            
JSR CHKIN         
LDA #147          
JSR CHROUT        
;** BILDSCHIRM    
;** LOESCHEN      
LDA #3            
DIR1;             
STA <LFD          
;*****************
;IGNORIERE DIE    
;ERSTEN 2*A BYTES 
;*****************
DIR2 JSR CHRIN    
STA <FZAEHL       
JSR READST        
BNE DIRERR        
JSR CHRIN         
STA <FZAEHL+1     
JSR READST        
BNE DIRERR        
DEC <LFD          
BNE DIR2          
;FZAEHL DEZIMAL   
;AUSGEBEN:        
;                 
LDA <FZAEHL       
LDX <FZAEHL+1     
JSR UPRTDEZI      
LDA #" "          
JSR CHROUT        
;ZEILE DRUCKEN:   
DIR3              
JSR CHRIN         
BEQ DIR4          
TAX               
JSR READST        
BNE DIRERR        
TXA               
JSR CHROUT        
BCC DIR3          
DIR4              
LDA #13           
JSR CHROUT        
LDA #2            
;** 2*2 BYTES     
;** UEBERLESEN    
BNE DIR1          
;                 
DIRERR            
;********** ENDE  
JSR CLRCHN        
LDA #1            
JSR CLOSE         
;WARTE AUF TASTE  
DIR5  JSR GETIN   
CMP #0            
BEQ DIR5          
JMP UCOLOR        
;-----------------
;UPRTDEZI         
;SCHREIBT ZAHL    
;OHNE VORZEICHEN  
;UNTERDRUECKE VOR-
;LAUFENDE 0       
;L=>A             
;H=>X             
;(MAX 5 STELLEN)  
;                 
NLT               
DFD 16,232        
DFD 100,10,1      
NHT               
DFD 39,3          
DFD 0,0,0         
;                 
UPRTDEZI          
STX <ZH           
STA <ZL           
LDY #0            
STY <MOR          
;**FLAG FUER 0    
PRTDEZI1          
LDA NLT,Y         
STA <NL           
LDA NHT,Y         
STA <NH           
STY <YREG         
JSR UDIV          
LDY <YREG         
CLC               
LDA <ZL           
BNE PRTDEZI2      
CPY #4            
BEQ PRTDEZI2      
LDX <MOR          
BEQ PRTDEZI3      
;*KEINE VORLAUFEN-
;*DEN NULLEN (NUR 
;*EINERSTELLE)    
PRTDEZI2          
ORA #48           
JSR CHROUT        
INC <MOR          
;                 
PRTDEZI3          
LDA <HL           
STA <ZL           
LDA <HH           
STA <ZH           
INY               
CPY #5            
BNE PRTDEZI1      
RTS               
;=================
ENDMOD4           
;                 
EXP COPY,UDIRECT, 
UIN,UOUT,ENDMOD4  
;                 
END