;=================
;   SCR.MOD5      
; SCREEN-EDITOR   
;=================
;                 
;3.6.1986         
;                 
;=================
;PRIMARY COMMANDS 
;INCL. FIND/CHANGE
;=================
;                 
IMP SCR.DECL      
IMP SCR.SYST      
;(WEGEN REPEAT)   
IMP SCR.MOD1      
IMP SCR.MOD2      
IMP SCR.MOD3      
IMP SCR.MOD4      
;(COPY,UIN,UOUT)  
;                 
;LADE DIE GLOBALEN
;LABELS           
;                 
;=================
ORG ENDMOD4       
;                 
;=================
;LOKALE VARIABLEN 
;FUER FIND/CHANGE 
;                 
<LAENG1 EQU $39   
<LAENG2 EQU $3A   
<BOTTOM EQU $3B   
<FMODUS EQU $3C   
<FMASKE EQU $3D   
<SPALT1 EQU $3E   
<SPALT2 EQU $3F   
<TRENN  EQU $40   
;                 
; BEREITS GLOBAL: 
;                 
;<FZAEHL EQU $41  
;(L/H)            
;================ 
UPRIM             
;BEFEHLSZEILE     
;LESEN UND ZUR    
;AUSFUEHRUNG      
;SPRINGEN         
;C=1 =>FEHLER     
;<XREG ZEIGT      
;AUF ERSTES SPACE 
;HINTER STRING    
;                 
LDA #0            
STA <CODE         
LDA <COMFLG       
BEQ PRIM10        
;** TEXT VOM BILD-
;** SCHIRM LESEN  
;** UND MIT " ",0 
;** MARKE BEENDEN 
LDA #0            
TAX               
JSR UCSPR         
LDX #<SCRLC-1     
LDY #0            
;                 
PRIM1 JSR UGETSCR 
STA TAB,Y         
CMP #" "          
BEQ PRIM0         
TYA               
TAX               
PRIM0 INY         
CPY #<SCRLC       
BNE PRIM1         
;                 
INX               
STX <XREG         
LDA #" "          
STA TAB,X         
INX               
LDA #0            
STA TAB,X         
;                 
TAX               
JSR BEFIND        
BCS PRIM10        
CPX #<OFFS1       
BCS PRIM5         
TXA               
ASL               
TAX               
LDA SPRTAB,X      
STA <IND          
LDA SPRTAB+1,X    
STA <IND+1        
JMP (<IND)        
;*****************
;DISK-COMMAND     
;*****************
PRIM5 LDX <XREG   
JSR UDISKC        
LDA <CODE         
ORA #1            
STA <CODE         
;STATUS ANZEIGEN  
;(AUCH 00,OK...)  
SEC               
RTS               
PRIM10 CLC        
RTS               
;-----------------
UCOL              
LDA #1            
STA <COLFLG       
RTS               
;-----------------
UBNDS             
LDA #1            
STA <BNDFLG       
RTS               
;-----------------
UMSK              
LDA #1            
STA <MSKFLG       
RTS               
;-----------------
UTABS             
LDA #1            
STA <TABFLG       
RTS               
;-----------------
ULOC              
LDX <ZAEHL        
INX               
JSR URZAHL        
LDX <ERG+1        
LDA <ERG          
CPX TXTBOT+<MXIND 
BCC LOC2          
BNE LOC1          
CMP TXTBOT        
BCC LOC2          
LOC1 LDA TXTBOT   
LDX TXTBOT+<MXIND 
LOC2 STA ANFZEI   
STX ANFZEI+<MXIND 
RTS               
;-----------------
UPROF             
LDA #1            
STA <MSKFLG       
STA <BNDFLG       
STA <TABFLG       
STA <COLFLG       
RTS               
;-----------------
URESET            
LDA #255          
STA <LAENG1       
STA <LAENG2       
LDA #0            
STA <MSKFLG       
STA <BNDFLG       
STA <TABFLG       
STA <COLFLG       
STA <TEFLAG       
STA REPEAT        
LDX #<CXIND       
RESET1            
STA FLAG,X        
DEX               
BPL RESET1        
RTS               
;-----------------
UREPT             
LDA #255          
STA REPEAT        
RTS               
;-----------------
UTXTON            
LDA #255          
STA <TEFLAG       
RTS               
;-----------------
UCANCL            
LDA #255          
STA <ENDFLG       
RTS               
;-----------------
UENDE             
JSR XSAVE         
BCC UCANCL        
RTS               
;-----------------
UCOPY             
JSR UREADRV       
JMP COPY          
;-----------------
XSAVE             
LDA DEFDRV        
PHA               
JSR UREADRV       
STA DEFDRV        
JSR USAVE         
PLA               
STA DEFDRV        
RTS               
;-----------------
UDRIVE            
JSR UREADRV       
STA DEFDRV        
RTS               
;-----------------
UDIR              
LDX <XREG         
LDA #0            
STA TAB,X         
;                 
LDX <ZAEHL        
INX               
JMP UDIRECT       
;-----------------
BEFIND            
;SPACE AM ANFANG  
;UEBERLESEN       
;BEFEHL AB TAB,X  
;BIS SPACE IN     
;TABELLE COMTAB   
;SUCHEN.          
;C=0 =>           
;GEFUNDEN:        
;X = INDEX        
;ZAEHL ZEIGT AUF  
;NAECHSTES SPACE  
;                 
;UNBEKANNT:       
;X = 255          
;ZAEHL ZEIGT AUF  
;DAS 1. ZEICHEN   
;                 
;C=1 =>TEXTENDE   
;                 
BEF0 LDA TAB,X    
BEQ BEF6          
INX               
CMP #" "          
BEQ BEF0          
DEX               
STX <ZAEHL        
LDY #0            
STY <YREG         
BEF1 LDX <ZAEHL   
BEF2              
LDA COMTAB,Y      
AND #127          
BEQ BEF5          
CMP TAB,X         
BNE BEF3          
INX               
INY               
LDA TAB,X         
CMP #" "          
BNE BEF2          
LDA COMTAB,Y      
BPL BEF4          
BEF3 INY          
LDA COMTAB,Y      
BNE BEF3          
INC <YREG         
INY               
BNE BEF1          
BEF4 STX <ZAEHL   
;******* GEFUNDEN!
LDX <YREG         
CLC               
RTS               
BEF5 LDX #255     
;***NICHT GEFUNDEN
CLC               
RTS               
BEF6 SEC          
;******** TEXTENDE
RTS               
;-----------------
COMTAB            
;                 
DFD "ÃÏÌUMNS",0   
DFD "ÍÓËS",0      
DFD "ÂÎÄS",0      
DFD "ÔÁÂULATOR",0 
DFD "ÌOCATE",0    
DFD "ÐÒÏÆILE",0   
DFD "ÒÅÓET",0     
DFD "ÔÅXT",0      
DFD "ÃÁÎCEL",0    
DFD "ÅÎÄ",0       
DFD "ÓÁÖÅ",0      
DFD "ÒÅÐEAT",0    
DFD "ÆIND",0      
DFD "ÃHANGE",0    
DFD "ÃÏÐÙ",0      
DFD "ÉÎPUT",0     
DFD "ÏÕÔPUT",0    
DFD "ÄÉÒECTORY",0 
DFD "ÄÒÉÖÅ",0     
DFD "ÁÌÌ",0       
DFD "ÆÉÒST",0     
DFD "ÎÅØT",0      
DFD "ÃÈÁRS",0     
DFD "×ÏÒD",0      
DFD "ÐÒÅFIX",0    
DFD "ÓÕÆFIX",0    
DFD 0             
;                 
<OFFS1 EQU 19     
;LAGE ALL         
;-----------------
SPRTAB            
;SPRUNGTABELLE    
;FUER COMMANDS    
;                 
DFD UCOL          
DFD UMSK          
DFD UBNDS         
DFD UTABS         
DFD ULOC          
DFD UPROF         
DFD URESET        
DFD UTXTON        
DFD UCANCL        
DFD UENDE         
DFD XSAVE         
DFD UREPT         
DFD UFIND         
DFD UCHANG        
DFD UCOPY         
DFD UIN           
DFD UOUT          
DFD UDIR          
DFD UDRIVE        
;-----------------
UREADRV           
; LAUFWERKSANGABE 
; (>=8) LESEN UND 
; IM AKKU ZURUECK.
;                 
LDX <ZAEHL        
INX               
JSR URZAHL        
LDA <ERG+1        
BNE READRV0       
LDA <ERG          
CMP #8            
BCS READRV1       
;****SONST DEFAULT
READRV0           
LDA DEFDRV        
READRV1 RTS       
;-----------------
GETTXT            
;HOLE STRING AB   
;TAB,X =>(<IND)   
;FUER FIND/CHANGE 
;A=>ALTE LAENGE   
;Y<=LAENGE NEU    
;X<=NAECHSTES     
;   ZEICHEN       
;                 
STA <LFD          
GETTX1 LDA TAB,X  
INX               
CMP #0            
BEQ GETTX9        
CMP #" "          
BEQ GETTX1        
CMP #"*"          
BNE GETTX2        
LDY <LFD          
CPY #255          
BEQ GETTX9        
BNE GETTX8        
;                 
GETTX2 CMP #"#"   
BNE GETTX3        
JSR URZAHL        
LDA <ERG          
LDY #0            
STA (<IND),Y      
INY               
BNE GETTX8        
;                 
GETTX3 CMP #"'"   
BNE GETTX5        
LDY #0            
GETTX4 LDA TAB,X  
BEQ GETTX9        
CMP #"'"          
BEQ GETTX7        
CPY #<MXLEN       
BPL NOCOP1        
STA (<IND),Y      
NOCOP1 INY        
INX               
BNE GETTX4        
;                 
GETTX5 LDY #0     
GETTX6            
CPY #<MXLEN       
BPL NOCOP2        
STA (<IND),Y      
NOCOP2            
LDA TAB,X         
INY               
INX               
CMP #" "          
BNE GETTX6        
BEQ GETTX8        
GETTX7 INX        
GETTX8 CLC        
RTS               
GETTX9 SEC        
RTS               
;-----------------
UCHANG            
;CHANGE ...       
;HOLE PARAMETER   
;AUSFUEHRUNG      
;                 
LDA #[STRNG1      
STA <IND          
LDA #]STRNG1      
STA <IND+1        
LDA <LAENG1       
LDX <ZAEHL        
JSR GETTXT        
BCS FINDX         
CPY #0            
BEQ FINDX         
STY <LAENG1       
LDA #[STRNG2      
STA <IND          
LDA #]STRNG2      
STA <IND+1        
LDA <LAENG2       
JSR GETTXT        
BCS FINDX         
STY <LAENG2       
LDA #128          
BNE FIND0         
;                 
FINDX             
;**** STRING FEHLT
LDA #135          
STA <FEHLER       
SEC               
RTS               
;-----------------
UFIND             
;PARAMETER LESEN  
;UND AUSFUEHRUNG  
;                 
LDA #[STRNG1      
STA <IND          
LDA #]STRNG1      
STA <IND+1        
LDA <LAENG1       
LDX <ZAEHL        
JSR GETTXT        
BCS FINDX         
CPY #0            
BEQ FINDX         
STY <LAENG1       
LDA #255          
LDA <LAENG2       
LDA #0            
;                 
FIND0             
;*****************
;SETZE DEFAULT    
;*****************
STA <FMODUS       
LDA #0            
STA <FMASKE       
LDA <LBND         
STA <SPALT1       
LDA <RBND         
SEC               
SBC <LAENG1       
STA <SPALT2       
FIND1             
;*****************
;HOLE SCHLUESSEL- 
;WORTE, SETZE     
;FMODUS UND FMASKE
;*****************
JSR BEFIND        
BCC *+5           
JMP USUCHE        
CPX #<OFFS1       
BNE FIND2         
LDA <FMODUS       
ORA #64           
STA <FMODUS       
BNE FIND6         
FIND2             
CPX #<OFFS1+1     
BNE FIND3         
LDA <FMODUS       
ORA #32           
STA <FMODUS       
BNE FIND6         
FIND3             
CPX #<OFFS1+2     
BEQ FIND6         
CPX #<OFFS1+3     
BEQ FIND6         
CPX #<OFFS1+4     
BNE FIND4         
LDA <FMASKE       
ORA #3            
STA <FMASKE       
BNE FIND6         
FIND4             
CPX #<OFFS1+5     
BNE FIND5         
LDA <FMASKE       
ORA #2            
STA <FMASKE       
BNE FIND6         
FIND5             
CPX #<OFFS1+6     
BNE FIND7         
LDA <FMASKE       
ORA #1            
STA <FMASKE       
;                 
FIND6             
LDX <ZAEHL        
BNE FIND1         
;                 
FIND7 LDX <ZAEHL  
LDA TAB,X         
CMP #"0"          
BCC FINDQ1        
CMP #"9"+1        
BCS FINDQ1        
;*****************
;SPALTEN1 UND 2   
;LESEN            
;*****************
JSR URZAHL        
LDA <ERG          
CMP <TXTLEN       
BCS FINDQ2        
STA <SPALT1       
STA <SPALT2       
LDA TAB,X         
CMP #"-"          
BNE USUCHE        
INX               
JSR URZAHL        
LDA <ERG          
CMP <TXTLEN       
BCS FINDQ2        
STA <SPALT2       
BCC USUCHE        
;                 
FINDQ1            
;********** SYNTAX
LDA #134          
DFD $2C           
FINDQ2            
;****** ILL. WERTE
LDA #136          
STA <FEHLER       
SEC               
RTS               
;-----------------
USUCHE            
;                 
;FIND UND CHANGE  
;===============  
;FMODUS = FIRST:  
;ZEIGER AUF       
;ANFANG SETZEN    
;                 
;SONST:           
;1                
; IM TEXT:        
; AB CURSORPOSI-  
; TION (+1, FALLS 
; MODUS = FIND)   
;2                
; SONST: AB ECKE  
; LINKS OBEN      
;                 
;                 
INITS1            
LDA <FMODUS       
AND #96           
BEQ INITS2        
;** AB ANFANG     
;** SUCHEN        
LDA #0            
STA <TZEIL        
STA <TZEIL+1      
LDY <SPALT1       
LDA #1            
STA <BOTTOM       
BNE SUCHE         
;                 
INITS2            
LDA #0            
STA <BOTTOM       
LDA APOS          
BNE INITS3        
LDA ANFZEI        
STA <TZEIL        
LDA ANFZEI+<MXIND 
STA <TZEIL+1      
LDY <SPALT1       
JMP SUCHE         
INITS3            
LDA AZEIL         
STA <TZEIL        
LDA AZEIL+<MXIND  
STA <TZEIL+1      
LDY <ASPAL        
LDA <FMODUS       
BMI SUCHE         
;** +1, WEIL FIND 
INY               
;                 
SUCHE             
;AB TZEIL  UND    
;SPALTE Y         
;                 
LDA #0            
STA <FEHLER       
STA <FZAEHL       
STA <FZAEHL+1     
;                 
STY <YREG         
LDA <TZEIL        
LDY <TZEIL+1      
JSR TPADR         
LDY <YREG         
;                 
SUCHE0            
;TEST AUF         
;TEXTENDE:        
LDA <TZEIL+1      
CMP TXTBOT+<MXIND 
BCC SUCHE1        
LDA <TZEIL        
CMP TXTBOT        
BCC SUCHE1        
JMP SUCHEX        
SUCHE1            
LDA #1            
STA <TRENN        
LDX #0            
;                 
SUCHE2            
LDA (<TP),Y       
CMP STRNG1,X      
BNE SUCHE8        
LDA <FMASKE       
AND #2            
BEQ SUCHE3        
LDA <TRENN        
BEQ SUCHE7        
SUCHE3 STY <YREG  
SUCHE4 INX        
INY               
CPX <LAENG1       
BEQ SUCHE5        
LDA (<TP),Y       
CMP STRNG1,X      
BEQ SUCHE4        
BNE SUCHE6        
SUCHE5 LDA <FMASKE
AND #1            
BEQ SUCHEQ        
LDA (<TP),Y       
JSR UTRENN        
BEQ SUCHE6        
;                 
SUCHEQ            
JMP GEFUND        
;FALLS ALL        
;RUECKKEHR!       
;<-------         
SUCHE6            
LDY <YREG         
LDX #0            
SUCHE7            
LDA (<TP),Y       
SUCHE8            
JSR UTRENN        
CPY <SPALT2       
BEQ SUCHE9        
BCS SUCHE9        
INY               
BNE SUCHE2        
SUCHE9            
LDA <TP           
CLC               
ADC <TXTLEN       
STA <TP           
BCC *+4           
INC <TP+1         
LDY <SPALT1       
INC <TZEIL        
BNE SUCHE0        
INC <TZEIL+1      
BNE SUCHE0        
;                 
SUCHEX            
;****** NICHT GEF.
LDX <BOTTOM       
LDA #1            
STA <BOTTOM       
LDA <FMODUS       
AND #64           
BNE SUCH12        
TXA               
BEQ SUCH11        
SUCH10 LDA #139   
DFD $2C           
SUCH11            
LDA #138          
;                 
;MESSAGE SETZEN   
STA <FEHLER       
SEC               
RTS               
;                 
SUCH12            
LDA <FZAEHL       
ORA <FZAEHL+1     
BEQ SUCH10        
LDA <FMODUS       
BMI SUCH13        
LDA #2            
DFD $2C           
SUCH13            
LDA #3            
STA <CODE         
SEC               
RTS               
;                 
GEFUND            
;******* GEFUNDEN!
INC <FZAEHL       
BNE GEFUNX        
INC <FZAEHL+1     
GEFUNX LDA <FMODUS
AND #64           
BEQ GEFUN2        
;************* ALL
LDA <FMODUS       
BPL GEFUN1        
JSR UXCHNG        
BCS GEFUN0        
LDY <YREG         
BNE GEFUN1        
;*****************
;IMMER NOCH AM    
;ZEILENANFANG     
;SONDERFALL, FALLS
;GESAMTES WORT    
;GELOESCHT        
;*****************
JMP SUCHE1        
GEFUN0 INC <FEHLER
GEFUN1 JMP SUCHE6 
;                 
GEFUN2            
LDA #0            
STA <BOTTOM       
LDY <YREG         
STY <ASPAL        
LDA <TZEIL        
STA AZEIL         
LDA <TZEIL+1      
STA AZEIL+<MXIND  
LDA #255          
STA APOS          
STA <FNDFLG       
;*****************
;VERHINDER TABU-  
;LIEREN. CURSOR   
;UND BILD SETZEN. 
;*****************
JSR UMOVE         
;                 
LDA <FMODUS       
BPL GEFUN4        
JSR UXCHNG        
BCS GEFUN3        
LDA #3            
STA <CODE         
;**** #### CHANGED
SEC               
RTS               
GEFUN3 LDA #133   
;****** MOVE ERROR
DFD $2C           
GEFUN4 LDA #137   
;**********  FOUND
STA <FEHLER       
SEC               
RTS               
;-----------------
UTRENN            
;TESTE AKKU AUF   
;TRENNZEICHEN     
;                 
CMP #"A"          
BCC TRENN1        
CMP #"Ú"+1        
BCS TRENN1        
CMP #"Á"          
BCS TRENN0        
CMP #"Z"+1        
BCS TRENN1        
TRENN0 LDA #0     
DFD $2C           
TRENN1 LDA #1     
STA <TRENN        
RTS               
;-----------------
RFIND             
; FIND * NEXT     
;UAPOS/UNPOS VOR- 
;HER UND NACHHER  
;AUFRUFEN!        
;-----------------
LDA <LAENG1       
CMP #255          
BEQ RFINDQ        
LDX #0            
LDA <BOTTOM       
BEQ RFIND1        
LDX #32           
;** FIRST, FALLS  
;** BOTTOM=1      
RFIND1 STX <FMODUS
JMP USUCHE        
;                 
RFINDQ            
LDA #140          
STA <FEHLER       
RTS               
;-----------------
RCHNG             
;CHANGE * NEXT    
;UAPOS/UNPOS VOR- 
;HER UND NACHHER  
;AUFRUFEN!        
;-----------------
LDA <LAENG1       
ORA <LAENG2       
CMP #255          
BEQ RFINDQ        
LDX #128          
LDA <BOTTOM       
BEQ RCHNG1        
LDX #128+32       
;** FIRST, FALLS  
;** BOTTOM=1      
RCHNG1 STX <FMODUS
JMP USUCHE        
;-----------------
UXCHNG            
;CHANGE AUS-      
;FUEHERN          
;                 
LDY <YREG         
STY <TSPAL        
SEC               
LDA <LAENG2       
SBC <LAENG1       
BCS XCHNG1        
BEQ XCHNG2        
EOR #$FF          
TAX               
INX               
JSR UDELE         
JMP XCHNG2        
;                 
XCHNG1            
STA <LFD          
LDY <YREG         
JSR UFRE          
TXA               
CMP <LFD          
BCS *+4           
SEC               
RTS               
;**** PLATZ GENUG:
LDX <LFD          
LDY <YREG         
JSR UINSE         
;                 
XCHNG2 LDY <YREG  
LDX #0            
XCHNG3            
CPX <LAENG2       
BEQ XCHNG4        
LDA STRNG2,X      
STA (<TP),Y       
INX               
INY               
BNE XCHNG3        
XCHNG4 TYA        
BEQ XCHNG5        
DEY               
XCHNG5 STY <YREG  
;*****************
;ZEIGER FUER      
;WEITERSUCHEN     
;*****************
CLC               
RTS               
;=================
ENDMOD5           
;                 
EXP UPRIM,UPROF,  
URESET,UTXTON,    
;                 
RFIND,RCHNG,      
ENDMOD5           
;                 
END