;-----------------
;M-PROGRAMM V4    
;=============    
;                 
;HILFSPROGRAMM IN 
;M-CODE FUER DEN  
;PASCAL-ASSEMBLER 
;                 
;24.5.1986        
;                 
ORG 5620          
;                 
;-----------------
<BASE EQU $FE     
;-----------------
BUCHST            
DFD 0,0           
DFD 0,0           
DFD 0,0           
DFD 0,0           
DFD 0,0           
DFD 0,0           
DFD 0,0           
DFD 0,0           
;                 
AM DFD 0,0        
ZW DFD 0,0        
;                 
MOR DFD 0,0       
MND DFD 0,0       
ERG DFD 0,0       
;                 
;-----------------
;START            
;HOLT ZU BEFEHL   
;IN 'BUCHST' DEN  
;6502 CODE:       
;AM=0 ->DEN ERSTEN
;       GEFUNDENEN
;=>ZW:=255 NICHT  
;GEFUNDEN, SONST  
;ADRESSIERUNGSART 
;                 
;AM>0 ->MIT DIESER
;ADRESSIERUNGSART 
;=>ZW:=255 NICHT  
;GEFUNDEN, SONST  
;OPCODE           
;-----------------
START CLD         
LDA BUCHST+2      
STA BUCHST+1      
LDA BUCHST+4      
STA BUCHST+2      
LDA BUCHST+6      
STA BUCHST+3      
;                 
LDX #$FF          
LDY #0            
LDA #[TAB         
STA <BASE         
LDA #]TAB         
STA <BASE+1       
;                 
SUCH              
LDA (<BASE),Y     
BMI NEXT          
INY               
BNE SUCH          
;                 
NEXT INX          
SEC               
TYA               
ADC <BASE         
STA <BASE         
BCC NOINC         
INC <BASE+1       
NOINC LDY #0      
CPX #255          
BNE COMP          
STX ZW            
RTS               
COMP LDA (<BASE),Y
AND #127          
CMP BUCHST,Y      
BNE SUCH          
INY               
CPY #3            
BNE COMP          
;                 
STX ZW            
TXA               
LSR               
TAX               
LDA ADCODE,X      
BCC RECHTS        
LSR               
LSR               
LSR               
LSR               
RECHTS            
AND #%00001111    
TAX               
LDA AM            
BEQ OK            
CMP ADDART,X      
BEQ ENDE          
LDX ZW            
JMP SUCH          
OK LDA ADDART,X   
STA ZW            
ENDE RTS          
;-----------------
UMULTI            
;MOR*MND=>ERG/MOR 
;(16*8)BIT OHNE   
;VORZEICHEN       
LDY #0            
STY ERG           
STY ERG+1         
LDY #8            
MULTI1 ASL ERG    
ROL ERG+1         
ROL MOR           
BCC MULTI2        
CLC               
LDA ERG           
ADC MND           
STA ERG           
LDA ERG+1         
ADC MND+1         
STA ERG+1         
BCC MULTI2        
INC MOR           
MULTI2 DEY        
BNE MULTI1        
RTS               
;                 
;-----------------
;                 
ADDART EQU *      
TAB    EQU *+12   
ADCODE EQU *+570  
LAST   EQU *+698  
;                 
;-----------------