;=================
;   SCR.MOD1      
; SCREEN-EDITOR   
; VERSION C-128   
;=================
;                 
;14.7.1986        
;                 
;SYSTEMABH. FKT.  
;BILDSCHIRM FKT.  
;TEXTZEIGER FKT.  
;=================
;                 
IMP SCR.SYST      
;FUER VICREG,MMU  
;UND COLOR        
IMP SCR.DECL      
IMP SCR.CST       
;                 
ORG ENDCONST      
;=================
; ALLG. HILFSFKT. 
;=================
UMULTI            
;MOR*MND=>ERG/MOR 
;(8*16)BIT        
;                 
LDY #0            
STY <ERG          
STY <ERG+1        
LDY #8            
MULTI1 ASL <ERG   
ROL <ERG+1        
ROL <MOR          
BCC MULTI2        
CLC               
LDA <ERG          
ADC <MND          
STA <ERG          
LDA <ERG+1        
ADC <MND+1        
STA <ERG+1        
BCC MULTI2        
INC <MOR          
MULTI2 DEY        
BNE MULTI1        
RTS               
;-----------------
UDIV              
;DIVISION         
;ZL&ZH/NL&NH      
;=> ZL&ZH         
;(16/16)BIT       
;                 
LDY #16           
LDA #0            
STA <HL           
STA <HH           
DIV2 ROL <ZL      
ROL <ZH           
ROL <HL           
ROL <HH           
SEC               
LDA <HL           
SBC <NL           
TAX               
LDA <HH           
SBC <NH           
BCC DIV3          
STA <HH           
STX <HL           
DIV3 DEY          
BNE DIV2          
ROL <ZL           
ROL <ZH           
RTS               
;-----------------
URZAHL            
;ZAHL LESEN       
;AB TAB,X         
;   =>ERG         
;                 
STX <ZAEHL        
LDA #0            
STA <ERG          
STA <ERG+1        
LDA TAB,X         
SEC               
SBC #48           
BCC RZAHL2        
CMP #10           
BCS RZAHL2        
STA <ERG          
RZAHL1 INC <ZAEHL 
LDX <ZAEHL        
SEC               
LDA TAB,X         
SBC #48           
BCC RZAHL2        
CMP #10           
BCS RZAHL2        
STA <LFD          
LDA #10           
STA <MOR          
LDA <ERG          
STA <MND          
LDA <ERG+1        
STA <MND+1        
JSR UMULTI        
LDA <ERG          
CLC               
ADC <LFD          
STA <ERG          
BCC RZAHL1        
INC <ERG+1        
BNE RZAHL1        
RZAHL2            
RTS               
;=================
;AUSGABEFUNKTIONEN
;ZEIGEROPERATIONEN
;FUER BILDSCHIRM  
;=================
USETR             
;SCHREIBT ASCII   
;AN LFD. POSITION 
;AENDERT NUR      
;SZEIL/SSPAL      
;UNTERER RAND!!   
;--------------   
;                 
STY <YREG         
LDY <SSPAL        
JSR USET          
INY               
CPY <MXCOL        
BCC SETR1         
INC <SZEIL        
JSR UNEXT         
LDY #0            
SETR1 STY <SSPAL  
LDY <YREG         
RTS               
;-----------------
USETAY            
;ZEICHEN A BIS    
;SPALTE Y AUS-    
;SCHLIESSLICH     
;SCHREIBEN        
;                 
STY <YREG         
LDY <SSPAL        
SETAY1            
CPY <YREG         
BEQ SETAY2        
PHA               
JSR USET          
PLA               
INY               
BNE SETAY1        
SETAY2            
STY <SSPAL        
RTS               
;-----------------
;UZAHL            
;SCHREIBT ZAHL    
;L=>A             
;H=>X             
;(<ZAHL=4 STELLEN)
;                 
NLT               
DFD 232,100,10,1  
NHT DFD 3,0,0,0   
;                 
UZAHL             
STX <ZH           
STA <ZL           
LDY #0            
ZLOOP             
LDA NLT,Y         
STA <NL           
LDA NHT,Y         
STA <NH           
STY <YREG         
JSR UDIV          
LDY <YREG         
CLC               
LDA <ZL           
ADC #48           
JSR USETR         
LDA <HL           
STA <ZL           
LDA <HH           
STA <ZH           
INY               
CPY #<ZAHL        
BNE ZLOOP         
RTS               
;-----------------
UTEXT             
;SCHREIBT TEXT    
;[IND] AUF DEN    
;SCHIRM BIS 0     
;AB LFD. POSITION 
;                 
LDY #0            
TEXT1             
LDA (<IND),Y      
BEQ TEXT9         
JSR USETR         
INY               
BNE TEXT1         
TEXT9 RTS         
;-----------------
UCENTER           
;DRUCKE TEXT (A,X)
;ZENTRIERT. WEITER
;IN NAECHSTE ZEILE
;                 
STA <IND          
STX <IND+1        
;                 
LDA #" "          
LDY #<ZAHL        
JSR USETAY        
;******ZENTRIEREN 
LDA <MXCOL        
LSR               
SEC               
SBC #4            
TAY               
LDA #"*"          
JSR USETAY        
JSR UTEXT         
LDA #"*"          
LDY <MXCOL        
JSR USETAY        
JMP UNEXT         
;-----------------
USADR             
;SETZT [<SP]      
;FUER SCHIRM      
;                 
LDA #0            
STA <MND+1        
LDA <SZEIL        
STA <MOR          
LDA <MXCOL        
STA <MND          
JSR UMULTI        
BIT <M4080        
BMI SADR1         
;****** 40 ZEICHEN
LDA <ERG          
CLC               
ADC #[SCREEN      
STA <SP           
LDA <ERG+1        
ADC #]SCREEN      
STA <SP+1         
RTS               
SADR1             
;****** 80 ZEICHEN
LDA <ERG          
STA <SP           
LDA <ERG+1        
STA <SP+1         
RTS               
;-----------------
UNEXT             
;SETZT ZEIGER     
;FUER SCHIRM AUF  
;NAECHSTE ZEILE   
;                 
LDA <SP           
CLC               
ADC <MXCOL        
STA <SP           
BCC NEXT1         
INC <SP+1         
NEXT1 RTS         
;-----------------
UPREV             
;SETZT ZEIGER     
;FUER SCHIRM AUF  
;VORHERIGE ZEILE  
;                 
LDA <SP           
SEC               
SBC <MXCOL        
STA <SP           
BCS PREV1         
DEC <SP+1         
PREV1 RTS         
;-----------------
UCSPR             
;SPRUNG AN BILD-  
;SCHIRMPOSITION   
;SPALTE=>A        
;ZEILE=>X         
;KEINE TESTS      
;===========      
;                 
STA <SSPAL        
STX <SZEIL        
JMP USADR         
;-----------------
UTEST             
;PRUEFT,OB CURSOR-
;POSITION IM      
;TEXTFENSTER      
;C=1 => JA        
;                 
LDA <SSPAL        
CMP #<ZAHL        
BCC TEST1         
CMP <SCLEN        
BCS TEST1         
LDA <SZEIL        
CMP <SCTOP        
BCC TEST1         
CMP <SCBOT        
BCS TEST1         
;IM BEREICH:      
SEC               
RTS               
TEST1 CLC         
RTS               
;-----------------
ZEILE             
;SCHREIBT ZEILE   
;AUS TEXT AUF     
;DEN SCHIRM       
;NUR LFD. ZEILE!! 
;---------------- 
;                 
LDA #<ZAHL        
STA <SSPAL        
JSR UTSPAL        
ZEILE1            
LDY <TSPAL        
CPY <TXTLEN       
BCS ZEILE2        
INC <TSPAL        
LDA (<TP),Y       
BCC ZEILE3        
ZEILE2            
LDA #" "          
;*****************
;" " AM RAND      
;*****************
ZEILE3 LDY <SSPAL 
JSR USET          
INY               
STY <SSPAL        
CPY <MXCOL        
BCC ZEILE1        
RTS               
;-----------------
UMWNDL            
;Y<= INDEX CODE-  
;TABELLE AUS X    
;                 
CPX #14           
BCS UMWND1        
TXA               
LSR               
TAY               
RTS               
UMWND1 CPX #16    
BCS UMWND2        
LDA FLAG,X        
AND #127          
CLC               
ADC #6            
TAY               
RTS               
UMWND2            
BNE UMWND3        
LDY #9            
RTS               
UMWND3            
LDA FLAG,X        
CLC               
ADC #9            
TAY               
RTS               
;-----------------
UZNR              
;SCHREIBT ZNR     
;ODER ZEILEN-     
;BEFEHL FUER      
;<TZEIL           
;                 
LDA #0            
STA <MMFLAG       
LDX #<CXIND       
ZNR1 LDA FLAG,X   
BEQ ZNR4          
LDA ZNRL,X        
CMP <TZEIL        
BNE ZNR4          
LDA ZNRH,X        
CMP <TZEIL+1      
BNE ZNR4          
LDA <MMFLAG       
BNE ZNR45         
JSR UMWNDL        
LDA CODE,Y        
JSR USETR         
LDA FLAG,X        
BMI ZNR2          
LDA #" "          
BNE ZNR3          
ZNR2 LDA CODE,Y   
ZNR3 JSR USETR    
LDA #" "          
JSR USETR         
LDA #" "          
JSR USETR         
INC <MMFLAG       
ZNR45 LDA #0      
STA FLAG,X        
;                 
ZNR4 DEX          
BPL ZNR1          
;                 
LDA <MMFLAG       
BNE ZNR5          
LDA <TZEIL        
LDX <TZEIL+1      
JSR UZAHL         
ZNR5 RTS          
;-----------------
UZEILE            
;SCHREIBT ZEILE   
;(AKKU)           
;INITIALISIERT    
;ALLE ZEIGER      
;                 
STA <SZEIL        
JSR USADR         
JSR UTZEIL        
JSR UTP           
LDA #0            
STA <SSPAL        
LDA <TZEIL+1      
CMP TXTBOT+<MXIND 
BCC ZLE3          
BNE ZLE2          
LDA <TZEIL        
CMP TXTBOT        
BCC ZLE3          
BNE ZLE2          
;***********BOTTOM
LDA #[TXT2        
LDX #]TXT2        
JMP UCENTER       
;                 
ZLE2              
;********LEERZEILE
LDA #" "          
LDY <MXCOL        
JMP USETAY        
ZLE3 JSR UZNR     
JMP ZEILE         
;-----------------
GRENZE            
;SCBOT/SCLEN      
;BESTIMMEN        
;                 
SEC               
LDA TXTBOT        
SBC ANFZEI        
PHA               
LDA TXTBOT+<MXIND 
SBC ANFZEI+<MXIND 
TAX               
PLA               
CLC               
ADC <SCTOP        
BCC GRENZ1        
INX               
GRENZ1 CPX #0     
BEQ GRENZ2        
LDA #$FF          
GRENZ2            
STA <SCBOT        
;                 
LDA <TXTLEN       
SEC               
SBC <ANFSPA       
CLC               
ADC #<ZAHL        
BCC GRENZ3        
LDA #$FF          
GRENZ3 STA <SCLEN 
RTS               
;-----------------
TXT1              
DFD "* TOP **",0  
TXT2              
DFD " BOTTOM ",0  
;-----------------
UBILD             
;BILDAUFBAU       
;KOMPLETT OHNE    
;KOPF. XREG.      
;ENTHAELT WERT    
;FUER 1. ZEILE    
;                 
STX <SCTOP        
LDA #0            
STA <TOPFLG       
LDA ANFZEI        
ORA ANFZEI+<MXIND 
BNE BILD0         
INX               
STX <SCTOP        
LDA #0            
DEX               
STX <TOPFLG       
JSR UCSPR         
;************TOP  
LDA #[TXT1        
LDX #]TXT1        
JSR UCENTER       
;                 
BILD0 JSR GRENZE  
LDA <SCTOP        
STA <ZAEHL        
BILD1             
JSR UZEILE        
INC <ZAEHL        
LDA <ZAEHL        
CMP #<MXLIN       
BNE BILD1         
RTS               
;=================
;UMWANDLUNGSFKT.  
; BILD <-> TEXT   
;=================
UTSPAL            
;WANDELT SPALTE   
;AUF SCHIRM IN    
;SPALTE IM TEXT   
;                 
SEC               
LDA <SSPAL        
SBC #<ZAHL        
CLC               
ADC <ANFSPA       
TAY               
STY <TSPAL        
RTS               
;-----------------
UTZEIL            
;WANDELT ZEILE    
;AUF SCHIRM IN    
;ZEILE IM TEXT    
;                 
SEC               
LDA <SZEIL        
SBC <SCTOP        
CLC               
ADC ANFZEI        
STA <TZEIL        
LDA ANFZEI+<MXIND 
ADC #0            
STA <TZEIL+1      
RTS               
;-----------------
UONSCR            
;TESTET,OB DIE    
;ALTE POSITION    
;AUF LFD. BILD    
;IST ,            
;                 
;SPALTE =>A       
;ZEILE  =>X       
;Y=>CODE FUER     
;  AUSSERHALB     
;                 
;C=1 => JA        
;                 
LDY #0            
SEC               
LDA <ASPAL        
SBC <ANFSPA       
BCC ONSCR1        
CLC               
ADC #<ZAHL        
BCS ONSCR1        
CMP <MXCOL        
BCC ONSCR2        
ONSCR1 INY        
ONSCR2 STA <LFD   
SEC               
LDA AZEIL         
SBC ANFZEI        
TAX               
LDA AZEIL+<MXIND  
SBC ANFZEI+<MXIND 
BCC ONSCR3        
BNE ONSCR3        
TXA               
CLC               
ADC <SCTOP        
BCS ONSCR3        
CMP #<MXLIN       
BCC ONSCR4        
ONSCR3 INY        
INY               
ONSCR4 CPY #0     
BNE ONSCR5        
TAX               
LDA <LFD          
SEC               
RTS               
ONSCR5            
;                 
;**AUSSERHALB     
;                 
LDA #0            
TAX               
CLC               
RTS               
;-----------------
UMOVE             
;SETZT ANFZEI     
;UND ANFSPA FUER  
;TEXTPOSITION     
;                 
JSR UONSCR        
TYA               
AND #1            
BEQ MOVE2         
SEC               
LDA <ASPAL        
SBC #<MSPAL       
BCS MOVE1         
LDA #0            
MOVE1             
STA <ANFSPA       
;                 
MOVE2 TYA         
AND #2            
BEQ MOVE4         
SEC               
LDA AZEIL         
SBC #<MZEIL       
TAX               
LDA AZEIL+<MXIND  
SBC #0            
BCS MOVE3         
LDA #0            
TAX               
MOVE3             
STX ANFZEI        
STA ANFZEI+<MXIND 
;                 
MOVE4             
RTS               
;=================
;ZEIGEROPERATIONEN
;IM TEXT          
;=================
UTP               
;SETZT ZEIGER <TP 
;IN TEXT          
;                 
LDA <TXTLEN       
STA <MOR          
LDA <TZEIL        
STA <MND          
LDA <TZEIL+1      
STA <MND+1        
JSR UMULTI        
LDA <ERG          
CLC               
ADC <BASIS        
STA <TP           
LDA <ERG+1        
ADC <BASIS+1      
STA <TP+1         
RTS               
;=================
;OPERATIONEN IN   
;EINER TEXTZEILE  
;=================
UDELE             
;LOESCHT X-ZEI-   
;CHEN IM TEXT     
;AB (<TP)         
;                 
CPX #0            
BEQ DELE9         
DELE1 LDY <TSPAL  
DELE2 INY         
CPY <RBND         
BCS DELE3         
LDA (<TP),Y       
DEY               
STA (<TP),Y       
INY               
BNE DELE2         
DELE3 BNE DELE9   
DEY               
LDA #" "          
STA (<TP),Y       
DEX               
BNE DELE1         
DELE9 RTS         
;-----------------
UINSE             
;X-ZEICHEN NACH   
;(<TP) EINFUEGEN  
;ZEILENENDE EVTL. 
;LOESCHEN         
;                 
CPX #0            
BEQ INSE9         
INSE0             
LDY <RBND         
INSE1 DEY         
CPY <TSPAL        
BEQ INSE2         
DEY               
LDA (<TP),Y       
INY               
STA (<TP),Y       
JMP INSE1         
INSE2             
LDA (<TP),Y       
INY               
STA (<TP),Y       
DEY               
LDA #" "          
STA (<TP),Y       
DEX               
BNE INSE0         
INSE9 RTS         
;-----------------
UFRE              
;X =>ANZAHL DER   
;BLANKS AM ZEI-   
;LENENDE          
;BIS TSPAL !!     
LDX #0            
LDY <RBND         
FRE1 CPY <TSPAL   
BEQ FRE9          
DEY               
LDA (<TP),Y       
CMP #" "          
BNE FRE9          
INX               
BNE FRE1          
FRE9 RTS          
;=================
CODE              
;TABELLE ALLER    
;LINE-COMMANDS    
DFD "DR)(><"      
DFD "OMCIAB"      
;                 
;=================
;SYSTEMABHAENGIGE 
;  OPERATIONEN    
;=================
USET              
;SETZT ASCII AUF  
;BILDSCHIRM AN DER
;POSITION (<SP),Y 
;                 
CMP #$80          
BCC SET1          
AND #$7F          
CMP #$20          
BCC SET8          
ORA #$40          
BNE SET3          
SET1 CMP #$20     
BCC SET9          
CMP #$60          
BCC SET2          
AND #$DF          
BNE SET3          
SET2 AND #$3F     
SET3              
JMP USET4080      
;*****************
;"" BEI CTRL.    
;*****************
SET8 ORA #$40     
SET9 ORA #$80     
JMP USET4080      
;-----------------
UGETSCR           
;HOLT LFD. (<SP),Y
;IN ASCII VOM     
;SCHIRM           
;                 
BIT <M4080        
BPL GET0          
;****** 80 ZEICHEN
JSR UGET80        
DFD $2C           
;****** 40 ZEICHEN
GET0 LDA (<SP),Y  
STA <LFD          
AND #$3F          
ASL <LFD          
BIT <LFD          
BPL GET1          
ORA #$80          
GET1              
BVS GET2          
ORA #$40          
GET2 RTS          
;-----------------
UCURSR            
;CURSOR SETZEN    
;UND LOESCHEN     
;AN LFD. POS.     
;                 
JSR USADR         
LDY <SSPAL        
BIT <M4080        
BMI CURSR0        
;****** 40 ZEICHEN
LDA (<SP),Y       
EOR #$80          
STA (<SP),Y       
RTS               
;****** 80 ZEICHEN
CURSR0            
JMP UCUR80        
;=================
;#################
;#################
;DIE FOLGENDEN    
 ROUTINEN DUERFEN 
