;=================
; SCREEN-EDITOR   
; (TEIL 4 C-64)   
;                 
;  24.11.1985     
;                 
ORG 39264         
;================ 
;                 
;***KONSTANTEN*** 
;                 
<MXCOL EQU 40     
<MXLIN EQU 25     
<ZAHL  EQU 4      
<SCRLC EQU 36     
<SCRLL EQU 0      
<MZEIL EQU 4      
<MSPAL EQU 4      
;                 
;***  Z-PAGE  *** 
;                 
<SP    EQU $FE    
<TP    EQU 2      
<IND   EQU 4      
;                 
<BASIS EQU 43     
<ENDE  EQU 45     
<TMEM  EQU 55     
;*** TABELLEN *** 
;                 
TEMPFLG EQU 907   
RSMEFLG EQU 908   
PNT     EQU 909   
COMP    EQU 923   
;                 
TAB    EQU $7FA0  
;                 
;=1=              
FLAG   EQU $7F20  
APOS   EQU $7F32  
;                 
;=2=              
ZNRL   EQU $7F40  
AZEIL  EQU $7F52  
ANFZEI EQU $7F53  
TXTBOT EQU $7F54  
MASK   EQU $7F55  
BNDS   EQU $7F56  
TABU   EQU $7F57  
;                 
;=3=              
ZNRH   EQU $7F60  
;                 
<CXIND EQU $11    
<AXIND EQU $14    
<MXIND EQU $20    
;[ZNRH-ZNRL]      
;                 
;**TEXT-SPALTEN** 
;                 
<TZEIL  EQU $6    
<TSPAL  EQU $8    
<ASPAL  EQU $9    
<ANFSPA EQU $A    
<TXTLEN EQU $B    
<LBND   EQU $C    
<RBND   EQU $D    
;                 
;**BILD-ZEIGER*** 
;                 
<SSPAL  EQU $E    
<SZEIL  EQU $F    
<XSPAL  EQU $10   
<XZEIL  EQU $11   
;                 
<SCLEN  EQU $12   
;                 
;**BILD-ZEILEN*** 
;                 
<SCTOP  EQU $13   
<SCBOT  EQU $14   
;                 
<MSKFLG EQU $15   
<BNDFLG EQU $16   
<TABFLG EQU $17   
<COLFLG EQU $18   
<TOPFLG EQU $19   
;                 
;**HILFSREGISTER* 
;                 
<MMFLAG EQU $1A   
<XREG   EQU $1B   
<YREG   EQU $1C   
<ZAEHL  EQU $1D   
<LFD    EQU $1E   
;                 
<SCRLH  EQU $1F   
<SCRLV  EQU $20   
<SCRLM  EQU $21   
;                 
;                 
<CODE   EQU $23   
<TEFLAG EQU $24   
<FEHLER EQU $25   
<ENDFLG EQU $26   
<COMFLG EQU $27   
;                 
<LAENG1 EQU $39   
<LAENG2 EQU $3A   
<BOTTOM EQU $3B   
<FMODUS EQU $3C   
<FMASKE EQU $3D   
<SPALT1 EQU $3E   
<SPALT2 EQU $3F   
<TRENN  EQU $40   
<FZAEHL EQU $41   
;(L/H)            
;                 
;***RECHENREG.*** 
;                 
<MOR    EQU $43   
<MND    EQU $44   
<ERG    EQU $46   
;                 
<ZL     EQU $48   
<ZH     EQU $49   
<NL     EQU $4A   
<NH     EQU $4B   
<HL     EQU $4C   
<HH     EQU $4D   
;                 
;===============  
READY  EQU $A474  
BASCLR EQU $A660  
BASINT EQU $E3BF  
VEKTOR EQU $E453  
BASCMD EQU $A7E7  
;(BEFPNT) ALT!    
;                 
CHKIN  EQU $FFC6  
CHKOUT EQU $FFC9  
CHRIN  EQU $FFCF  
CHROUT EQU $FFD2  
CLOSE  EQU $FFC3  
CLRCHN EQU $FFCC  
LOAD   EQU $FFD5  
MEMTOP EQU $FF99  
MEMBOT EQU $FF9C  
OPEN   EQU $FFC0  
READST EQU $FFB7  
SAVE   EQU $FFD8  
SETLFS EQU $FFBA  
SETMSG EQU $FF90  
SETNAM EQU $FFBD  
;                 
REPEAT EQU 650    
ERRPTR EQU $300   
BEFPNT EQU $308   
;                 
<CHGET EQU $0073  
<CHGOT EQU $0079  
;                 
;===============  
;                 
UMULTI EQU 32771  
UCOLOR EQU 33527  
;                 
;===============  
;                 
URZAHL EQU 34751  
TPADR  EQU 35224  
UINSA  EQU 35236  
UINSB  EQU 35242  
;                 
;===============  
;                 
MAIN^  EQU 37274  
MAIN2  EQU 37372  
UINPUT EQU 37948  
ZINPUT EQU 37996  
;                 
;===============  
COPY              
;KOPIERT TEILE    
;AUS EINEM        
;DATASET  AUF     
;DER DISKETTE     
;                 
JSR DEFLT         
LDA #[MSG3        
LDY #]MSG3        
JSR UINPUT        
BCS COPYQ         
TXA               
LDX #[TAB         
LDY #]TAB         
JSR SETNAM        
LDA #1            
LDX #8            
LDY #0            
JSR SETLFS        
LDA #1            
JSR CLOSE         
JSR OPEN          
BCC *+5           
JMP ENDX          
LDX #1            
JSR CHKIN         
;                 
;STARTADRESSE     
;UEBERLESEN:      
;ABBRUCH,FALLS    
;FILE NOT FOUND   
;                 
JSR CHRIN         
JSR CHRIN         
JSR READST        
BNE COPYQ         
;                 
JSR CHRIN         
STA <TSPAL        
JSR CHRIN         
STA <FZAEHL       
JSR CHRIN         
STA <FZAEHL+1     
JSR CLRCHN        
LDA <TSPAL        
CMP <TXTLEN       
BEQ COPY1         
;VERSCHIEDENE     
;SATZLAENGE!      
LDA #[MSG4        
LDY #]MSG4        
JSR UINPUT        
CPX #1            
BNE COPYQ         
LDA TAB           
CMP #"C"          
BEQ COPY1         
;                 
COPYQ             
;CANCEL           
JMP ENDQ          
;                 
COPY1             
LDA #0            
STA <TZEIL        
STA <TZEIL+1      
LDA #[MSG5        
LDY #]MSG5        
JSR UINPUT        
BCS COPY3         
;**ALL**          
LDX #0            
JSR URZAHL        
LDA <ERG          
STA <TZEIL        
LDA <ERG+1        
STA <TZEIL+1      
LDA #[MSG6        
LDY #]MSG6        
JSR UINPUT        
BCS COPY1         
LDX #0            
JSR URZAHL        
LDX <ERG          
LDY <ERG+1        
CPY <FZAEHL+1     
BCC COPY4         
BNE COPY3         
CPX <FZAEHL       
BCC COPY4         
COPY3             
;** BIS ENDE      
LDX <FZAEHL       
LDY <FZAEHL+1     
DEX               
CPX #255          
BNE COPY4         
DEY               
;                 
COPY4 SEC         
TXA               
SBC <TZEIL        
TAX               
TYA               
SBC <TZEIL+1      
BCC COPY1         
STX <FZAEHL       
STA <FZAEHL+1     
;DIFFERENZ        
;IN FZAEHL        
;                 
COPY5 CLC         
LDA <TZEIL        
ADC #3            
STA <MND          
LDA <TZEIL+1      
ADC #0            
STA <MND+1        
LDA <TSPAL        
STA <MOR          
JSR UMULTI        
CLC               
LDA <ERG          
ADC #1            
PHA               
LDA <ERG+1        
ADC #0            
PHA               
LDX #1            
JSR CHKIN         
PLA               
TAY               
PLA               
TAX               
;                 
;STATUSZEILEN     
;ETC. UEBERLESEN  
;                 
BEQ COPY7         
COPY6 JSR CHRIN   
DEX               
CPX #255          
BNE COPY6         
COPY7 DEY         
LDX #255          
CPY #255          
BNE COPY6         
;                 
COPY8             
JSR UILINE        
BCC COPY9         
JMP ENDE          
COPY9 LDY #0      
COPY11 JSR CHRIN  
STA (<TP),Y       
INY               
CPY <TXTLEN       
BEQ COPY13        
CPY <TSPAL        
BNE COPY11        
LDA #" "          
COPY12            
STA (<TP),Y       
INY               
CPY <TXTLEN       
BNE COPY12        
BEQ COPY14        
COPY13            
CPY <TSPAL        
BEQ COPY14        
JSR CHRIN         
INY               
BNE COPY13        
COPY14            
DEC <FZAEHL       
LDA <FZAEHL       
CMP #255          
BNE COPY8         
DEC <FZAEHL+1     
LDA <FZAEHL+1     
CMP #255          
BNE COPY8         
JMP ENDQ          
;                 
;                 
;                 
UILINE            
;FUEGT EINE ZEILE 
;BEI ZNRL+17...   
;EIN. SETZT <TP   
;C=1 => FEHLER    
;                 
LDA FLAG+17       
CMP #2            
LDA ZNRL+17       
LDY ZNRH+17       
LDX #1            
BCS ILINE1        
JSR UINSA         
PHP               
INC ZNRL+17       
BNE ILINE2        
INC ZNRH+17       
BNE ILINE2        
ILINE1 JSR UINSB  
PHP               
ILINE2            
LDA <TZEIL        
LDY <TZEIL+1      
JSR TPADR         
PLP               
RTS               
;                 
;===============  
DIALOG            
;FUER SEQ. I/O    
;SETZT NAME,      
;PRIMAER- UND     
;SEKUNDAERADR.    
;AUF FILE #1      
;(INCL. OPEN)     
;C=1 => FEHLER    
;    X=0: CANCEL  
;SONST SYSERROR   
;                 
LDA #[MSG7        
LDY #]MSG7        
JSR ZINPUT        
LDX #0            
BCS DIA9          
STA <FZAEHL       
LDA #[MSG8        
LDY #]MSG8        
JSR ZINPUT        
BCC DIA1          
LDA #255          
DIA1 TAY          
LDX <FZAEHL       
LDA #1            
JSR SETLFS        
LDA #[MSG9        
LDY #]MSG9        
JSR UINPUT        
BCC DIA2          
LDX #0            
DIA2 TXA          
LDX #[TAB         
LDY #]TAB         
JSR SETNAM        
JSR OPEN          
BCC DIA3          
;                 
;SYSTEM ERROR...  
;                 
STA <FEHLER       
LDX #255          
STX <CODE         
SEC               
RTS               
;                 
DIA3 LDA #[MSG10  
LDY #]MSG10       
JSR ZINPUT        
LDY #255          
BCC DIA4          
LDY #0            
DIA4 STA <FZAEHL  
STY <FZAEHL+1     
CLC               
DIA9 RTS          
;                 
;FZAEHL+1 = 0     
;=>KEIN DELIM.    
;SONST:           
;FZAEHL=>DELIM.   
UOUT              
;SEQ. OUTPUT      
;                 
JSR DIALOG        
BCC OUT1          
CPX #0            
BEQ *+5           
JMP ENDE          
JMP ENDQ          
OUT1              
;TRUNCATE         
;JA =>MMFLAG<>0   
;                 
LDA #[MSG11       
LDY #]MSG11       
JSR UINPUT        
BCS OUT1          
CPX #1            
BNE OUT1          
LDA TAB           
CMP #"Y"          
BEQ OUT2          
CMP #"N"          
BNE OUT1          
LDA #0            
OUT2              
STA <MMFLAG       
LDA #0            
TAY               
JSR TPADR         
LDX #1            
JSR CHKOUT        
BCC OUT4          
JMP ENDX          
;                 
OUT4              
LDA <TP+1         
CMP <ENDE+1       
BCC OUT5          
LDA <TP           
CMP <ENDE         
BCC OUT5          
JMP ENDQ          
OUT5 LDY <TXTLEN  
LDA <MMFLAG       
BEQ OUT8          
OUT6 DEY          
LDA (<TP),Y       
CMP #" "          
BNE OUT7          
CPY #0            
BNE OUT6          
BEQ OUT10         
OUT7 INY          
OUT8 STY <LFD     
LDY #0            
OUT9 LDA (<TP),Y  
JSR CHROUT        
INY               
CPY <LFD          
BNE OUT9          
OUT10             
LDA <FZAEHL+1     
BEQ OUT11         
LDA <FZAEHL       
JSR CHROUT        
OUT11 CLC         
LDA <TP           
ADC <TXTLEN       
STA <TP           
BCC OUT4          
INC <TP+1         
BNE OUT4          
;                 
;                 
UIN               
;SEQ. INPUT       
;                 
JSR DIALOG        
BCC IN1           
CPX #0            
BNE *+5           
JMP ENDQ          
JMP ENDE          
;                 
IN1               
JSR DEFLT         
LDX #1            
JSR CHKIN         
LDA #0            
STA <MMFLAG       
;                 
IN2               
JSR UILINE        
BCS ENDE          
;                 
LDY #0            
LDX <FZAEHL+1     
IN3 JSR CHRIN     
PHA               
JSR READST        
CMP #1            
PLA               
BCS IN5           
CPX #0            
BEQ IN4           
CMP <FZAEHL       
BEQ IN6           
IN4 STA (<TP),Y   
INY               
CPY <TXTLEN       
BNE IN3           
BEQ IN8           
IN5 INC <MMFLAG   
IN6 LDA #" "      
IN7 STA (<TP),Y   
INY               
CPY <TXTLEN       
BNE IN7           
IN8 LDA <MMFLAG   
BEQ IN2           
BNE ENDQ          
;                 
ENDX STA <FEHLER  
LDA #255          
STA <CODE         
SEC               
BCS ENDE          
;                 
ENDQ CLC          
;                 
ENDE PHP          
JSR CLRCHN        
LDA #0            
STA FLAG+17       
LDA #1            
JSR CLOSE         
JSR UCOLOR        
PLP               
RTS               
;                 
DEFLT             
;SETZE DEFAULT    
;POSITON          
;(VOR ZEILE 0)    
LDA FLAG+17       
BNE DEFLT1        
LDA #2            
STA FLAG+17       
LDA #0            
STA ZNRL+17       
STA ZNRH+17       
DEFLT1 RTS        
;                 
USTORE            
;BASIC ZEIGER     
;RETTEN           
LDX #13;56-43     
STORE1            
LDA <BASIS,X      
STA PNT,X         
DEX               
BPL STORE1        
RTS               
;                 
MSG1              
DFD 9,142,147,31  
DFD "PASCAL-"     
DFD "MENU ",13    
DFD "·······"     
DFD "···· ",13    
DFD 13,13         
DFD "SELECT "     
DFD "OPTION:",13  
DFD 13            
DFD "NAME  EDIT " 
DFD "NEW DATASET" 
DFD 13            
DFD "'?'   RESUME"
DFD " EDIT",13    
DFD "'$'   COMPI" 
DFD "LE DATASET"  
DFD 13            
DFD "'*'   EXIT " 
DFD "TO BASIC",13 
DFD 13,"==>",0    
MSG3              
DFD 147           
DFD "COPY D"      
DFD "ATASET",13   
DFD "······"      
DFD "······"      
DFD 13,13,13      
DFD "ENTER DATA"  
DFD "SET-NAME:",13
DFD "['*' OR '?"  
DFD "' FOR END]"  
DFD 13,13         
DFD "==>",0       
MSG4              
DFD 147,13,13     
DFD "THIS DATAS"  
DFD "ET HAS A ",13
DFD "DIFFERENT’ "
DFD "RECORD-SIZE!"
DFD 13,13         
DFD "CONFIRM COPY"
DFD " WITH 'C'!"  
DFD 13,13         
DFD "==>",0       
MSG5              
DFD 147,13,13     
DFD "FIRST LINE " 
DFD "COPIED:",13  
DFD "'*' OR '?' " 
DFD "TO COPY ALL" 
DFD 13            
DFD "==>",0       
MSG6              
DFD 13,13         
DFD "LAST LINE "  
DFD "COPIED:",13  
DFD "==>",0       
;                 
MSG7              
DFD 147,13,13     
DFD "DEVICE NUM"  
DFD "BER:",13     
DFD "['*' OR '?"  
DFD "' FOR END]"  
DFD 13,"==>",0    
MSG8              
DFD 13            
DFD "SEK. ADDRESS"
DFD ":",13        
DFD "['*' OR '?' "
DFD "FOR NONE]",13
DFD "==>",0       
MSG9              
DFD 13            
DFD "FILE NAME:"  
DFD 13            
DFD "['*' OR '?' "
DFD "FOR NONE]",13
DFD "==>",0       
MSG10             
DFD 13            
DFD "CODE OF DE"  
DFD "LIMITER:",13 
DFD "['*' OR '?' "
DFD "FOR NONE]",13
DFD "==>13??",0   
MSG11             
DFD 13            
DFD "TRUNCATE "   
DFD "TRAILING",13 
DFD "SPACES? ("   
DFD "Y’ES OR N’"
DFD "O)",13       
DFD "==>Y?",0     
;                 
MENUE             
;-----------------
;EINTRITT VON     
;BASIC AUS        
;-----------------
JSR USTORE        
MENUE1            
;* ERRORPOINTER   
;* UMSETZEN       
;* (FUER RESTORE) 
LDA #[MENUE0      
STA ERRPTR        
LDA #]MENUE0      
STA ERRPTR+1      
JSR UCOLOR        
LDA #0            
JSR SETMSG        
SEC               
JSR MEMTOP        
STX <TMEM         
STY <TMEM+1       
;**TITELBILD:     
LDA #[MSG1        
LDY #]MSG1        
JSR UINPUT        
BCS MENUE2        
LDA TAB           
CMP #"$"          
BEQ MENUE5        
JSR MAIN^         
BCC MENUE3        
;                 
MENUE0            
;**RESUME SPERREN 
LDA #0            
STA RSMEFLG       
BEQ MENUE1        
;                 
MENUE2            
CMP #"?"          
BNE MENUE9        
LDA RSMEFLG       
BEQ MENUE1        
JSR MAIN2         
BCS MENUE0        
;                 
MENUE3            
;**RESUME ERLAUBEN
LDA #1            
STA RSMEFLG       
BNE MENUE1        
;                 
MENUE5 JSR UIZPAG 
JMP COMP          
;==> COMPILER     
;-----------------
MENUE9            
;BASIC ZEIGER     
;ZURUECKHOLEN     
JSR UIZPAG        
LDX #13           
MENUE10           
LDA PNT,X         
STA <BASIS,X      
DEX               
BPL MENUE10       
JSR BASCLR        
JSR VEKTOR        
;                 
LDA #[BEFNEU      
STA BEFPNT        
LDA #]BEFNEU      
STA BEFPNT+1      
;                 
JMP READY         
;-----------------
BEFNEU            
JSR <CHGET        
CMP #172;"*"      
BNE BEFNEU1       
JMP MENUE1        
BEFNEU1           
JSR <CHGOT        
JMP BASCMD        
;=================
OBJECT  EQU $4000 
;ANFANG CODE      
SOURCE  EQU 641   
;ANFANG QUELLTEXT 
TABLES  EQU 643   
;ANFANG EDITOR    
START   EQU 5611  
;ZIEL FUER CODE   
;-----------------
<ABANF  EQU $5F   
<ABEND  EQU $5A   
<NBEND  EQU $58   
BLOCK   EQU $A3BF 
;**KOPIERT NUR    
;**VON L->H. KEINE
;**UEBERLAPPUNG!  
;-----------------
NAME1 DFD "C$"    
NAME2 DFD "F$"    
;                 
;NACH RUECKKEHR   
;VOM COMPILER DEN 
;CODE VERSCHIEBEN:
;                 
;ABANF :=OBJECT   
;ABEND :=(SOURCE) 
;NBEND :=START    
;    +ABEND-ABANF 
;                 
;<== COMPILER     
;=================
RETURN            
LDA #[OBJECT      
STA <ABANF        
LDA #]OBJECT      
STA <ABANF+1      
;                 
SEC               
LDA SOURCE        
STA <ABEND        
SBC <ABANF        
STA <NBEND        
LDA SOURCE+1      
STA <ABEND+1      
SBC <ABANF+1      
STA <NBEND+1      
;(NBEND=LAENGE)   
CLC               
LDA <NBEND        
ADC #[START       
STA <NBEND        
LDA <NBEND+1      
ADC #]START       
STA <NBEND+1      
JSR BLOCK         
LDA TEMPFLG       
BEQ RETURN9       
;                 
;CODE NACHLADEN:  
;                 
LDA #2            
LDX #[NAME1       
LDY #]NAME1       
JSR SETNAM        
LDA #1            
LDX #8            
LDY #2            
;** ABSOLUT LADEN 
JSR SETLFS        
LDA #0            
JSR LOAD          
STX <ENDE         
STY <ENDE+1       
;** FIXUP         
LDA #2            
LDX #[NAME2       
LDY #]NAME2       
JSR SETNAM        
LDA #1            
LDX #8            
LDY #3            
JSR SETLFS        
JSR OPEN          
LDX #1            
JSR CHKIN         
;                 
RETURN1           
JSR CHRIN         
STA <SP           
JSR CHRIN         
STA <SP+1         
JSR READST        
BNE RETURN7       
JSR CHRIN         
LDY #0            
STA (<SP),Y       
INY               
JSR CHRIN         
STA (<SP),Y       
JMP RETURN1       
;                 
RETURN7           
JSR CLRCHN        
LDA #1            
JSR CLOSE         
;**TEST AUF       
;**UEBERLAUF:     
LDA SOURCE        
CMP <ENDE         
LDA SOURCE+1      
SBC <ENDE+1       
BCS RETURN9       
;**RESUME SPERREN 
LDA #0            
STA RSMEFLG       
;                 
LDA TABLES        
CMP <ENDE         
LDA TABLES+1      
SBC <ENDE+1       
BCS RETURN9       
;**UEBERLAUF      
;**=>ABBRUCH      
JMP MENUE9        
;                 
RETURN9           
JMP MENUE1        
;-----------------
UIZPAG            
;ZERO PAGE INIT.  
;BASIC ZEIGER     
;RUECKSETZEN      
;                 
SEC               
JSR MEMBOT        
STX <ENDE         
STY <ENDE+1       
;BYTE 0 RETTEN:   
LDY #0            
LDA (<ENDE),Y     
PHA               
JSR BASINT        
LDY #0            
PLA               
STA (<ENDE),Y     
RTS