;================  
; SCREEN-EDITOR    
;(TEIL3.1  C-64)   
;                  
;17.11.1985        
;                  
ORG 36140          
;                  
;================  
;                  
;***KONSTANTEN***  
;                  
<MXCOL EQU 40      
<MXLIN EQU 25      
<ZAHL  EQU 4       
<SCRLC EQU 36      
<SCRLL EQU 0       
<MZEIL EQU 4       
<MSPAL EQU 4       
;                  
;***  Z-PAGE  ***  
;                  
<SP    EQU $FE     
<TP    EQU 2       
<IND   EQU 4       
;                  
<BASIS EQU 43      
<ENDE  EQU 45      
<TMEM  EQU 55      
;*** TABELLEN ***  
;                  
TAB    EQU $7FA0   
LAENGE EQU $7FEF   
NAME   EQU $7FF0   
;                  
;                  
;=1=               
FLAG   EQU $7F20   
APOS   EQU $7F32   
;                  
;=2=               
ZNRL   EQU $7F40   
AZEIL  EQU $7F52   
ANFZEI EQU $7F53   
TXTBOT EQU $7F54   
MASK   EQU $7F55   
BNDS   EQU $7F56   
TABU   EQU $7F57   
;                  
;=3=               
ZNRH   EQU $7F60   
;                  
<CXIND EQU $11     
<AXIND EQU $14     
<MXIND EQU $20     
;[ZNRH-ZNRL]       
;                  
;**TEXT-SPALTEN**  
;                  
<TZEIL  EQU $6     
<TSPAL  EQU $8     
<ASPAL  EQU $9     
<ANFSPA EQU $A     
<TXTLEN EQU $B     
<LBND   EQU $C     
<RBND   EQU $D     
;                  
;**BILD-ZEIGER***  
;                  
<SSPAL  EQU $E     
<SZEIL  EQU $F     
<XSPAL  EQU $10    
<XZEIL  EQU $11    
;                  
<SCLEN  EQU $12    
;                  
;**BILD-ZEILEN***  
;                  
<SCTOP  EQU $13    
<SCBOT  EQU $14    
;                  
<MSKFLG EQU $15    
<BNDFLG EQU $16    
<TABFLG EQU $17    
<COLFLG EQU $18    
<TOPFLG EQU $19    
;                  
;**HILFSREGISTER*  
;                  
<MMFLAG EQU $1A    
<XREG   EQU $1B    
<YREG   EQU $1C    
<ZAEHL  EQU $1D    
<LFD    EQU $1E    
;                  
<SCRLH  EQU $1F    
<SCRLV  EQU $20    
<SCRLM  EQU $21    
;                  
;                  
<CODE   EQU $23    
<TEFLAG EQU $24    
<FEHLER EQU $25    
<ENDFLG EQU $26    
<COMFLG EQU $27    
;                  
<FZAEHL EQU $41    
;(L/H)             
;***RECHENREG.***  
;                  
<MOR    EQU $43    
<MND    EQU $44    
<ERG    EQU $46    
;                  
<ZL     EQU $48    
<ZH     EQU $49    
<NL     EQU $4A    
<NH     EQU $4B    
<HL     EQU $4C    
<HH     EQU $4D    
;                  
;===============   
UMULTI EQU 32771   
UDIV   EQU 32808   
UZAHL  EQU 32856   
USET_  EQU 32901   
TEXT   EQU 33364   
ZEILE  EQU 33377   
UCOLOR EQU 33527   
UCSPR  EQU 33591   
UNPOS  EQU 34154   
FUNKT  EQU 34344   
;                  
;===============   
;                  
GETSCR EQU 34714   
URZAHL EQU 34751   
ULCOM  EQU 34820   
UEXLCO EQU 34898   
TPADR  EQU 35224   
;                  
;===============   
;                  
CHKIN  EQU $FFC6   
CHKOUT EQU $FFC9   
CHRIN  EQU $FFCF   
CHROUT EQU $FFD2   
CLOSE  EQU $FFC3   
CLRCHN EQU $FFCC   
LOAD   EQU $FFD5   
MEMBOT EQU $FF9C   
OPEN   EQU $FFC0   
READST EQU $FFB7   
SAVE   EQU $FFD8   
SETLFS EQU $FFBA   
SETMSG EQU $FF90   
SETNAM EQU $FFBD   
;                  
REPEAT EQU 650     
;                  
;================  
TXT5               
DFD "1.COL:",0     
TXT6               
DFD "SCROLL:",0    
TXT7 DFD "HALF",0  
TXT8 DFD "PAGE",0  
TXT9 DFD "COL=",0  
TXT10 DFD "MSK=",0 
TXT11 DFD "BND=",0 
TXT12 DFD "TAB=",0 
TXT13              
DFD "SYSTEM ERR"   
DFD "OR NR:",0     
TXT14              
DFD " TIMES FOUND" 
DFD 0              
TXT15              
DFD " CHANGED",0   
TXT16              
DFD " ERRORS",0    
;================= 
<OFFSET EQU 19     
;                  
TXTTAB             
DFD "LINE-COMM."   
DFD "IGNORED ",0   
DFD "COMMAND CO"   
DFD "NFLICT  ",0   
DFD "OUT OF MEM"   
DFD "ORY     ",0   
DFD "BLOCK TOO "   
DFD "LONG    ",0   
DFD "ILLEGAL BO"   
DFD "UNDS    ",0   
DFD "MOVE ERROR"   
DFD "        ",0   
DFD "ILLEGAL CO"   
DFD "MMAND   ",0   
DFD "ENTER A ST"   
DFD "RING!   ",0   
DFD "ILLEGAL CO"   
DFD "LUMN    ",0   
DFD "STRING FOU"   
DFD "ND      ",0   
DFD "**BOTTOM R"   
DFD "EACHED**",0   
DFD "STRING NOT"   
DFD " FOUND  ",0   
DFD "KEY IS NOT"   
DFD " ACTIVE ",0   
;                  
UWKOPF             
;KOPF SCHREIBEN    
;(OHNE FEHLER)     
;**COL:####        
;                  
LDA #[TXT5         
STA <IND           
LDA #]TXT5         
STA <IND+1         
JSR TEXT           
LDA <ANFSPA        
LDX #0             
JSR UZAHL          
STA TAB            
LDA #[TAB          
STA <IND           
LDA #]TAB          
;                  
UWTOP              
;SCHREIBT IN DIE   
;BEFEHLSZEILE BIS  
;AN DEN RECHTEN    
;RAND              
;                  
STA <IND+1         
LDY #0             
WTOP1 LDA (<IND),Y 
BEQ WTOP2          
JSR USET_          
INY                
LDX <SSPAL         
CPX #<SCRLC        
BNE WTOP1          
WTOP2 LDA #" "     
LDX <SSPAL         
CPX #<SCRLC-7      
;**PLATZ FUER      
;**"SCROLL:" ?     
BPL WTOP4          
WTOP3              
JSR USET_          
INX                
CPX #<SCRLC-7      
BNE WTOP3          
LDA #[TXT6         
STA <IND           
LDA #]TXT6         
STA <IND+1         
JMP TEXT           
;                  
WTOP4 CPX #<SCRLC  
BPL WTOP5          
JSR USET_          
INX                
BNE WTOP4          
WTOP5 RTS          
;                  
UWSCRL             
;SCROLL-BETRAG     
;SCHREIBEN         
;                  
LDA #<SCRLC        
LDX #<SCRLL        
JSR UCSPR          
LDA <SCRLM         
BNE WSCRL1         
;**HALF            
LDA #[TXT7         
STA <IND           
LDA #]TXT7         
STA <IND+1         
JSR TEXT           
LDA #<MXLIN        
LSR                
STA <SCRLV         
LDA #<MXCOL-<ZAHL  
LSR                
STA <SCRLH         
RTS                
WSCRL1 CMP #1      
BNE WSCRL2         
;**PAGE            
LDA #[TXT8         
STA <IND           
LDA #]TXT8         
STA <IND+1         
JSR TEXT           
LDA #<MXCOL-<ZAHL-1
STA <SCRLH         
LDA #<MXLIN-3      
STA <SCRLV         
RTS                
WSCRL2             
;**                
LDA <SCRLH         
LDX #0             
JSR UZAHL          
LDA <SCRLH         
STA <SCRLV         
RTS                
;                  
;                  
UCOLS              
;SCHREIBT IN DIE   
;ZEILE NUMMER X    
;SPALTENMARK.      
;                  
STX <COLFLG        
LDA #0             
JSR UCSPR          
LDA #100           
LDX #0             
STA <NL            
STX <NH            
LDA <ANFSPA        
STA <ZL            
STX <ZH            
JSR UDIV           
LDA <HL            
LDX #0             
STA <ZL            
STX <ZH            
LDA #10            
STA <NL            
STX <NH            
JSR UDIV           
LDA #[TXT9         
STA <IND           
LDA #]TXT9         
STA <IND+1         
JSR TEXT           
LDX <HL            
LDY <ZL            
COLS0 TXA          
BNE COLS1          
TYA                
CLC                
ADC #48            
BNE COLS3          
COLS1 CPX #5       
BNE COLS2          
LDA #"+"           
DFD $2C            
COLS2 LDA #"-"     
COLS3 JSR USET_    
INX                
CPX #10            
BCC COLS4          
LDX #0             
INY                
CPY #10            
BCC COLS4          
LDY #0             
COLS4              
LDA <SSPAL         
BNE COLS0          
RTS                
;                  
UMASK              
;MASKE IN DER      
;ZEILE X           
;ANZEIGEN          
;                  
STX <MSKFLG        
LDA #0             
JSR UCSPR          
LDA #[TXT10        
STA <IND           
LDA #]TXT10        
STA <IND+1         
JSR TEXT           
;                  
LDA MASK           
STA <TP            
LDA MASK+<MXIND    
STA <TP+1          
JMP ZEILE          
;                  
UBND               
;GRENZEN IN DER    
;ZEILE X           
;ANZEIGEN          
;                  
STX <BNDFLG        
LDA #0             
JSR UCSPR          
LDA #[TXT11        
STA <IND           
LDA #]TXT11        
STA <IND+1         
JSR TEXT           
;                  
LDA BNDS           
STA <TP            
LDA BNDS+<MXIND    
STA <TP+1          
JMP ZEILE          
;                  
UTAB               
;TABULATOR IN      
;ZEILE X           
;ANZEIGEN          
;                  
STX <TABFLG        
LDA #0             
JSR UCSPR          
LDA #[TXT12        
STA <IND           
LDA #]TXT12        
STA <IND+1         
JSR TEXT           
;                  
LDA TABU           
STA <TP            
LDA TABU+<MXIND    
STA <TP+1          
JMP ZEILE          
;                  
UTOP               
;KOPF SCHREIBEN    
;INCL. DER         
;STATUS-ZEILEN     
;CODE+FEHLER       
;BEACHTEN          
;                  
LDA #0             
TAX                
JSR UCSPR          
LDA <CODE          
CMP #255           
BNE ERROR1         
;**SYSERR #...     
LDA #[TXT13        
STA <IND           
LDA #]TXT13        
STA <IND+1         
JSR TEXT           
LDA <FEHLER        
CLC                
ADC #48            
STA TAB            
LDA #0             
STA TAB+1          
BEQ ERROR11        
;                  
ERROR1             
CMP #1             
BNE ERROR2         
;**DISK STATUS     
;**IN TAB ANZEIGEN 
ERROR11            
LDA #[TAB          
STA <IND           
LDA #]TAB          
JMP TOP5           
;                  
ERROR2             
CMP #2             
BNE ERROR3         
;** #### FOUND     
LDA <FZAEHL        
LDX <FZAEHL+1      
JSR UZAHL          
LDA #[TXT14        
STA <IND           
LDA #]TXT14        
JMP TOP5           
;                  
ERROR3             
CMP #3             
BNE TOPOK          
;*** #### ERRORS   
LDA <FEHLER        
BEQ ERROR4         
LDA <FZAEHL        
LDX <FZAEHL+1      
JSR UZAHL          
LDA #"/"           
JSR USET_          
LDA <FEHLER        
LDX #0             
JSR UZAHL          
LDA #[TXT16        
STA <IND           
LDA #]TXT16        
JMP TOP5           
;                  
ERROR4             
;** CHANGED        
LDA <FZAEHL        
LDX <FZAEHL+1      
JSR UZAHL          
LDA #[TXT15        
STA <IND           
LDA #]TXT15        
JMP TOP5           
;                  
TOPOK              
LDA <FEHLER        
BNE TOP1           
JSR UWKOPF         
JMP TOP6           
TOP1 BMI TOP2      
LDA #0             
TOP2               
;TEXT AUS TXTTAB   
;ANZEIGEN          
AND #127           
STA <MND           
LDA #0             
STA <MND+1         
LDA #<OFFSET       
STA <MOR           
JSR UMULTI         
CLC                
LDA #[TXTTAB       
ADC <ERG           
STA <IND           
LDA #]TXTTAB       
ADC <ERG+1         
;                  
TOP5 JSR UWTOP     
;                  
TOP6 JSR UWSCRL    
LDX #1             
STX <SCTOP         
LDA <MSKFLG        
BEQ TOP7           
JSR UMASK          
LDX <SCTOP         
INX                
STX <SCTOP         
TOP7 LDA <BNDFLG   
BEQ TOP8           
JSR UBND           
LDX <SCTOP         
INX                
STX <SCTOP         
TOP8 LDA <TABFLG   
BEQ TOP9           
JSR UTAB           
LDX <SCTOP         
INX                
STX <SCTOP         
TOP9 LDA <COLFLG   
BEQ TOP10          
JSR UCOLS          
LDX <SCTOP         
INX                
STX <SCTOP         
TOP10 RTS          
;                  
URSCRL             
;SCROLL LESEN      
;                  
LDA #<SCRLC        
LDX #<SCRLL        
JSR UCSPR          
LDY <SSPAL         
JSR GETSCR         
CMP #"H"           
BNE URSCR1         
LDA #0             
STA <SCRLM         
RTS                
URSCR1             
CMP #"P"           
BNE URSCR2         
LDA #1             
STA <SCRLM         
RTS                
URSCR2 LDX #0      
URSCR3 STA TAB,X   
INX                
INY                
CPY #<MXCOL        
BCS URSCR4         
JSR GETSCR         
JMP URSCR3         
URSCR4 LDA #0      
STA TAB,X          
LDX #0             
JSR URZAHL         
LDA <ERG+1         
BEQ URSCR5         
LDA #127           
BNE URSCR6         
URSCR5 LDA <ERG    
URSCR6 AND #127    
STA <SCRLH         
LDA #2             
STA <SCRLM         
RTS                
;                  
URBND              
;BNDS LESEN        
;C=1 => FEHLER     
;                  
LDA <BNDFLG        
BEQ RBND5          
LDY <TXTLEN        
LDA BNDS           
STA <TP            
LDA BNDS+<MXIND    
STA <TP+1          
;                  
RBND1 CPY #0       
BEQ RBND9          
DEY                
LDA (<TP),Y        
CMP #" "           
BEQ RBND1          
CMP #">"           
BNE RBND9          
TYA                
TAX                
INX                
;                  
RBND2 CPY #0       
BEQ RBND9          
DEY                
LDA (<TP),Y        
CMP #" "           
BEQ RBND2          
CMP #"<"           
BNE RBND9          
;                  
STY <YREG          
RBND3 CPY #0       
BEQ RBND4          
DEY                
LDA (<TP),Y        
CMP #" "           
BEQ RBND3          
BNE RBND9          
RBND4 LDY <YREG    
STY <LBND          
STX <RBND          
RBND5 CLC          
RTS                
;                  
RBND9 LDA #132     
STA <FEHLER        
SEC                
RTS                
;                  
URTAB              
;TABS LESEN        
;                  
LDA <TABFLG        
BEQ RTAB3          
LDY <TXTLEN        
LDA TABU           
STA <TP            
LDA TABU+<MXIND    
STA <TP+1          
;                  
RTAB1 CPY #0       
BEQ RTAB3          
DEY                
LDA (<TP),Y        
CMP #" "           
BEQ RTAB2          
LDA #"-"           
RTAB2 STA (<TP),Y  
JMP RTAB1          
RTAB3 RTS          
;                  
UINITP             
;STATUS-ZEILEN     
;HERSTELLEN        
;(NEUES DATASET)   
;                  
JSR UBLANK         
LDA <LFD           
JSR PLUSA          
JSR UBLANK         
LDA #"<"           
STA (<IND),Y       
LDA #">"           
LDY <LFD           
DEY                
STA (<IND),Y       
LDA <LFD           
JSR PLUSA          
;                  
UBLANK             
;ZEILE MIT " "     
;FUELLEN (<IND)    
;                  
LDY <LFD           
LDA #" "           
BLANK1 CPY #0      
BEQ BLANK2         
DEY                
STA (<IND),Y       
BNE BLANK1         
BLANK2 RTS         
;================= 
;EINTRITTSPUNKTE:  
;MAIN^ UND MAIN2   
;CLC FALLS OK      
;================= 
QUIT SEC           
RTS                
;                  
MAIN^              
;AUFRUF NEUER NAME 
;X=LAENGE IN TAB   
;                  
CPX #0             
BEQ QUIT           
CPX #17            
BCS QUIT           
STX LAENGE         
MAIN0              
LDA TAB,X          
STA NAME,X         
DEX                
BPL MAIN0          
LDA #0             
LDX LAENGE         
JSR ULOAD          
BCC MAIN2          
LDA TAB            
CMP #"6"           
BNE QUIT           
LDA TAB+1          
CMP #"2"           
BNE QUIT           
;*FILE NOT FOUND   
;*NEUES DATASET    
;*                 
JSR UDISKI         
;*BLINKEN AUS!     
MAIN1 LDA #[MSG2   
LDY #]MSG2         
JSR ZINPUT         
BCS QUIT           
BEQ MAIN1          
CPY #0             
BNE MAIN1          
CMP #81            
BCS MAIN1          
STA <LFD           
;MIT SATZLAENGE    
;INITIALISIEREN:   
;                  
SEC                
JSR MEMBOT         
STX <IND           
STY <IND+1         
LDY #0             
LDA <LFD           
STA (<IND),Y       
INY                
LDA #0             
STA (<IND),Y       
INY                
STA (<IND),Y       
LDA #5             
JSR PLUSA          
JSR UINITP         
MAIN2              
;AUFRUF ALTER NAME 
;NAME,LAENGE SIND  
;GUELTIG           
SEC                
JSR MEMBOT         
STX <IND           
STY <IND+1         
LDY #0             
LDA (<IND),Y       
STA <TXTLEN        
INY                
LDA (<IND),Y       
STA TXTBOT         
INY                
LDA (<IND),Y       
STA TXTBOT+<MXIND  
LDA <IND           
LDX <IND+1         
CLC                
ADC #5             
BCC MAIN5          
INX                
MAIN5              
STA MASK           
STX MASK+<MXIND    
JSR PLUS           
STA BNDS           
STX BNDS+<MXIND    
JSR PLUS           
STA TABU           
STX TABU+<MXIND    
JSR PLUS           
STA <BASIS         
STX <BASIS+1       
LDA TXTBOT         
LDY TXTBOT+<MXIND  
JSR TPADR          
LDA <TP            
STA <ENDE          
LDA <TP+1          
STA <ENDE+1        
LDA #0             
STA ANFZEI         
STA ANFZEI+<MXIND  
STA <ANFSPA        
;============      
;SPRUNG  NACH      
;***UPROF ***      
;============      
NOP                
NOP                
NOP                
JSR URBND          
JSR URTAB          
;***URESET***      
;***UTEXT ***      
NOP                
NOP                
NOP                
NOP                
NOP                
NOP                
LDA #255           
STA FLAG+$13       
STA FLAG+$14       
LDA #0             
STA <ENDFLG        
STA <XZEIL         
STA <XSPAL         
STA APOS           
STA <SCRLM         
STA <FEHLER        
STA <CODE          
JSR UCOLOR         
JSR UNPOS          
MAIN6 JSR FUNKT    
LDA <ENDFLG        
BEQ MAIN6          
JSR UWHEAD         
CLC                
RTS                
;                  
UWHEAD             
;TEXT- UND SATZ-   
;LAENGE ANFUEGEN   
SEC                
JSR MEMBOT         
STX <SP            
STY <SP+1          
LDY #2             
LDA TXTBOT+<MXIND  
STA (<SP),Y        
DEY                
LDA TXTBOT         
STA (<SP),Y        
DEY                
LDA <TXTLEN        
STA (<SP),Y        
RTS                
;                  
PLUS               
CLC                
ADC <TXTLEN        
BCC PLUS1          
INX                
PLUS1 RTS          
;                  
PLUSA              
CLC                
ADC <IND           
STA <IND           
BCC PLUSA1         
INC <IND+1         
PLUSA1 RTS         
;                  
U1                 
;LFD BILDSCHIRM    
;AUSWERTEN         
;BIS FEHLER        
;                  
JSR ULCOM          
JSR URTAB          
JSR URSCRL         
;===========       
;SPRUNG NACH       
;***UPRIM***       
;===========       
NOP                
NOP                
NOP                
LDA <FEHLER        
BNE U11            
JSR URBND          
BCS U11            
JSR UEXLCO         
U11 RTS            
;                  
;===============   
;                  
UDISKI             
;SENDET "I0"       
;                  
LDX #2             
LDA #"I"           
STA TAB            
LDA #"0"           
STA TAB+1          
;                  
UDISKC             
;SENDET BEFEHL     
;IN TAB AN DISK.   
;[BIS X]           
;                  
STX <ZAEHL         
LDA #15            
JSR CLOSE          
LDA <ZAEHL         
LDX #[TAB          
LDY #]TAB          
JSR SETNAM         
LDA #15            
LDX #8             
LDY #15            
JSR SETLFS         
JSR OPEN           
BCS SYSERR         
;                  
UDISKS             
;LIEST DISKSTATUS  
;=>TAB [BIS X]     
;KANAL #15 MUSS    
;SCHON GEOEFFNET   
;SEIN              
;C=1 =>FEHLER      
;                  
LDX #15            
JSR CHKIN          
BCS SYSERR         
LDX #0             
DISKS1             
JSR CHRIN          
BCS SYSERR         
CMP #13;   CR      
BEQ DISKS2         
STA TAB,X          
INX                
CPX #<SCRLC        
BNE DISKS1         
BEQ DISKS3         
DISKS2             
LDA #" "           
STA TAB,X          
INX                
CPX #<SCRLC        
BNE DISKS2         
DISKS3             
LDA #0             
STA TAB,X          
STX <ZAEHL         
JSR CLRCHN         
LDX <ZAEHL         
LDA TAB            
CMP #"2"           
RTS                
;**C=1,FALLS**     
;**NUMMER>19**     
;                  
SYSERR             
STA <FEHLER        
LDA #255           
STA <CODE          
JSR CLRCHN         
SEC                
RTS                
;                  
USAVE              
;SPEICHERT LFD.    
;DATASET MIT       
;NAMEN IN "NAME"   
;                  
;ZUERST I0 UND     
;S0:NAME           
;                  
JSR UDISKI         
BCS USAVE9         
LDX LAENGE         
USAVE1 LDA NAME,X  
STA TAB+3,X        
DEX                
BPL USAVE1         
LDA #"S"           
STA TAB            
LDA #"0"           
STA TAB+1          
LDA #":"           
STA TAB+2          
LDX LAENGE         
INX                
INX                
INX                
JSR UDISKC         
BCS USAVE9         
LDA LAENGE         
LDX #[NAME         
LDY #]NAME         
JSR SETNAM         
LDA #0             
LDX #8             
LDY #0             
JSR SETLFS         
JSR UWHEAD         
LDA #<SP           
LDX <ENDE          
LDY <ENDE+1        
JSR SAVE           
BCS USAVE9         
JSR UDISKS         
BCS USAVE9         
LDA #1             
;**VERIFY          
LDX LAENGE         
JSR ULOAD          
BCS USAVE9         
LDA <LFD;**STATUS  
AND #$10           
BEQ USAVE2         
JMP USAVE          
USAVE2 CLC         
RTS                
USAVE9             
LDA <CODE          
ORA #1             
STA <CODE          
SEC                
RTS                
;                  
ULOAD              
;DATASET LESEN     
;NAME IN "NAME"    
;X   =>LAENGE      
;LFD =>STATUS      
;                  
STA <LFD           
STX <XREG          
JSR UDISKI         
;**INITIALIZE      
BCS USAVE9         
LDA <XREG          
LDX #[NAME         
LDY #]NAME         
JSR SETNAM         
LDA #0             
LDX #8             
LDY #0             
JSR SETLFS         
SEC                
JSR MEMBOT         
LDA <LFD           
JSR LOAD           
JSR READST         
STA <LFD           
JSR UDISKS         
RTS                
;                  
MSG2               
DFD 147,13,13      
DFD "THIS IS A "   
DFD "NEW’ DATA"   
DFD "SET!",13,13   
DFD "ENTER RECO"   
DFD "RD LENGTH:"   
DFD 13,13          
DFD "[RANGE:1.."   
DFD "80]",13       
DFD "['*' OR '?"   
DFD "' FOR END]"   
DFD 13,13          
DFD "==>",0        
;                  
UINPUT             
;PROMPT-MELDUNG    
;AUSGEBEN          
;EINGABE NACH      
;TAB (0...)        
;X =>LAENGE        
;0 AM ENDE         
;C=1 => "*/?"      
;                  
STA <IND           
STY <IND+1         
LDY #0             
INPUT1             
LDA (<IND),Y       
BEQ INPUT2         
JSR CHROUT         
INY                
BNE INPUT1         
INPUT2             
LDX #0             
INPUT3             
JSR CHRIN          
CMP #13;   CR      
BEQ INPUT5         
CMP #"*"           
BEQ INPUT4         
CMP #"?"           
BEQ INPUT4         
STA TAB,X          
INX                
BNE INPUT3         
INPUT4 SEC         
RTS                
INPUT5 CLC         
LDA #0             
STA TAB,X          
RTS                
;                  
ZINPUT             
;WIE INPUT         
;EINGABE ALS       
;ZAHL NACH         
;A/Y (L/H)         
;C=1 =>"*/?"       
;                  
JSR UINPUT         
BCS ZINPT1         
LDX #0             
JSR URZAHL         
LDY <ERG+1         
LDA <ERG           
CLC                
ZINPT1 RTS