;=================
;   SCR.MOD6      
; SCREEN-EDITOR   
;=================
;                 
;3.6.1986         
;                 
;=================
;CURSORBEWEGUNGEN 
;HAUPTPROGRAMM    
;EINBINDUNG PASCAL
;=================
;                 
IMP SCR.DECL      
IMP SCR.SYST      
;(WEGEN PASCAL)   
IMP SCR.MOD1      
IMP SCR.MOD2      
IMP SCR.MOD3      
IMP SCR.MOD4      
IMP SCR.MOD5      
;                 
;LADE DIE GLOBALEN
;LABELS           
;                 
;=================
ORG ENDMOD5       
;                 
;=================
;LOKALE VARIABLEN:
;                 
TEMPFLG EQU 907   
RSMEFLG EQU 908   
PNT     EQU 909   
COMP    EQU 923   
;START COMPILER!  
;RUECKKEHR RETURN 
;                 
READY   EQU $A474 
BASCLR  EQU $A660 
BASINT  EQU $E3BF 
VEKTOR  EQU $E453 
BASCMD  EQU $A7E7 
;(BEFPNT) ALT!    
;                 
ERRPTR  EQU $300  
BEFPNT  EQU $308  
;                 
<CHGET  EQU $0073 
<CHGOT  EQU $0079 
;                 
;=================
;CURSORSTEUERUNG  
;=================
UP                
;                 
LDA <SZEIL        
BEQ UP1           
DEC <SZEIL        
JMP UPREV         
UP1 LDX #<MXLIN   
DEX               
LDA <SSPAL        
JMP UCSPR         
;-----------------
DOWN              
;                 
INC <SZEIL        
LDA <SZEIL        
CMP #<MXLIN       
BEQ DOWN1         
JMP UNEXT         
DOWN1 LDX #0      
LDA <SSPAL        
JMP UCSPR         
;-----------------
LEFT              
;                 
LDA <SSPAL        
BEQ LEFT1         
DEC <SSPAL        
RTS               
LEFT1 LDX #<MXCOL 
DEX               
STX <SSPAL        
RTS               
;-----------------
RIGHT             
;CURSOR NACH      
;RECHTS. BEACHTE  
;TEXTMODUS        
;                 
INC <SSPAL        
LDA <SSPAL        
CMP #<MXCOL       
BNE SKIP2         
BIT <TEFLAG       
BPL SKIP1         
JSR UTEST         
BCC SKIP1         
JMP QRIGHT        
;                 
SKIP              
;CURSOR AUF BILD  
;NACH RECHTS      
;                 
INC <SSPAL        
LDY <SSPAL        
CPY #<MXCOL       
BNE SKIP2         
SKIP1             
LDY #0            
STY <SSPAL        
SKIP2 RTS         
;-----------------
RETRN             
;                 
JSR UTEST         
BCC RETRN1        
BIT <TEFLAG       
BMI UCRLF         
RETRN1 LDA #0     
STA <SSPAL        
JMP DOWN          
;- - - - - - - - -
UCRLF             
;                 
JSR UAPOS         
LDA APOS          
BEQ UCRLF1        
JSR CRLF          
JSR UMOVE         
UCRLF1 JMP UNPOS  
;-----------------
CRLF              
;ASPAL AUF DEN    
;NAECHSTEN        
;ZEILENBEGINN     
;                 
LDY <LBND         
STY <ASPAL        
LDY AZEIL+<MXIND  
LDX AZEIL         
INX               
BNE CRLF1         
INY               
CRLF1 CPX TXTBOT  
BNE CRLF2         
CPY TXTBOT        
BNE CRLF2         
LDX #0            
LDY #0            
CRLF2 STX AZEIL   
STY AZEIL+<MXIND  
RTS               
;-----------------
UDSPCMD           
;KOMMANDOZEILE AUS
;TAB ANZEIGEN     
JSR HOME1         
LDY #0            
DSPCMD1 LDA TAB,Y 
JSR USETR         
INY               
CPY #<SCRLC       
BNE DSPCMD1       
RTS               
;-----------------
SCNCLR            
;                 
LDY #0            
LDA #" "          
SCNCLR1 STA TAB,Y 
INY               
CPY #<SCRLC       
BNE SCNCLR1       
JSR UDSPCMD       
JSR USETAY        
LDA #255          
STA <COMFLG       
BNE HOME1         
;- - - - - - - - -
HOME              
;                 
LDA <SSPAL        
ORA <SZEIL        
BNE HOME1         
LDA #<SCRLC       
LDX #<SCRLL       
JMP UCSPR         
HOME1 LDA #0      
TAX               
JMP UCSPR         
;-----------------
UPOS              
;BESTIMME CURSOR- 
;POSITION:        
;******C=1********
;(<TP),Y ZEIGT IN 
;TEXT (Y=<TSPAL)  
;X=FELDLAENGE     
;A=0:TEXT         
;A=1:TAB          
;A=2:BND          
;A=3:MSK          
;A=4 COMMAND      
;                 
;A=5 SCROLL       
;A=6 ZAHLBEREICH  
;*****C=0*********
;A=255            
;GESPERRT         
;                 
JSR UTEST         
BCS IN.TEXT       
LDY <SSPAL        
LDA <SZEIL        
BNE POS1          
CPY #<SCRLC       
BCS IN.SCRL       
;**********COMMAND
LDA <COMFLG       
BNE POS0          
JSR SCNCLR        
POS0              
LDY <SSPAL        
STY <TSPAL        
LDA #[TAB         
LDX #]TAB         
STA <TP           
STX <TP+1         
LDX #<SCRLC       
LDA #4            
SEC               
RTS               
;*****************
IN.SCRL           
LDA #5            
SEC               
RTS               
;*****************
IN.TEXT           
JSR UTZEIL        
JSR UTSPAL        
JSR UTP           
LDX <TXTLEN       
LDY <TSPAL        
LDA #0            
SEC               
RTS               
;*****************
POS1              
CPY #<ZAHL        
BCS POS2          
CMP <TOPFLG       
BEQ IN.ZAHL       
CMP <SCTOP        
BCC POSA          
CMP <SCBOT        
BCC IN.ZAHL       
;********BLOCKIERT
POSA LDA #255     
CLC               
RTS               
;*****************
IN.ZAHL           
LDA #6            
SEC               
RTS               
;*****************
POS2              
CPY <SCLEN        
BCS POSA          
CMP <MSKFLG       
BNE POS3          
;************MASKE
LDA MASK          
LDX MASK+<MXIND   
LDY #3            
BNE POS5          
POS3 CMP <BNDFLG  
BNE POS4          
;*************BNDS
LDA BNDS          
LDX BNDS+<MXIND   
LDY #2            
JMP POS5          
POS4 CMP <TABFLG  
BNE POSA          
;*************TABS
LDA TABU          
LDX TABU+<MXIND   
LDY #1            
POS5              
STA <TP           
STX <TP+1         
STY <YREG         
JSR UTSPAL        
LDX <TXTLEN       
LDA <YREG         
SEC               
RTS               
;-----------------
UENTER            
;                 
LDA <LFD          
STA (<TP),Y       
;- - - - - - - - -
UDISPLAY          
;                 
LDY <SSPAL        
LDA <LFD          
JMP USET          
;-----------------
ZEICH             
;SETZT ZEICHEN A  
;VON TASTATUR     
;AN LFD. POS.     
;                 
STA <LFD          
JSR UPOS          
BCC ZEICHX        
BNE ZEICH2        
;** IM TEXT       
JSR UENTER        
BIT <TEFLAG       
BMI ZEICH0        
JMP SKIP          
;                 
ZEICH0            
;** TEXT MODUS    
LDY <TSPAL        
INY               
CPY <RBND         
BNE ZEICH1        
JMP RETRN         
ZEICH1 JMP RIGHT  
;                 
ZEICH2            
CMP #5            
BEQ ZEICH3        
CMP #6            
BEQ ZEICH4        
;** TEXT,PROFILE  
;** ODER COMMAND  
JSR UENTER        
JMP RIGHT         
;                 
ZEICH3            
;** SCROLL        
JSR UDISPLAY      
JSR SKIP          
CPY #0            
BEQ ZEICHX        
LDA #" "          
JMP USET          
;                 
ZEICH4            
;** LINE COMM.    
JSR UDISPLAY      
JSR SKIP          
CPY #<ZAHL        
BEQ ZEICHX        
LDA #" "          
JMP USET          
ZEICHX RTS        
;-----------------
SRETRN            
;SHIFT RETURN     
;FALLS NICHT FIND-
;BEFEHL GEFUNDEN  
;                 
JSR UAPOS         
BNE SRETR9        
BIT <TEFLAG       
BPL SRETR9        
LDA APOS          
BEQ SRETR9        
LDA TABU          
STA <IND          
LDA TABU+<MXIND   
STA <IND+1        
LDY <ASPAL        
SRETR1 INY        
CPY <RBND         
BCS SRETR2        
LDA (<IND),Y      
CMP #" "          
BEQ SRETR1        
STY <ASPAL        
JMP SRETR3        
SRETR2            
JSR CRLF          
SRETR3            
JSR UMOVE         
SRETR9            
JMP UNPOS         
;-----------------
QUP               
; BILD HOCH       
JSR UAPOS         
SEC               
LDA ANFZEI        
SBC <SCRLV        
TAX               
LDA ANFZEI+<MXIND 
SBC #0            
BCS QUP1          
LDA #0            
TAX               
QUP1              
STA ANFZEI+<MXIND 
STX ANFZEI        
JMP UNPOS         
;-----------------
QDOWN             
; BILD RUNTER     
;                 
JSR UAPOS         
CLC               
LDA ANFZEI        
ADC <SCRLV        
TAX               
LDA ANFZEI+<MXIND 
ADC #0            
CMP TXTBOT+<MXIND 
BCC QDOWN1        
BNE QDOWN0        
CPX TXTBOT        
BCC QDOWN1        
QDOWN0            
LDX TXTBOT        
LDA TXTBOT+<MXIND 
QDOWN1            
STX ANFZEI        
STA ANFZEI+<MXIND 
JMP UNPOS         
;-----------------
QLEFT             
; BILD LINKS      
;                 
JSR UAPOS         
SEC               
LDA <ANFSPA       
SBC <SCRLH        
BCS QLEFT1        
LDA #0            
QLEFT1 STA <ANFSPA
JMP UNPOS         
;-----------------
QRIGHT            
; BILD RECHTS     
;                 
JSR UAPOS         
CLC               
LDA <ANFSPA       
ADC <SCRLH        
BCS QRGHT1        
CMP <TXTLEN       
BCC QRGHT2        
QRGHT1 LDX <TXTLEN
DEX               
TXA               
QRGHT2            
STA <ANFSPA       
JMP UNPOS         
;-----------------
DELETE            
;LOESCHE ZEICHEN  
;LINKS VOM CURSOR 
;CURSOR NACH LINKS
;                 
JSR UAXPOS        
BCC DEL2          
CMP #5            
BCS DEL2          
CPY #0            
BEQ DEL2          
;                 
STX <YREG         
DEL1              
LDA (<TP),Y       
DEY               
STA (<TP),Y       
INY               
INY               
CPY <YREG         
BNE DEL1          
LDA #" "          
DEY               
STA (<TP),Y       
JSR UNXPOS        
JMP LEFT          
DEL2 RTS          
;-----------------
INSERT            
;FUEGE LEERZEICHEN
;BEIM CURSOR EIN  
;                 
JSR UAXPOS        
BCC INS4          
CMP #5            
BCS INS4          
;                 
STY <YREG         
TXA               
TAY               
DEY               
LDA (<TP),Y       
CMP #" "          
BNE INS3          
;** ZEILE VOLL    
;                 
INS1 CPY <YREG    
BEQ INS2          
DEY               
LDA (<TP),Y       
INY               
STA (<TP),Y       
DEY               
BNE INS1          
INS2 LDA #" "     
STA (<TP),Y       
INS3 JMP UNXPOS   
INS4 RTS          
;-----------------
UAXPOS            
;MERKE CURSOR FUER
;ZEILENKORREKTUR  
;                 
LDA <SSPAL        
STA <XSPAL        
LDA <SZEIL        
STA <XZEIL        
JSR UPOS          
STA <LFD          
RTS               
;-----------------
UNXPOS            
;RESTAURIERE DIE  
;ZEILE UND DIE    
;CURSORPOSITION   
;A = 4 KOPFZEILE, 
;SONST PROFILE    
;ODER TEXT        
;                 
LDA <LFD          
CMP #4            
BNE NXPOS1        
JSR UDSPCMD       
JMP NXPOS2        
NXPOS1 LDA <XZEIL 
JSR ZEILE         
NXPOS2 LDA <XSPAL 
LDX <XZEIL        
JMP UCSPR         
;-----------------
DOFIND            
;WIEDERHOLE FIND- 
;KOMMANDO         
;                 
JSR UAPOS         
JSR RFIND         
JMP UNPOS         
;-----------------
DOCHANG           
;WIEDERHOLE       
;CHANGE-KOMMANDO  
;                 
JSR UAPOS         
JSR RCHNG         
JMP UNPOS         
;-----------------
FUNKT             
;WARTE AUF EINE   
;TASTE. SETZE     
;ZEICHEN ODER     
;FUEHRE EINE      
;FUNKTION AUS     
;                 
JSR UCURSR        
FUNKT1            
JSR GETIN         
BEQ FUNKT1        
STA <LFD          
JSR UCURSR        
LDA <LFD          
;                 
LDX #15           
;** LAENGE        
;** KEYTAB        
FUNKT2            
CMP KEYTAB,X      
BEQ FUNKT3        
DEX               
BPL FUNKT2        
JMP ZEICH         
FUNKT3            
TXA               
ASL               
TAX               
LDA KSPRTAB,X     
STA <IND          
LDA KSPRTAB+1,X   
STA <IND+1        
JMP (<IND)        
;-----------------
KEYTAB            
;TABELLE ALLER    
;ASCII-CODES      
;DER FUNKTIONS-   
;TASTEN;          
DFD 141,13,20,148 
DFD "“‘?…†‡ˆ‰Š"
;-----------------
KSPRTAB           
DFD SRETRN,RETRN  
DFD DELETE,INSERT 
DFD HOME,SCNCLR   
DFD UP,DOWN       
DFD LEFT,RIGHT    
DFD QUP,QDOWN     
DFD QLEFT,QRIGHT  
DFD DOFIND,DOCHANG
;=================
UAPOS             
;APOS = 255:      
;CURSORPOSITION   
;STEHT IN ASPAL   
;UND AZEIL(L/H)   
;APOS = 0:        
;CURSOR WAR       
;NICHT IM TEXT    
;                 
;BILD KOMPLETT    
;AUSWERTEN!       
;A<>0, FALLS FIND 
;                 
JSR UTEST         
BCC APOS1         
;**********IM TEXT
JSR UTZEIL        
JSR UTSPAL        
JSR UTP           
LDA <TSPAL        
STA <ASPAL        
LDA <TZEIL        
STA AZEIL         
LDA <TZEIL+1      
STA AZEIL+<MXIND  
LDA #255          
JMP APOS2         
;                 
APOS1             
;*******AUSSERHALB
LDA <SZEIL        
STA <XZEIL        
LDA #0            
STA <XSPAL        
;                 
APOS2 STA APOS    
LDA #0            
STA <FEHLER       
STA <FNDFLG       
;                 
JSR ULCOM         
JSR URTAB         
JSR URSCRL        
;                 
JSR UPRIM         
;                 
LDA <FEHLER       
BNE APOS3         
JSR URBND         
BCS APOS3         
JSR UEXLCO        
;                 
APOS3 LDA <FNDFLG 
RTS               
;=================
UNPOS             
;DER CURSOR       
;SPRINGT AUF      
;ALTE TEXTPOS.,   
;FALLS DIESE      
;NOCH AUF DEM     
;NEUEN BILD       
;IST. SONST AN    
;DIE LINKE        
;OBERE ECKE       
;                 
;BILDAUFBAU       
;                 
LDA #0            
STA <COMFLG       
;                 
JSR UTOP          
;                 
JSR UBILD         
LDA APOS          
BEQ NPOS1         
JSR UONSCR        
JMP UCSPR         
NPOS1 LDA <XSPAL  
LDX <XZEIL        
JMP UCSPR         
;=================
;HAUPTSCHLEIFE    
;MAINX UND MAIN2  
;CLC FALLS OK     
;=================
QUIT SEC          
RTS               
;                 
MAINX             
;*****************
;<----------      
;AUFRUF NEUER NAME
;X=LAENGE IN TAB  
;*****************
CPX #0            
BEQ QUIT          
CPX #17           
BCS QUIT          
STX LAENGE        
MAIN0             
LDA TAB,X         
STA NAME,X        
DEX               
BPL MAIN0         
LDA #0            
LDX LAENGE        
JSR ULOAD         
BCC MAIN2         
LDA TAB           
CMP #"6"          
BNE QUIT          
LDA TAB+1         
CMP #"2"          
BNE QUIT          
;** FILE NOT FOUND
;** NEUES DATASET 
JSR UDISKI        
;**  BLINKEN AUS! 
MAIN1 LDA #[MSG2  
LDY #]MSG2        
JSR ZINPUT        
BCS QUIT          
BEQ MAIN1         
CPY #0            
BNE MAIN1         
CMP #81           
BCS MAIN1         
STA <LFD          
;*****************
;MIT SATZLAENGE   
;INITIALISIEREN:  
;*****************
SEC               
JSR MEMBOT        
STX <IND          
STY <IND+1        
LDY #0            
LDA <LFD          
STA (<IND),Y      
INY               
LDA #0            
STA (<IND),Y      
INY               
STA (<IND),Y      
LDA #5            
JSR PLUSA         
JSR UINITP        
MAIN2             
;*****************
;<----------      
;AUFRUF ALTER NAME
;NAME,LAENGE SIND 
;GUELTIG          
;*****************
SEC               
JSR MEMBOT        
STX <IND          
STY <IND+1        
LDY #0            
LDA (<IND),Y      
STA <TXTLEN       
INY               
LDA (<IND),Y      
STA TXTBOT        
INY               
LDA (<IND),Y      
STA TXTBOT+<MXIND 
LDA <IND          
LDX <IND+1        
CLC               
ADC #5            
BCC MAIN5         
INX               
MAIN5             
STA MASK          
STX MASK+<MXIND   
JSR PLUS          
STA BNDS          
STX BNDS+<MXIND   
JSR PLUS          
STA TABU          
STX TABU+<MXIND   
JSR PLUS          
STA <BASIS        
STX <BASIS+1      
LDA TXTBOT        
LDY TXTBOT+<MXIND 
JSR TPADR         
LDA <TP           
STA <ENDE         
LDA <TP+1         
STA <ENDE+1       
LDA #0            
STA ANFZEI        
STA ANFZEI+<MXIND 
STA <ANFSPA       
;*****************
; BND UND TAB     
; INITIALISIEREN! 
;*****************
JSR UPROF         
JSR URBND         
JSR URTAB         
;*****************
;JETZT ERST DIE   
;ANFANGSWERTE:    
;*****************
JSR URESET        
JSR UTXTON        
;*******KONSTANTEN
LDA #255          
STA FLAG+$13      
STA FLAG+$14      
LDA #0            
STA <ENDFLG       
STA <XZEIL        
STA <XSPAL        
STA APOS          
STA <SCRLM        
STA <FEHLER       
STA <CODE         
JSR UCOLOR        
JSR UNPOS         
MAIN6 JSR FUNKT   
LDA <ENDFLG       
BEQ MAIN6         
JSR UWHEAD        
CLC               
RTS               
;-----------------
PLUS              
;(A,X) UM SATZ-   
;LAENGE ERHOEHEN  
;                 
CLC               
ADC <TXTLEN       
BCC PLUS1         
INX               
PLUS1 RTS         
;-----------------
PLUSA             
;<IND UM AKKU     
;INKREMENTIEREN   
CLC               
ADC <IND          
STA <IND          
BCC PLUSA1        
INC <IND+1        
PLUSA1 RTS        
;-----------------
MSG2              
DFD 147,13,13     
DFD "THIS IS A "  
DFD "NEW’ DATA"  
DFD "SET!",13,13  
DFD "ENTER LINE"  
DFD " LENGTH:"    
DFD 13,13         
DFD "[RANGE:1.."  
DFD "80]",13      
DFD "['*' OR '?"  
DFD "' RETURN TO" 
DFD " MENU]"      
DFD 13,13         
DFD "==>",0       
;=================
;SCHALE EDITOR    
;=================
MSG1              
DFD 9,142,147,31  
DFD "PASCAL-"     
DFD "MENU",13     
DFD "-------"     
DFD "----",13     
DFD 13,13         
DFD "SELECT "     
DFD "OPTION:",13  
DFD 13            
DFD "NAME  EDIT " 
DFD "NEW DATASET" 
DFD 13            
DFD "'?'   RESUME"
DFD " EDIT",13    
DFD "'$'   COMPI" 
DFD "LE DATASET"  
DFD 13            
DFD "'@'   SHOW " 
DFD "DIRECTORY"   
DFD 13            
DFD "'*'   EXIT " 
DFD "TO BASIC",13 
DFD 13,"==>",0    
;-----------------
USTORE            
;BASIC ZEIGER     
;RETTEN           
;                 
LDX #<TMEM-<BASIS 
INX               
STORE1            
LDA <BASIS,X      
STA PNT,X         
DEX               
BPL STORE1        
RTS               
;-----------------
UIZPAG            
;ZERO PAGE INIT.  
;BASIC ZEIGER     
;RUECKSETZEN      
;                 
SEC               
JSR MEMBOT        
STX <ENDE         
STY <ENDE+1       
;** BYTE 0 RETTEN:
LDY #0            
LDA (<ENDE),Y     
PHA               
JSR BASINT        
LDY #0            
PLA               
STA (<ENDE),Y     
RTS               
;-----------------
MENUE             
;*****************
;EINTRITT VON     
;BASIC AUS        
;*****************
JSR USTORE        
LDA #8            
STA DEFDRV        
;*****************
;STANDARDADRESSE  
;DER FLOPPY = 8   
;*****************
MENUE1            
;** ERRORPOINTER  
;** UMSETZEN      
;** (FUER RESTORE)
LDA #[MENUE0      
STA ERRPTR        
LDA #]MENUE0      
STA ERRPTR+1      
JSR UCOLOR        
LDA #0            
JSR SETMSG        
SEC               
JSR MEMTOP        
STX <TMEM         
STY <TMEM+1       
;*******TITELBILD:
LDA #[MSG1        
LDY #]MSG1        
JSR UINPUT        
LDA TAB           
CMP #"?"          
BEQ MENUE2        
CMP #"$"          
BEQ MENUE5        
CMP #"@"          
BEQ MENUE6        
CMP #"*"          
BEQ MENUE9        
JSR MAINX         
BCC MENUE3        
;                 
MENUE0            
;** RESUME SPERREN
LDA #0            
STA RSMEFLG       
BEQ MENUE1        
;                 
MENUE2            
;** RESUME AUS-   
;** FUEHREN       
LDA RSMEFLG       
BEQ MENUE1        
JSR MAIN2         
BCS MENUE0        
;                 
MENUE3            
;** RESUME ERLAUBT
LDA #1            
STA RSMEFLG       
BNE MENUE1        
;                 
MENUE5 JSR UIZPAG 
JMP COMP          
;*****************
;==> COMPILER     
;RUECKKEHR UEBER  
;LABEL RETURN     
;*****************
MENUE6            
;** DIRECTORY     
;** NAME AB TAB,1 
LDX #1            
JSR UDIRECT       
JMP MENUE1        
;                 
MENUE9            
;** BASIC ZEIGER  
;** ZURUECKHOLEN  
JSR UIZPAG        
LDX #13           
MENUE10           
LDA PNT,X         
STA <BASIS,X      
DEX               
BPL MENUE10       
JSR BASCLR        
JSR VEKTOR        
;                 
LDA #[BEFNEU      
STA BEFPNT        
LDA #]BEFNEU      
STA BEFPNT+1      
;                 
JMP READY         
;-----------------
BEFNEU            
;ERWEITERTER BASIC
;INTERPRETER      
;                 
JSR <CHGET        
CMP #172;"*"      
BNE BEFNEU1       
JMP MENUE1        
BEFNEU1           
JSR <CHGOT        
JMP BASCMD        
;=================
;OPERATIONEN BEI  
;DER RUECKKEHR VOM
;COMPILER         
;=================
OBJECT  EQU $4000 
;ANFANG CODE      
SOURCE  EQU 641   
;ANFANG QUELLTEXT 
TABLES  EQU 643   
;ANFANG EDITOR    
START   EQU 5611  
;ZIEL FUER CODE   
;-----------------
<ABANF  EQU $5F   
<ABEND  EQU $5A   
<NBEND  EQU $58   
BLOCK   EQU $A3BF 
;**KOPIERT NUR    
;**VON L->H. KEINE
;**UEBERLAPPUNG!  
;-----------------
NAME1 DFD "C$"    
NAME2 DFD "F$"    
;                 
;NACH RUECKKEHR   
;VOM COMPILER DEN 
;CODE VERSCHIEBEN:
;                 
;ABANF :=OBJECT   
;ABEND :=(SOURCE) 
;NBEND :=START    
;    +ABEND-ABANF 
;-----------------
RETURN            
;<== COMPILER     
;                 
LDA #[OBJECT      
STA <ABANF        
LDA #]OBJECT      
STA <ABANF+1      
;                 
SEC               
LDA SOURCE        
STA <ABEND        
SBC <ABANF        
STA <NBEND        
LDA SOURCE+1      
STA <ABEND+1      
SBC <ABANF+1      
STA <NBEND+1      
;(NBEND=LAENGE)   
CLC               
LDA <NBEND        
ADC #[START       
STA <NBEND        
LDA <NBEND+1      
ADC #]START       
STA <NBEND+1      
JSR BLOCK         
LDA TEMPFLG       
BEQ RETURN9       
;*****************
;CODE NACHLADEN:  
;*****************
LDA #2            
LDX #[NAME1       
LDY #]NAME1       
JSR SETNAM        
LDA #1            
LDX #8            
LDY #2            
;*** ABSOLUT LADEN
JSR SETLFS        
LDA #0            
JSR LOAD          
STX <ENDE         
STY <ENDE+1       
;*********** FIXUP
LDA #2            
LDX #[NAME2       
LDY #]NAME2       
JSR SETNAM        
LDA #1            
LDX #8            
LDY #3            
JSR SETLFS        
JSR OPEN          
LDX #1            
JSR CHKIN         
;                 
RETURN1           
JSR CHRIN         
STA <SP           
JSR CHRIN         
STA <SP+1         
JSR READST        
BNE RETURN7       
JSR CHRIN         
LDY #0            
STA (<SP),Y       
INY               
JSR CHRIN         
STA (<SP),Y       
JMP RETURN1       
;                 
RETURN7           
JSR CLRCHN        
LDA #1            
JSR CLOSE         
;*****************
;TEST AUF         
;UEBERLAUF:       
;*****************
LDA SOURCE        
CMP <ENDE         
LDA SOURCE+1      
SBC <ENDE+1       
BCS RETURN9       
;***RESUME SPERREN
LDA #0            
STA RSMEFLG       
;                 
LDA TABLES        
CMP <ENDE         
LDA TABLES+1      
SBC <ENDE+1       
BCS RETURN9       
;*****************
;UEBERLAUF        
;=> ABBRUCH       
;*****************
JMP MENUE9        
;                 
RETURN9           
JMP MENUE1        
;=================
ENDMOD6           
;                 
EXP MENUE,RETURN, 
ENDMOD6           
;                 
END