;KEINESFALLS IM   
;I/O-BEREICH      
; ($D000-$DFFF)   
;STEHEN!          
;#################
;#################
UCOLREG           
;INITIALSIERE     
;ALLE FARBREGISTER
;** SYSTEM I/O    
;** EINBLENDEN    
STA LCRC          
;                 
BIT <M4080        
BMI COLREG1       
;****** 40 ZEICHEN
LDA COLTAB        
STA VICREG        
LDA COLTAB+1      
STA VICREG+1      
LDA COLTAB+3      
STA <ERG          
LDA COLTAB+4      
STA <ERG+1        
LDA COLTAB+7      
LDX #[COLOR       
LDY #]COLOR       
JMP COLREG2       
;****** 80 ZEICHEN
COLREG1           
LDA COLTAB+2      
LDX #26           
JSR UVDCREG       
LDA COLTAB+5      
STA <ERG          
LDA COLTAB+6      
STA <ERG+1        
LDA COLTAB+8      
LDX #[COLOR80     
LDY #]COLOR80     
;                 
COLREG2           
STX <SP           
STY <SP+1         
JMP CHROUT        
STA LCRB          
RTS               
;-----------------
UCOLOR            
;INITIALISIERT    
;ALLE FARBEN      
JSR UCOLREG       
;(<SP) ZEIGT      
;AUF FARB-RAM     
;**KONFIGURATION: 
STA LCRC          
;**KONTROLLZEICHEN
;**FUER FARBE     
LDX #1            
LDY <MXCOL        
DEY               
LDA <ERG          
COLOR1            
JSR USET4080      
DEY               
BPL COLOR1        
;                 
COLOR2            
LDA <SP           
CLC               
ADC <MXCOL        
STA <SP           
BCC COLOR3        
INC <SP+1         
COLOR3            
LDY <MXCOL        
DEY               
LDA <ERG+1        
COLOR4            
JSR USET4080      
DEY               
CPY #<ZAHL        
BCS COLOR4        
LDA <ERG          
COLOR5            
JSR USET4080      
DEY               
BPL COLOR5        
INX               
CPX #<MXLIN       
BNE COLOR2        
;** SYSTEM I/O    
;** AUSBLENDEN    
STA LCRB          
RTS               
;-----------------
UVDCDAT           
;                 
LDX #$1F          
;* DATA-REGISTER  
;                 
UVDCREG           
;VDC-REGISTER     
;SETZEN           
;                 
STX VDC           
VDCREG1           
BIT VDC           
BPL VDCREG1       
;                 
STA VDC+1         
RTS               
;-----------------
UVDCUPD           
;UPDATE-REGISTER  
;AUF <SP+Y SETZEN 
;                 
;A,X ZERSTOERT!   
LDX #$12          
CLC               
TYA               
ADC <SP           
PHA               
LDA #0            
ADC <SP+1         
JSR UVDCREG       
PLA               
INX               
JMP UVDCREG       
;-----------------
UVDCGET           
;DATA-REGISTER    
;SETZEN           
;                 
LDX #$1F          
STX VDC           
VDCGET1           
BIT VDC           
BPL VDCGET1       
;                 
LDA VDC+1         
RTS               
;-----------------
USET4080          
;** A AN (<SP),Y  
;** SETZEN        
BIT <M4080        
BMI USET80        
;****** 40 ZEICHEN
STA (<SP),Y       
RTS               
;                 
USET80            
;80 ZEICHEN SETZEN
;                 
PHA               
STA LCRC          
;** I/O EINBLENDEN
STX <XLOCAL       
JSR UVDCUPD       
PLA               
JSR UVDCDAT       
LDX <XLOCAL       
;** I/O AUSBLENDEN
STA LCRB          
RTS               
;-----------------
UGET80            
;80 ZEICHEN LESEN 
;                 
STA LCRC          
;** I/O EINBLENDEN
STX <XLOCAL       
JSR UVDCUPD       
JSR UVDCGET       
LDX <XLOCAL       
;** I/O AUSBLENDEN
STA LCRB          
RTS               
;-----------------
UCUR80            
;80 ZEICHEN CURSOR
;UMSCHALTEN.      
STA LCRC          
;** I/O EINBLENDEN
STX <XLOCAL       
JSR UVDCUPD       
JSR UVDCGET       
EOR #$80          
PHA               
JSR UVDCUPD       
PLA               
JSR UVDCDAT       
LDX <XLOCAL       
;** I/O AUSBLENDEN
STA LCRB          
RTS               
;                 
;=================
ENDMOD1           
;=================
EXP USET,UCOLOR,  
UCOLREG,          
UGETSCR,UCURSR,   
;                 
UMULTI,UDIV,      
URZAHL,           
;                 
USETR,UZAHL,      
USETAY,           
UTEXT,USADR,      
UNEXT,UPREV,      
UCSPR,UTEST,      
ZEILE,UBILD,      
;                 
UTSPAL,UTZEIL,    
UONSCR,UMOVE,UTP, 
;                 
UDELE,UINSE,      
UFRE,             
;                 
CODE,ENDMOD1      
;                 
END