;================ 
; SCREEN-EDITOR   
;(TEIL3.2  C-64)  
;                 
;17.11.1985       
;                 
ORG 38012         
;                 
;================ 
;                 
;***KONSTANTEN*** 
;                 
<MXCOL EQU 40     
<MXLIN EQU 25     
<ZAHL  EQU 4      
<SCRLC EQU 36     
<SCRLL EQU 0      
<MZEIL EQU 4      
<MSPAL EQU 4      
;                 
;***  Z-PAGE  *** 
;                 
<SP    EQU $FE    
<TP    EQU 2      
<IND   EQU 4      
;                 
<BASIS EQU 43     
<ENDE  EQU 45     
<TMEM  EQU 55     
;*** TABELLEN *** 
;                 
TAB    EQU $7FA0  
<MXLEN EQU $20    
STRNG1 EQU $7F80  
STRNG2 EQU $7F00  
;                 
;=1=              
FLAG   EQU $7F20  
APOS   EQU $7F32  
;                 
;=2=              
ZNRL   EQU $7F40  
AZEIL  EQU $7F52  
ANFZEI EQU $7F53  
TXTBOT EQU $7F54  
MASK   EQU $7F55  
BNDS   EQU $7F56  
TABU   EQU $7F57  
;                 
;=3=              
ZNRH   EQU $7F60  
;                 
<CXIND EQU $11    
<AXIND EQU $14    
<MXIND EQU $20    
;[ZNRH-ZNRL]      
;                 
;**TEXT-SPALTEN** 
;                 
<TZEIL  EQU $6    
<TSPAL  EQU $8    
<ASPAL  EQU $9    
<ANFSPA EQU $A    
<TXTLEN EQU $B    
<LBND   EQU $C    
<RBND   EQU $D    
;                 
;**BILD-ZEIGER*** 
;                 
<SSPAL  EQU $E    
<SZEIL  EQU $F    
<XSPAL  EQU $10   
<XZEIL  EQU $11   
;                 
<SCLEN  EQU $12   
;                 
;**BILD-ZEILEN*** 
;                 
<SCTOP  EQU $13   
<SCBOT  EQU $14   
;                 
<MSKFLG EQU $15   
<BNDFLG EQU $16   
<TABFLG EQU $17   
<COLFLG EQU $18   
<TOPFLG EQU $19   
;                 
;**HILFSREGISTER* 
;                 
<MMFLAG EQU $1A   
<XREG   EQU $1B   
<YREG   EQU $1C   
<ZAEHL  EQU $1D   
<LFD    EQU $1E   
;                 
<SCRLH  EQU $1F   
<SCRLV  EQU $20   
<SCRLM  EQU $21   
;                 
;                 
<CODE   EQU $23   
<TEFLAG EQU $24   
<FEHLER EQU $25   
<ENDFLG EQU $26   
<COMFLG EQU $27   
<FNDFLG EQU $28   
;                 
<LAENG1 EQU $39   
<LAENG2 EQU $3A   
<BOTTOM EQU $3B   
<FMODUS EQU $3C   
<FMASKE EQU $3D   
<SPALT1 EQU $3E   
<SPALT2 EQU $3F   
<TRENN  EQU $40   
<FZAEHL EQU $41   
;(L/H)            
;                 
;***RECHENREG.*** 
;                 
<MOR    EQU $43   
<MND    EQU $44   
;                 
<ERG    EQU $46   
;                 
<ZL     EQU $48   
<ZH     EQU $49   
<NL     EQU $4A   
<NH     EQU $4B   
<HL     EQU $4C   
<HH     EQU $4D   
;                 
;===============  
;                 
CHKIN  EQU $FFC6  
CHKOUT EQU $FFC9  
CHRIN  EQU $FFCF  
CHROUT EQU $FFD2  
CLOSE  EQU $FFC3  
CLRCHN EQU $FFCC  
LOAD   EQU $FFD5  
MEMBOT EQU $FF9C  
OPEN   EQU $FFC0  
READST EQU $FFB7  
SAVE   EQU $FFD8  
SETLFS EQU $FFBA  
SETMSG EQU $FF90  
SETNAM EQU $FFBD  
;                 
REPEAT EQU 650    
;================ 
UDELE  EQU 33121  
UINSE  EQU 33151  
UFRE   EQU 33185  
UCSPR  EQU 33591  
UMOVE  EQU 34050  
UAPOS  EQU 34098  
UNPOS  EQU 34154  
;================ 
GETSCR EQU 34714  
URZAHL EQU 34751  
TPADR  EQU 35224  
;================ 
UDISKC EQU 37605  
USAVE  EQU 37702  
;================ 
;                 
UPRIM             
;BEFEHLSZEILE     
;LESEN UND ZUR    
;AUSFUEHRUNG      
;SPRINGEN         
;C=1 =>FEHLER     
LDA #0            
STA <CODE         
LDA <COMFLG       
BEQ PRIM10        
LDA #0            
TAX               
JSR UCSPR         
LDY #0            
PRIM1 JSR GETSCR  
STA TAB,Y         
INY               
CPY #<SCRLC       
BNE PRIM1         
LDA #" "          
STA TAB,Y         
INY               
LDA #0            
STA TAB,Y         
LDX #0            
JSR BEFIND        
BCS PRIM10        
CPX #17;<==MAXIND 
BCS PRIM5         
TXA               
ASL               
TAX               
LDA SPRTAB,X      
STA <IND          
LDA SPRTAB+1,X    
STA <IND+1        
JMP (<IND)        
;                 
;DISK-COMMAND     
;                 
PRIM5             
LDX #<SCRLC-1     
PRIM6 LDA TAB,X   
CMP #" "          
BNE PRIM7         
DEX               
BPL PRIM6         
PRIM7 INX         
JSR UDISKC        
LDA <CODE         
ORA #1            
STA <CODE         
;STATUS ANZEIGEN  
;(AUCH 00,OK...)  
SEC               
RTS               
PRIM10 CLC        
RTS               
;                 
UCOL              
LDA #1            
STA <COLFLG       
RTS               
;                 
UBNDS             
LDA #1            
STA <BNDFLG       
RTS               
;                 
UMSK              
LDA #1            
STA <MSKFLG       
RTS               
;                 
UTABS             
LDA #1            
STA <TABFLG       
RTS               
;                 
ULOC              
LDX <ZAEHL        
INX               
JSR URZAHL        
LDX <ERG+1        
LDA <ERG          
CPX TXTBOT+<MXIND 
BCC LOC2          
BNE LOC1          
CMP TXTBOT        
BCC LOC2          
LOC1 LDA TXTBOT   
LDX TXTBOT+<MXIND 
LOC2 STA ANFZEI   
STX ANFZEI+<MXIND 
RTS               
;                 
UPROF             
LDA #1            
STA <MSKFLG       
STA <BNDFLG       
STA <TABFLG       
STA <COLFLG       
RTS               
;                 
URESET            
LDA #255          
STA <LAENG1       
STA <LAENG2       
LDA #0            
STA <MSKFLG       
STA <BNDFLG       
STA <TABFLG       
STA <COLFLG       
STA <TEFLAG       
STA REPEAT        
LDX #<CXIND       
RESET1            
STA FLAG,X        
DEX               
BPL RESET1        
RTS               
;                 
UREPT             
LDA #255          
STA REPEAT        
RTS               
;                 
UTXTON            
LDA #255          
STA <TEFLAG       
RTS               
;                 
UCANCL            
LDA #255          
STA <ENDFLG       
RTS               
;                 
UENDE             
JSR USAVE         
BCC UCANCL        
RTS               
;                 
BEFIND            
;SPACE AM ANFANG  
;UEBERLESEN       
;BEFEHL AB TAB,X  
;BIS SPACE IN     
;TABELLE COMTAB   
;SUCHEN.          
;C=0 =>           
;GEFUNDEN:        
;X = INDEX        
;ZAEHL ZEIGT AUF  
;NAECHSTES SPACE  
;                 
;UNBEKANNT:       
;X = 255          
;ZAEHL ZEIGT AUF  
;DAS 1. ZEICHEN   
;                 
;C=1 =>TEXTENDE   
;                 
BEF0 LDA TAB,X    
BEQ BEF6          
INX               
CMP #" "          
BEQ BEF0          
DEX               
STX <ZAEHL        
LDY #0            
STY <YREG         
BEF1 LDX <ZAEHL   
BEF2              
LDA COMTAB,Y      
AND #127          
BEQ BEF5          
CMP TAB,X         
BNE BEF3          
INX               
INY               
LDA TAB,X         
CMP #" "          
BNE BEF2          
LDA COMTAB,Y      
BPL BEF4          
BEF3 INY          
LDA COMTAB,Y      
BNE BEF3          
INC <YREG         
INY               
BNE BEF1          
BEF4 STX <ZAEHL   
;***GEFUNDEN!     
LDX <YREG         
CLC               
RTS               
BEF5 LDX #255     
;***NICHT GEF.    
CLC               
RTS               
BEF6 SEC          
;***TEXTENDE      
RTS               
;                 
;===============  
;                 
COMTAB            
;                 
DFD "ÃÏÌUMNS",0   
DFD "ÍÓËS",0      
DFD "ÂÎÄS",0      
DFD "ÔÁÂULATOR",0 
DFD "ÌOCATE",0    
DFD "ÐÒÏÆILE",0   
DFD "ÒÅÓET",0     
DFD "ÔÅXT",0      
DFD "ÃÁÎCEL",0    
DFD "ÅÎÄ",0       
DFD "ÓÁÖÅ",0      
DFD "ÒÅÐEAT",0    
DFD "ÆIND",0      
DFD "ÃHANGE",0    
DFD "ÃÏÐÙ",0      
DFD "ÉÎPUT",0     
DFD "ÏÕÔPUT",0    
DFD "ÁÌÌ",0       
DFD "ÆÉÒST",0     
DFD "ÎÅØT",0      
DFD "ÃÈÁRS",0     
DFD "×ÏÒD",0      
DFD "ÐÒÅFIX",0    
DFD "ÓÕÆFIX",0    
DFD 0             
;                 
SPRTAB            
;SPRUNGTABELLE    
;FUER COMMANDS    
;                 
DFD UCOL          
DFD UMSK          
DFD UBNDS         
DFD UTABS         
DFD ULOC          
DFD UPROF         
DFD URESET        
DFD UTXTON        
DFD UCANCL        
DFD UENDE         
DFD USAVE         
DFD UREPT         
DFD UFIND         
DFD UCHANG        
DFD URESET        
DFD URESET        
DFD URESET        
;                 
;===============  
;                 
GETTXT            
;HOLE TEXT AB     
;TAB,X =>(<IND)   
;A=>ALTE LAENGE   
;Y<=LAENGE NEU    
;X<=NAECHSTES     
;   ZEICHEN       
;                 
STA <LFD          
GETTX1 LDA TAB,X  
INX               
CMP #0            
BEQ GETTX9        
CMP #" "          
BEQ GETTX1        
CMP #"*"          
BNE GETTX2        
LDY <LFD          
CPY #255          
BEQ GETTX9        
BNE GETTX8        
;                 
GETTX2 CMP #"#"   
BNE GETTX3        
JSR URZAHL        
LDA <ERG          
LDY #0            
STA (<IND),Y      
INY               
BNE GETTX8        
;                 
GETTX3 CMP #"'"   
BNE GETTX5        
LDY #0            
GETTX4 LDA TAB,X  
BEQ GETTX9        
CMP #"'"          
BEQ GETTX7        
CPY #<MXLEN       
BPL NOCOP1        
STA (<IND),Y      
NOCOP1 INY        
INX               
BNE GETTX4        
;                 
GETTX5 LDY #0     
GETTX6            
CPY #<MXLEN       
BPL NOCOP2        
STA (<IND),Y      
NOCOP2            
LDA TAB,X         
INY               
INX               
CMP #" "          
BNE GETTX6        
BEQ GETTX8        
GETTX7 INX        
GETTX8 CLC        
RTS               
GETTX9 SEC        
RTS               
;                 
UCHANG            
;CHANGE ...       
;HOLE PARAMETER   
;AUSFUEHRUNG      
;                 
LDA #[STRNG1      
STA <IND          
LDA #]STRNG1      
STA <IND+1        
LDA <LAENG1       
LDX <ZAEHL        
JSR GETTXT        
BCS FINDX         
CPY #0            
BEQ FINDX         
STY <LAENG1       
LDA #[STRNG2      
STA <IND          
LDA #]STRNG2      
STA <IND+1        
LDA <LAENG2       
JSR GETTXT        
BCS FINDX         
STY <LAENG2       
LDA #128          
BNE FIND0         
;                 
FINDX             
;STRING FEHLT     
LDA #135          
STA <FEHLER       
SEC               
RTS               
;                 
UFIND             
;PARAMETER LESEN  
;UND AUSFUEHRUNG  
;                 
LDA #[STRNG1      
STA <IND          
LDA #]STRNG1      
STA <IND+1        
LDA <LAENG1       
LDX <ZAEHL        
JSR GETTXT        
BCS FINDX         
CPY #0            
BEQ FINDX         
STY <LAENG1       
LDA #255          
LDA <LAENG2       
LDA #0            
;                 
FIND0             
;SETZE DEFAULT-   
;WERTE            
STA <FMODUS       
LDA #0            
STA <FMASKE       
LDA <LBND         
STA <SPALT1       
LDA <RBND         
SEC               
SBC <LAENG1       
STA <SPALT2       
FIND1             
;HOLE SCHLUESSEL- 
;WORTE            
;SETZE FMODUS     
;UND FMASKE       
JSR BEFIND        
BCC *+5           
JMP USUCHE        
CPX #17           
BNE FIND2         
LDA <FMODUS       
ORA #64           
STA <FMODUS       
BNE FIND6         
FIND2 CPX #18     
BNE FIND3         
LDA <FMODUS       
ORA #32           
STA <FMODUS       
BNE FIND6         
FIND3 CPX #19     
BEQ FIND6         
CPX #20           
BEQ FIND6         
CPX #21           
BNE FIND4         
LDA <FMASKE       
ORA #3            
STA <FMASKE       
BNE FIND6         
FIND4 CPX #22     
BNE FIND5         
LDA <FMASKE       
ORA #2            
STA <FMASKE       
BNE FIND6         
FIND5 CPX #23     
BNE FIND7         
LDA <FMASKE       
ORA #1            
STA <FMASKE       
;                 
FIND6             
LDX <ZAEHL        
BNE FIND1         
;                 
FIND7 LDX <ZAEHL  
LDA TAB,X         
CMP #"0"          
BCC FINDQ1        
CMP #"9"+1        
BCS FINDQ1        
;                 
;SPALTEN1 UND 2   
;LESEN            
;                 
JSR URZAHL        
LDA <ERG          
CMP <TXTLEN       
BCS FINDQ2        
STA <SPALT1       
STA <SPALT2       
LDA TAB,X         
CMP #"-"          
BNE USUCHE        
INX               
JSR URZAHL        
LDA <ERG          
CMP <TXTLEN       
BCS FINDQ2        
STA <SPALT2       
BCC USUCHE        
;                 
FINDQ1            
;***SYNTAX        
LDA #134          
DFD $2C           
FINDQ2            
;***ILL. WERTE    
LDA #136          
STA <FEHLER       
SEC               
RTS               
;                 
USUCHE            
;                 
;FIND UND CHANGE  
;===============  
;FMODUS = FIRST:  
;ZEIGER AUF       
;ANFANG SETZEN    
;                 
;SONST:           
;1                
; IM TEXT:        
; AB CURSORPOSI-  
; TION (+1, FALLS 
; MODUS = FIND)   
;2                
; SONST: AB ECKE  
; LINKS OBEN      
;                 
;                 
INITS1            
LDA <FMODUS       
AND #96           
BEQ INITS2        
;** AB ANFANG     
;** SUCHEN        
LDA #0            
STA <TZEIL        
STA <TZEIL+1      
LDY <SPALT1       
LDA #1            
STA <BOTTOM       
BNE SUCHE         
;                 
INITS2            
LDA #0            
STA <BOTTOM       
LDA APOS          
BNE INITS3        
LDA ANFZEI        
STA <TZEIL        
LDA ANFZEI+<MXIND 
STA <TZEIL+1      
LDY <SPALT1       
JMP SUCHE         
INITS3            
LDA AZEIL         
STA <TZEIL        
LDA AZEIL+<MXIND  
STA <TZEIL+1      
LDY <ASPAL        
LDA <FMODUS       
BMI SUCHE         
;**+1, WEIL FIND  
INY               
;                 
SUCHE             
;AB TZEIL  UND    
;SPALTE Y         
;                 
LDA #0            
STA <FEHLER       
STA <FZAEHL       
STA <FZAEHL+1     
;                 
STY <YREG         
LDA <TZEIL        
LDY <TZEIL+1      
JSR TPADR         
LDY <YREG         
;                 
SUCHE0            
;TEST AUF         
;TEXTENDE:        
LDA <TZEIL+1      
CMP TXTBOT+<MXIND 
BCC SUCHE1        
LDA <TZEIL        
CMP TXTBOT        
BCC SUCHE1        
JMP SUCHEX        
SUCHE1            
LDA #1            
STA <TRENN        
LDX #0            
;                 
SUCHE2            
LDA (<TP),Y       
CMP STRNG1,X      
BNE SUCHE8        
LDA <FMASKE       
AND #2            
BEQ SUCHE3        
LDA <TRENN        
BEQ SUCHE7        
SUCHE3 STY <YREG  
SUCHE4 INX        
INY               
CPX <LAENG1       
BEQ SUCHE5        
LDA (<TP),Y       
CMP STRNG1,X      
BEQ SUCHE4        
BNE SUCHE6        
SUCHE5 LDA <FMASKE
AND #1            
BEQ SUCHEQ        
LDA (<TP),Y       
JSR UTRENN        
BEQ SUCHE6        
;                 
SUCHEQ            
JMP GEFUND        
;FALLS ALL        
;RUECKKEHR!       
;<-------         
SUCHE6            
LDY <YREG         
LDX #0            
SUCHE7            
LDA (<TP),Y       
SUCHE8            
JSR UTRENN        
CPY <SPALT2       
BEQ SUCHE9        
BCS SUCHE9        
INY               
BNE SUCHE2        
SUCHE9            
LDA <TP           
CLC               
ADC <TXTLEN       
STA <TP           
BCC *+4           
INC <TP+1         
LDY <SPALT1       
INC <TZEIL        
BNE SUCHE0        
INC <TZEIL+1      
BNE SUCHE0        
;                 
SUCHEX            
;***NICHT GEF.    
LDX <BOTTOM       
LDA #1            
STA <BOTTOM       
LDA <FMODUS       
AND #64           
BNE SUCH12        
TXA               
BEQ SUCH11        
SUCH10 LDA #139   
DFD $2C           
SUCH11            
LDA #138          
;                 
;MESSAGE SETZEN   
STA <FEHLER       
SEC               
RTS               
;                 
SUCH12            
LDA <FZAEHL       
ORA <FZAEHL+1     
BEQ SUCH10        
LDA <FMODUS       
BMI SUCH13        
LDA #2            
DFD $2C           
SUCH13            
LDA #3            
STA <CODE         
SEC               
RTS               
;                 
GEFUND            
;***GEFUNDEN!     
INC <FZAEHL       
BNE GEFUNX        
INC <FZAEHL+1     
GEFUNX LDA <FMODUS
AND #64           
BEQ GEFUN2        
;**ALL            
LDA <FMODUS       
BPL GEFUN1        
JSR UXCHNG        
BCS GEFUN0        
LDY <YREG         
BNE GEFUN1        
;IMMER NOCH AM    
;ZEILENANFANG     
;SONDERFALL, FALLS
;GESAMTES WORT    
;GELOESCHT        
JMP SUCHE1        
GEFUN0 INC <FEHLER
GEFUN1 JMP SUCHE6 
;                 
GEFUN2            
LDA #0            
STA <BOTTOM       
LDY <YREG         
STY <ASPAL        
LDA <TZEIL        
STA AZEIL         
LDA <TZEIL+1      
STA AZEIL+<MXIND  
LDA #255          
STA APOS          
STA <FNDFLG       
;VERHINDER TABU-  
;LIEREN. CURSOR   
;UND BILD SETZEN. 
JSR UMOVE         
;                 
LDA <FMODUS       
BPL GEFUN4        
JSR UXCHNG        
BCS GEFUN3        
LDA #3            
STA <CODE         
;**#### CHANGED   
SEC               
RTS               
GEFUN3 LDA #133   
;**MOVE ERROR     
DFD $2C           
GEFUN4 LDA #137   
;**FOUND          
STA <FEHLER       
SEC               
RTS               
;                 
;                 
UTRENN            
;TESTE AKKU AUF   
;TRENNZEICHEN     
CMP #"A"          
BCC TRENN1        
CMP #"Ú"+1        
BCS TRENN1        
CMP #"Á"          
BCS TRENN0        
CMP #"Z"+1        
BCS TRENN1        
TRENN0 LDA #0     
DFD $2C           
TRENN1 LDA #1     
STA <TRENN        
RTS               
;                 
RFIND             
; FIND * NEXT     
;                 
JSR UAPOS         
LDA <LAENG1       
CMP #255          
BEQ RFINDQ        
LDX #0            
LDA <BOTTOM       
BEQ RFIND1        
LDX #32           
;** FIRST, FALLS  
;** BOTTOM=1      
RFIND1 STX <FMODUS
JSR USUCHE        
JMP UNPOS         
;                 
RFINDQ            
LDA #140          
STA <FEHLER       
JMP UNPOS         
;                 
RCHNG             
;CHANGE * NEXT    
;                 
JSR UAPOS         
LDA <LAENG1       
ORA <LAENG2       
CMP #255          
BEQ RFINDQ        
LDX #128          
LDA <BOTTOM       
BEQ RCHNG1        
LDX #128+32       
;** FIRST, FALLS  
;** BOTTOM=1      
RCHNG1 STX <FMODUS
JSR USUCHE        
JMP UNPOS         
;                 
UXCHNG            
;CHANGE AUS-      
;FUEHERN          
;                 
LDY <YREG         
STY <TSPAL        
SEC               
LDA <LAENG2       
SBC <LAENG1       
BCS XCHNG1        
BEQ XCHNG2        
EOR #$FF          
TAX               
INX               
JSR UDELE         
JMP XCHNG2        
;                 
XCHNG1            
STA <LFD          
LDY <YREG         
JSR UFRE          
TXA               
CMP <LFD          
BCS *+4           
SEC               
RTS               
;PLATZ GENUG:     
LDX <LFD          
LDY <YREG         
JSR UINSE         
;                 
XCHNG2 LDY <YREG  
LDX #0            
XCHNG3            
CPX <LAENG2       
BEQ XCHNG4        
LDA STRNG2,X      
STA (<TP),Y       
INX               
INY               
BNE XCHNG3        
XCHNG4 TYA        
BEQ XCHNG5        
DEY               
XCHNG5 STY <YREG  
;ZEIGER FUER      
;WEITERSUCHEN     
CLC               
RTS