;=================
;   SCR.MOD3      
; SCREEN-EDITOR   
;=================
;                 
;3.6.1986         
;                 
;=================
;KOPF,SCROLL,BNDS,
;COLS,MASK,...    
;ANZEIGEN / LESEN 
;DISK-INTERFACE   
;INPUT-FUNKTIONEN 
;=================
;                 
IMP SCR.DECL      
IMP SCR.SYST      
IMP SCR.MOD1      
IMP SCR.MOD2      
;                 
;LADE DIE GLOBALEN
;LABELS           
;                 
;=================
ORG ENDMOD2       
;                 
;=================
TXT5              
DFD "1.COL:",0    
TXT6              
DFD "SCROLL:",0   
TXT7 DFD "HALF",0 
TXT8 DFD "PAGE",0 
TXT9 DFD "COL=",0 
TXT10 DFD "MSK=",0
TXT11 DFD "BND=",0
TXT12 DFD "TAB=",0
TXT13             
DFD "SYSTEM ERR"  
DFD "OR NR:",0    
TXT14             
DFD " TIMES FOUND"
DFD 0             
TXT15             
DFD " CHANGED",0  
TXT16             
DFD " ERRORS",0   
;=================
<OFFSET EQU 19    
;                 
TXTTAB            
DFD "LINE-COMM."  
DFD "IGNORED ",0  
DFD "COMMAND CO"  
DFD "NFLICT  ",0  
DFD "OUT OF MEM"  
DFD "ORY     ",0  
DFD "BLOCK TOO "  
DFD "LONG    ",0  
DFD "ILLEGAL BO"  
DFD "UNDS    ",0  
DFD "MOVE ERROR"  
DFD "        ",0  
DFD "ILLEGAL CO"  
DFD "MMAND   ",0  
DFD "ENTER A ST"  
DFD "RING!   ",0  
DFD "ILLEGAL CO"  
DFD "LUMN    ",0  
DFD "STRING FOU"  
DFD "ND      ",0  
DFD "**BOTTOM R"  
DFD "EACHED**",0  
DFD "STRING NOT"  
DFD " FOUND  ",0  
DFD "KEY IS NOT"  
DFD " ACTIVE ",0  
;=================
;AUSGABE INFO     
;=================
UWKOPF            
;KOPF SCHREIBEN   
;(OHNE FEHLER)    
;**COL:####       
;                 
LDA #[TXT5        
STA <IND          
LDA #]TXT5        
STA <IND+1        
JSR UTEXT         
LDA <ANFSPA       
LDX #0            
JSR UZAHL         
STA TAB           
LDA #[TAB         
STA <IND          
LDA #]TAB         
;- - - - - - - - -
UWTOP             
;SCHREIBT IN DIE  
;BEFEHLSZEILE BIS 
;AN DEN RECHTEN   
;RAND             
;                 
STA <IND+1        
LDY #0            
WTOP1 LDA (<IND),Y
BEQ WTOP2         
JSR USETR         
INY               
LDX <SSPAL        
CPX #<SCRLC       
BNE WTOP1         
WTOP2 LDA #" "    
LDX <SSPAL        
CPX #<SCRLC-7     
;**PLATZ FUER     
;**"SCROLL:" ?    
BPL WTOP4         
WTOP3             
JSR USETR         
INX               
CPX #<SCRLC-7     
BNE WTOP3         
LDA #[TXT6        
STA <IND          
LDA #]TXT6        
STA <IND+1        
JMP UTEXT         
;                 
WTOP4 CPX #<SCRLC 
BPL WTOP5         
JSR USETR         
INX               
BNE WTOP4         
WTOP5 RTS         
;-----------------
UWSCRL            
;SCROLL-BETRAG    
;SCHREIBEN        
;                 
LDA #<SCRLC       
LDX #<SCRLL       
JSR UCSPR         
LDA <SCRLM        
BNE WSCRL1        
;*************HALF
LDA #[TXT7        
STA <IND          
LDA #]TXT7        
STA <IND+1        
JSR UTEXT         
LDA #<MXLIN       
LSR               
STA <SCRLV        
LDA #<MXCOL-<ZAHL 
LSR               
STA <SCRLH        
RTS               
WSCRL1 CMP #1     
BNE WSCRL2        
;*************PAGE
LDA #[TXT8        
STA <IND          
LDA #]TXT8        
STA <IND+1        
JSR UTEXT         
LDX #<MXCOL-<ZAHL 
DEX               
STX <SCRLH        
LDA #<MXLIN-3     
STA <SCRLV        
RTS               
WSCRL2            
;*****************
LDA <SCRLH        
LDX #0            
JSR UZAHL         
LDA <SCRLH        
STA <SCRLV        
RTS               
;-----------------
UCOLS             
;SCHREIBT IN DIE  
;ZEILE NUMMER X   
;SPALTENMARK.     
;                 
STX <COLFLG       
LDA #0            
JSR UCSPR         
LDA #100          
LDX #0            
STA <NL           
STX <NH           
LDA <ANFSPA       
STA <ZL           
STX <ZH           
JSR UDIV          
LDA <HL           
LDX #0            
STA <ZL           
STX <ZH           
LDA #10           
STA <NL           
STX <NH           
JSR UDIV          
LDA #[TXT9        
STA <IND          
LDA #]TXT9        
STA <IND+1        
JSR UTEXT         
LDX <HL           
LDY <ZL           
COLS0 TXA         
BNE COLS1         
TYA               
CLC               
ADC #48           
BNE COLS3         
COLS1 CPX #5      
BNE COLS2         
LDA #"+"          
DFD $2C           
COLS2 LDA #"-"    
COLS3 JSR USETR   
INX               
CPX #10           
BCC COLS4         
LDX #0            
INY               
CPY #10           
BCC COLS4         
LDY #0            
COLS4             
LDA <SSPAL        
BNE COLS0         
RTS               
;-----------------
UMASK             
;MASKE IN DER     
;ZEILE X          
;ANZEIGEN         
;                 
STX <MSKFLG       
LDA #0            
JSR UCSPR         
LDA #[TXT10       
STA <IND          
LDA #]TXT10       
STA <IND+1        
JSR UTEXT         
;                 
LDA MASK          
STA <TP           
LDA MASK+<MXIND   
STA <TP+1         
JMP ZEILE         
;-----------------
UBND              
;GRENZEN IN DER   
;ZEILE X          
;ANZEIGEN         
;                 
STX <BNDFLG       
LDA #0            
JSR UCSPR         
LDA #[TXT11       
STA <IND          
LDA #]TXT11       
STA <IND+1        
JSR UTEXT         
;                 
LDA BNDS          
STA <TP           
LDA BNDS+<MXIND   
STA <TP+1         
JMP ZEILE         
;-----------------
UTAB              
;TABULATOR IN     
;ZEILE X          
;ANZEIGEN         
;                 
STX <TABFLG       
LDA #0            
JSR UCSPR         
LDA #[TXT12       
STA <IND          
LDA #]TXT12       
STA <IND+1        
JSR UTEXT         
;                 
LDA TABU          
STA <TP           
LDA TABU+<MXIND   
STA <TP+1         
JMP ZEILE         
;-----------------
UTOP              
;KOPF SCHREIBEN   
;INCL. DER        
;STATUS-ZEILEN    
;CODE+FEHLER      
;BEACHTEN         
;                 
LDA #0            
TAX               
JSR UCSPR         
LDA <CODE         
CMP #255          
BNE ERROR1        
;******SYSERR #...
LDA #[TXT13       
STA <IND          
LDA #]TXT13       
STA <IND+1        
JSR UTEXT         
LDA <FEHLER       
CLC               
ADC #48           
STA TAB           
LDA #0            
STA TAB+1         
BEQ ERROR11       
;                 
ERROR1            
CMP #1            
BNE ERROR2        
;**DISK STATUS    
;**IN TAB ANZEIGEN
ERROR11           
LDA #[TAB         
STA <IND          
LDA #]TAB         
JMP TOP5          
;                 
ERROR2            
CMP #2            
BNE ERROR3        
;****** #### FOUND
LDA <FZAEHL       
LDX <FZAEHL+1     
JSR UZAHL         
LDA #[TXT14       
STA <IND          
LDA #]TXT14       
JMP TOP5          
;                 
ERROR3            
CMP #3            
BNE TOPOK         
;***** #### ERRORS
LDA <FEHLER       
BEQ ERROR4        
LDA <FZAEHL       
LDX <FZAEHL+1     
JSR UZAHL         
LDA #"/"          
JSR USETR         
LDA <FEHLER       
LDX #0            
JSR UZAHL         
LDA #[TXT16       
STA <IND          
LDA #]TXT16       
JMP TOP5          
;                 
ERROR4            
;********* CHANGED
LDA <FZAEHL       
LDX <FZAEHL+1     
JSR UZAHL         
LDA #[TXT15       
STA <IND          
LDA #]TXT15       
JMP TOP5          
;                 
TOPOK             
LDA <FEHLER       
BNE TOP1          
JSR UWKOPF        
JMP TOP6          
TOP1 BMI TOP2     
LDA #0            
TOP2              
;**TEXT AUS TXTTAB
;**ANZEIGEN       
AND #127          
STA <MND          
LDA #0            
STA <MND+1        
LDA #<OFFSET      
STA <MOR          
JSR UMULTI        
CLC               
LDA #[TXTTAB      
ADC <ERG          
STA <IND          
LDA #]TXTTAB      
ADC <ERG+1        
;                 
TOP5 JSR UWTOP    
;                 
TOP6 JSR UWSCRL   
LDX #1            
STX <SCTOP        
LDA <MSKFLG       
BEQ TOP7          
JSR UMASK         
LDX <SCTOP        
INX               
STX <SCTOP        
TOP7 LDA <BNDFLG  
BEQ TOP8          
JSR UBND          
LDX <SCTOP        
INX               
STX <SCTOP        
TOP8 LDA <TABFLG  
BEQ TOP9          
JSR UTAB          
LDX <SCTOP        
INX               
STX <SCTOP        
TOP9 LDA <COLFLG  
BEQ TOP10         
JSR UCOLS         
LDX <SCTOP        
INX               
STX <SCTOP        
TOP10 RTS         
;=================
;EINLESEN INFO    
;=================
URSCRL            
;SCROLL VOM BILD- 
;SCHIRM LESEN     
;                 
LDA #<SCRLC       
LDX #<SCRLL       
JSR UCSPR         
LDY <SSPAL        
JSR UGETSCR       
CMP #"H"          
BNE URSCR1        
LDA #0            
STA <SCRLM        
RTS               
URSCR1            
CMP #"P"          
BNE URSCR2        
LDA #1            
STA <SCRLM        
RTS               
URSCR2 LDX #0     
URSCR3 STA TAB,X  
INX               
INY               
CPY #<MXCOL       
BCS URSCR4        
JSR UGETSCR       
JMP URSCR3        
URSCR4 LDA #0     
STA TAB,X         
LDX #0            
JSR URZAHL        
LDA <ERG+1        
BEQ URSCR5        
LDA #127          
BNE URSCR6        
URSCR5 LDA <ERG   
URSCR6 AND #127   
STA <SCRLH        
LDA #2            
STA <SCRLM        
RTS               
;-----------------
URBND             
;BNDS IM SPEICHER 
;AUF GUELTIGKEIT  
;TESTEN UND RBND/ 
;LBND SETZEN      
;C=1 => FEHLER    
;                 
LDA <BNDFLG       
BEQ RBND5         
LDY <TXTLEN       
LDA BNDS          
STA <TP           
LDA BNDS+<MXIND   
STA <TP+1         
;                 
RBND1 CPY #0      
BEQ RBND9         
DEY               
LDA (<TP),Y       
CMP #" "          
BEQ RBND1         
CMP #">"          
BNE RBND9         
TYA               
TAX               
INX               
;                 
RBND2 CPY #0      
BEQ RBND9         
DEY               
LDA (<TP),Y       
CMP #" "          
BEQ RBND2         
CMP #"<"          
BNE RBND9         
;                 
STY <YREG         
RBND3 CPY #0      
BEQ RBND4         
DEY               
LDA (<TP),Y       
CMP #" "          
BEQ RBND3         
BNE RBND9         
RBND4 LDY <YREG   
STY <LBND         
STX <RBND         
RBND5 CLC         
RTS               
;                 
RBND9 LDA #132    
STA <FEHLER       
SEC               
RTS               
;-----------------
URTAB             
;TABS AUS DEM     
;SPEICHER LESEN   
;UND AUSERTEN     
;                 
LDA <TABFLG       
BEQ RTAB3         
LDY <TXTLEN       
LDA TABU          
STA <TP           
LDA TABU+<MXIND   
STA <TP+1         
;                 
RTAB1 CPY #0      
BEQ RTAB3         
DEY               
LDA (<TP),Y       
CMP #" "          
BEQ RTAB2         
LDA #"-"          
RTAB2 STA (<TP),Y 
JMP RTAB1         
RTAB3 RTS         
;=================
;INITIALISIERUNG  
;INFOS            
;=================
UWHEAD            
;TEXT- UND SATZ-  
;LAENGE ANFUEGEN  
;                 
SEC               
JSR MEMBOT        
STX <SP           
STY <SP+1         
LDY #2            
LDA TXTBOT+<MXIND 
STA (<SP),Y       
DEY               
LDA TXTBOT        
STA (<SP),Y       
DEY               
LDA <TXTLEN       
STA (<SP),Y       
RTS               
;-----------------
PLUSA             
;<IND UM A HOCH-  
;ZAEHLEN          
;                 
CLC               
ADC <IND          
STA <IND          
BCC PLUSA1        
INC <IND+1        
PLUSA1 RTS        
;-----------------
UBLANK            
;ZEILE MIT " "    
;FUELLEN (<IND)   
;                 
LDY <LFD          
LDA #" "          
BLANK1 CPY #0     
BEQ BLANK2        
DEY               
STA (<IND),Y      
BNE BLANK1        
BLANK2 RTS        
;-----------------
UINITP            
;STATUS-ZEILEN    
;HERSTELLEN       
;(NEUES DATASET)  
;                 
JSR UBLANK        
LDA <LFD          
JSR PLUSA         
JSR UBLANK        
LDA #"<"          
STA (<IND),Y      
LDA #">"          
LDY <LFD          
DEY               
STA (<IND),Y      
LDA <LFD          
JSR PLUSA         
JMP UBLANK        
;=================
;DISK-INTERFACE   
;=================
UDISKI            
;SENDET "I0"      
;                 
LDX #2            
LDA #"I"          
STA TAB           
LDA #"0"          
STA TAB+1         
;-----------------
UDISKC            
;SENDET BEFEHL    
;IN TAB AN DISK.  
;[BIS X]          
;                 
STX <ZAEHL        
LDA #15           
JSR CLOSE         
LDA <ZAEHL        
LDX #[TAB         
LDY #]TAB         
JSR SETNAM        
LDA #15           
LDX DEFDRV        
LDY #15           
JSR SETLFS        
JSR OPEN          
BCS SYSERR        
;-----------------
UDISKS            
;LIEST DISKSTATUS 
;=>TAB [BIS X]    
;KANAL #15 MUSS   
;SCHON GEOEFFNET  
;SEIN             
;C=1 =>FEHLER     
;                 
LDX #15           
JSR CHKIN         
BCS SYSERR        
LDX #0            
DISKS1            
JSR CHRIN         
BCS SYSERR        
CMP #13;   CR     
BEQ DISKS2        
STA TAB,X         
INX               
CPX #<SCRLC       
BNE DISKS1        
BEQ DISKS3        
DISKS2            
LDA #" "          
STA TAB,X         
INX               
CPX #<SCRLC       
BNE DISKS2        
DISKS3            
LDA #0            
STA TAB,X         
STX <ZAEHL        
JSR CLRCHN        
LDX <ZAEHL        
LDA TAB           
CMP #"2"          
RTS               
;**C=1,FALLS**    
;**NUMMER>19**    
;-----------------
SYSERR            
STA <FEHLER       
LDA #255          
STA <CODE         
JSR CLRCHN        
SEC               
RTS               
;-----------------
USAVE             
;SPEICHERT LFD.   
;DATASET MIT      
;NAMEN IN "NAME"  
;                 
;ZUERST I0 UND    
;S0:NAME          
;                 
JSR UDISKI        
BCS USAVE9        
LDX LAENGE        
USAVE1 LDA NAME,X 
STA TAB+3,X       
DEX               
BPL USAVE1        
LDA #"S"          
STA TAB           
LDA #"0"          
STA TAB+1         
LDA #":"          
STA TAB+2         
LDX LAENGE        
INX               
INX               
INX               
JSR UDISKC        
BCS USAVE9        
LDA LAENGE        
LDX #[NAME        
LDY #]NAME        
JSR SETNAM        
LDA #0            
LDX DEFDRV        
LDY #0            
JSR SETLFS        
JSR UWHEAD        
LDA #<SP          
LDX <ENDE         
LDY <ENDE+1       
JSR SAVE          
BCS USAVE9        
JSR UDISKS        
BCS USAVE9        
LDA #1            
;********** VERIFY
LDX LAENGE        
JSR ULOAD         
BCS USAVE9        
LDA <LFD;** STATUS
AND #$10          
BEQ USAVE2        
JMP USAVE         
USAVE2 CLC        
RTS               
USAVE9            
LDA <CODE         
ORA #1            
STA <CODE         
SEC               
RTS               
;-----------------
ULOAD             
;DATASET LESEN    
;NAME IN "NAME"   
;X   =>LAENGE     
;LFD =>STATUS     
;                 
STA <LFD          
STX <XREG         
JSR UDISKI        
;****** INITIALIZE
BCS USAVE9        
LDA <XREG         
LDX #[NAME        
LDY #]NAME        
JSR SETNAM        
LDA #0            
LDX DEFDRV        
LDY #0            
JSR SETLFS        
SEC               
JSR MEMBOT        
LDA <LFD          
JSR LOAD          
JSR READST        
STA <LFD          
JSR UDISKS        
RTS               
;=================
;EINGABEFUNKTIONEN
;=================
UINPUT            
;PROMPT-MELDUNG   
;(A/Y) AUSGEBEN   
;EINGABE NACH     
;TAB (0...)       
;X =>LAENGE       
;0 AM ENDE        
;C=1 => "*/?"     
;      GELESEN    
;                 
STA <IND          
STY <IND+1        
LDY #0            
STY <LFD          
INPUT1            
LDA (<IND),Y      
BEQ INPUT2        
JSR CHROUT        
INY               
BNE INPUT1        
INPUT2            
LDX #0            
INPUT3            
JSR CHRIN         
CMP #13           
BEQ INPUT5        
CMP #"*"          
BEQ INPUT4        
CMP #"?"          
BNE INPUT41       
INPUT4 INC <LFD   
INPUT41 STA TAB,X 
INX               
BNE INPUT3        
INPUT5            
LDA #0            
STA TAB,X         
LDA <LFD          
CMP #1            
RTS               
;-----------------
ZINPUT            
;WIE INPUT        
;EINGABE ALS      
;ZAHL NACH        
;A/Y (L/H)        
;C=1 =>"*/?"      
;                 
JSR UINPUT        
BCS ZINPT1        
LDX #0            
JSR URZAHL        
LDY <ERG+1        
LDA <ERG          
CLC               
ZINPT1 RTS        
;=================
ENDMOD3           
;                 
EXP UTOP,URSCRL,  
URBND,URTAB,      
;                 
UWHEAD,UINITP,    
;                 
UDISKI,UDISKC,    
UDISKS,USAVE,     
ULOAD,            
;                 
UINPUT,ZINPUT,    
;                 
ENDMOD3           
;                 
END