(* INCLUDE-FILE FUER ASSEMBLER *)            
(* FLORIAN MATTHES 28.5.1986   *)            
                                             
(* ----------------------VERWALTUNG LABELS *)
                                             
FUNCTION FIND(LBL:LSTRING):TPLABEL;          
(* LIEFERT ZEIGER AUF LABELRECORD IM BAUM. *)
(* NIL, FALLS NICHT GEFUNDEN               *)
 VAR P:TPLABEL;                              
BEGIN                                        
  P:=ROOTLABEL; FIND:= NIL;                  
  WHILE P<>NIL DO                            
  BEGIN                                      
    IF P^.NAMEN>LBL THEN P:=P^.R ELSE        
    IF P^.NAMEN<LBL THEN P:=P^.L ELSE        
     BEGIN FIND:=P; P:=NIL END;              
  END;                                       
END; (* FIND *)                              
                                             
PROCEDURE DEFINE (LBL:LSTRING; ZAHL:INTEGER);
(* DEFINIERE LABEL MIT WERT ZAHL           *)
                                             
  PROCEDURE SEARCH(VAR P:TPLABEL);           
  BEGIN                                      
    IF P=NIL THEN                            
      BEGIN  (* NOCH NICHT VORHANDEN *)      
        NEW(P);                              
        WITH P^ DO                           
          BEGIN                              
            NAMEN:=LBL; WERT:= ZAHL;         
            L:=NIL; R:=NIL;                  
            LASTZN:=ZN; LASTLABEL:=P;        
          END;                               
      END ELSE                               
    IF P^.NAMEN>LBL THEN SEARCH(P^.R) ELSE   
    IF P^.NAMEN<LBL THEN SEARCH(P^.L) ELSE   
      ERROR(9); (* BEREITS VORHANDEN ! *)    
  END; (* SEARCH *)                          
                                             
BEGIN                                        
  SEARCH(ROOTLABEL);                         
END; (* DEFINE *)                            
                                             
PROCEDURE LABELTABELLE;                      
(* ZEIGE LABELTABELLE AN *)                  
 CONST LABELSPERPAGE=38;                     
 VAR C: INTEGER;                             
     P: TPLABEL;                             
                                             
  PROCEDURE SHOWLABELS(P:TPLABEL);           
  (*ZEIGE ALLE LABELS IM BAUM MIT WURZEL P *)
  BEGIN                                      
   IF P<>NIL THEN                            
   BEGIN                                     
     SHOWLABELS(P^.R);                       
     IF C MOD LABELSPERPAGE=0 THEN           
       BEGIN KEY;                            
         WRITELN("“LABELTABELLE:");          
         WRITELN("--------------");          
       END;                                  
     WRITE(P^.NAMEN, " =");                  
     WRITEADR(P^.WERT,6);WRITE("   ");       
     IF ODD(C) THEN WRITELN;                 
     IF P^.NAMEN[1]="<" THEN                 
       BEGIN                                 
        IF HBYTE(P^.WERT)<>0 THEN ERROR(4)   
       END                                   
     ELSE                                    
       BEGIN                                 
        IF HBYTE(P^.WERT)=0 THEN ERROR (4);  
       END;                                  
     C:=C+1;                                 
     SHOWLABELS(P^.L);                       
   END;                                      
  END; (* SHOWLABELS *)                      
                                             
BEGIN                                        
 ZN:=-1;(* UNTERDRUECKT ZEILE BEI FEHLERN *) 
 C:=0;                                       
 SHOWLABELS(ROOTLABEL);                      
END;(* LABELTABELLE*)