;================ 
; SCREEN-EDITOR   
; (TEIL 2 C-64)   
;                 
;14.6.1985        
;                 
ORG 34666         
;                 
;================ 
;                 
;***KONSTANTEN*** 
;                 
<MXCOL EQU 40     
<MXLIN EQU 25     
<ZAHL  EQU 4      
<SCRLC EQU 36     
<SCRLL EQU 0      
<MZEIL EQU 4      
<MSPAL EQU 4      
;                 
;***  Z-PAGE  *** 
;                 
<SP    EQU $FE    
<TP    EQU 2      
<IND   EQU 4      
;                 
<BASIS EQU 43     
<ENDE  EQU 45     
<TMEM  EQU 55     
;*** TABELLEN *** 
;                 
TAB    EQU $7FA0  
;                 
;=1=              
FLAG   EQU $7F20  
APOS   EQU $7F32  
;                 
;=2=              
ZNRL   EQU $7F40  
AZEIL  EQU $7F52  
ANFZEI EQU $7F53  
TXTBOT EQU $7F54  
MASK   EQU $7F55  
BNDS   EQU $7F56  
TABU   EQU $7F57  
;                 
;=3=              
ZNRH   EQU $7F60  
;                 
<CXIND EQU $11    
<AXIND EQU $14    
<MXIND EQU $20    
;[ZNRH-ZNRL]      
;                 
;**TEXT-SPALTEN** 
;                 
<TZEIL  EQU $6    
<TSPAL  EQU $8    
<ASPAL  EQU $9    
<ANFSPA EQU $A    
<TXTLEN EQU $B    
<LBND   EQU $C    
<RBND   EQU $D    
;                 
;**BILD-ZEIGER*** 
;                 
<SSPAL  EQU $E    
<SZEIL  EQU $F    
<XSPAL  EQU $10   
<XZEIL  EQU $11   
;                 
<SCLEN  EQU $12   
;                 
;**BILD-ZEILEN*** 
;                 
<SCTOP  EQU $13   
<SCBOT  EQU $14   
;                 
<MSKFLG EQU $15   
<BNDFLG EQU $16   
<TABFLG EQU $17   
<COLFLG EQU $18   
<TOPFLG EQU $19   
;                 
;**HILFSREGISTER* 
;                 
<MMFLAG EQU $1A   
<XREG   EQU $1B   
<YREG   EQU $1C   
<ZAEHL  EQU $1D   
<LFD    EQU $1E   
;                 
<SCRLH  EQU $1F   
<SCRLV  EQU $20   
<SCRLM  EQU $21   
;                 
<CODE   EQU $23   
<TEFLAG EQU $24   
<FEHLER EQU $25   
<ENDFLG EQU $26   
<COMFLG EQU $27   
;***RECHENREG.*** 
;                 
<MOR    EQU $43   
<MND    EQU $44   
<ERG    EQU $46   
;                 
<ZL     EQU $48   
<ZH     EQU $49   
<NL     EQU $4A   
<NH     EQU $4B   
<HL     EQU $4C   
<HH     EQU $4D   
;                 
;===============  
;                 
GETIN  EQU $FFE4  
;                 
;===============  
;**BLOCK-MOVE**   
BLOCK  EQU $A3BF  
;                 
<ABANF EQU $5F    
<ABEND EQU $5A    
<NBEND EQU $58    
;                 
;===============  
UMULTI EQU 32771  
USADR  EQU 32925  
UNEXT  EQU 32999  
UTZEIL EQU 33073  
UDELE  EQU 33121  
UINSE  EQU 33151  
UFRE   EQU 33185  
CODE   EQU 34654  
;===============  
;                 
UREAD             
;ZEILENBEFEHL     
;FUER ZEILE X     
;LESEN            
;                 
STX <SZEIL        
JSR USADR         
LDX #0            
LDY #0            
READ1             
JSR GETSCR        
CMP #" "          
BNE READ2         
TXA               
BNE READ5         
BEQ READ4         
READ2             
CMP #"9"+1        
BCS READ3         
CMP #"0"          
BCC READ3         
CPX #0            
BEQ READ4         
READ3             
STA TAB,X         
INX               
READ4             
INY               
CPY #<ZAHL        
BNE READ1         
READ5 LDA #0      
STA TAB,X         
RTS               
;                 
;                 
GETSCR            
;HOLT LFD.        
;IN ASCII VOM     
;SCHIRM           
;                 
LDA (<SP),Y       
STA <LFD          
AND #$3F          
ASL <LFD          
BIT <LFD          
BPL GET1          
ORA #$80          
GET1              
BVS GET2          
ORA #$40          
GET2 RTS          
;                 
UZAHLX            
;ZAHL AB TAB,X    
;LESEN:           
;AKKU <= 1..127   
;                 
JSR URZAHL        
LDA <ERG+1        
BNE ZAHLX1        
LDA <ERG          
BPL ZAHLX2        
ZAHLX1 LDA #127   
ZAHLX2            
BNE ZAHLX3        
LDA #1            
ZAHLX3 RTS        
;                 
;                 
URZAHL            
;ZAHL LESEN       
;AB TAB,X         
;   =>ERG         
;                 
STX <ZAEHL        
LDA #0            
STA <ERG          
STA <ERG+1        
LDA TAB,X         
SEC               
SBC #48           
BCC RZAHL2        
CMP #10           
BCS RZAHL2        
STA <ERG          
RZAHL1 INC <ZAEHL 
LDX <ZAEHL        
SEC               
LDA TAB,X         
SBC #48           
BCC RZAHL2        
CMP #10           
BCS RZAHL2        
STA <LFD          
LDA #10           
STA <MOR          
LDA <ERG          
STA <MND          
LDA <ERG+1        
STA <MND+1        
JSR UMULTI        
LDA <ERG          
CLC               
ADC <LFD          
STA <ERG          
BCC RZAHL1        
INC <ERG+1        
BNE RZAHL1        
RZAHL2            
RTS               
;                 
;                 
ULCOM             
;ALLE ZEILEN-     
;BEFEHLE LESEN    
;UND IN TABELLE   
;EINTRAGEN        
;C=1=>BEFEHLE     
;     UEBERLESEN  
;                 
LDX <TOPFLG       
BEQ LCOM2         
JSR UREAD         
LDA TAB           
BEQ LCOM2         
CMP #"I"          
BEQ LCOM1         
JSR IGNOR         
JMP LCOM2         
LCOM1 LDA #255    
STA <TZEIL        
STA <TZEIL+1      
LDX #9            
JSR UCOMX         
LCOM2 LDX <SCTOP  
LCOM3 JSR UREAD   
TXA               
BEQ LCOM6         
JSR UTZEIL        
LDX #11           
LDA TAB           
LCOM4 CMP CODE,X  
BEQ LCOM5         
DEX               
BPL LCOM4         
BMI LCOM6         
LCOM5             
JSR UCOMX         
LCOM6             
LDX <SZEIL        
INX               
CPX #<MXLIN       
BCS LCOM7         
CPX <SCBOT        
BCC LCOM3         
LCOM7 LDA <FEHLER 
CMP #0            
RTS               
;                 
;                 
;                 
UEXLCO            
;ZEILENBEFEHLE    
;AUSFUEHREN BIS   
;C=1 =>FEHLER     
;                 
JSR QKLZU         
BCS LCOM9         
JSR QKLAUF        
BCS LCOM9         
JSR QGR           
BCS LCOM9         
JSR QKL           
BCS LCOM9         
JSR QD            
BCS LCOM9         
JSR QR            
BCS LCOM9         
JSR QM            
BCS LCOM9         
JSR QI            
LCOM9 RTS         
;                 
;                 
UCOMX             
;BEARBEITET CODE  
;# X IN TZEIL     
;                 
CPX #7            
BCS COMX1         
;**DD..OO**       
TXA               
ASL               
TAX               
LDA #0            
JMP QF            
COMX1             
BNE COMX2         
;**M(M)**         
LDA #1            
COMXM STA <MMFLAG 
LDX #14           
LDA FLAG,X        
ORA FLAG+1,X      
BEQ COMXM1        
AND #127          
CMP <MMFLAG       
BEQ COMXM1        
JMP IGNOR         
COMXM1 LDA <MMFLAG
JMP QF            
;                 
COMX2             
CPX #9            
BCS COMX3         
;**C(C)**         
LDA #2            
BNE COMXM         
;                 
COMX3             
BNE COMX4         
;**I **           
LDX #16           
LDA FLAG,X        
BEQ *+5           
JMP IGNOR         
LDX #1            
JSR UZAHLX        
TAY               
LDA <TZEIL        
AND <TZEIL+1      
CMP #255          
BNE COMX31        
TYA               
ORA #128          
TAY               
COMX31 TYA        
LDX #16           
JMP MERKE         
COMX4             
CPX #10           
BNE COMX5         
;**A **           
LDX #17           
LDA FLAG,X        
BEQ *+5           
JMP IGNOR         
LDA #1            
JMP MERKE         
COMX5             
;**B **           
LDX #17           
LDA FLAG,X        
BEQ *+5           
JMP IGNOR         
LDA #2            
JMP MERKE         
;                 
QF                
;MERKT DIE        
;BLOCK-BEFEHLE    
;(DD...OO)        
;X=>INDEX FUER    
;   FLAG / ZNR    
;A=0 =>ZAHL MERKEN
;A>0 =>AKKU MERKEN
STA <MMFLAG       
STX <XREG         
LDA TAB+1         
CMP TAB           
BEQ QFF           
;** F **          
QF1               
LDA FLAG,X        
ORA FLAG+1,X      
BNE IGNOR         
LDX #1            
JSR UZAHLX        
TAY               
LDA <MMFLAG       
BEQ QF2           
TAY               
QF2 TYA           
LDX <XREG         
JSR MERKE         
INX               
TYA               
JMP MERKE         
;                 
QFF               
;** FF **         
LDA FLAG,X        
BEQ QFF1          
LDA FLAG+1,X      
BNE IGNOR         
QFF1 LDX #2       
JSR UZAHLX        
TAY               
LDA <MMFLAG       
BEQ QFF2          
TAY               
QFF2 LDX <XREG    
LDA FLAG,X        
BEQ QFF3          
INX               
QFF3 TYA          
ORA #128          
;                 
MERKE             
STA FLAG,X        
LDA <TZEIL        
STA ZNRL,X        
LDA <TZEIL+1      
STA ZNRH,X        
RTS               
;                 
IGNOR             
;                 
INC <FEHLER       
RTS               
;                 
;                 
UTNEXT            
;<TP + TXTLEN     
;                 
CLC               
LDA <TP           
ADC <TXTLEN       
STA <TP           
BCC TNEXT1        
INC <TP+1         
TNEXT1 RTS        
;                 
UINEXT            
;<IND + TXTLEN    
;                 
CLC               
LDA <IND          
ADC <TXTLEN       
STA <IND          
BCC INEXT1        
INC <IND+1        
INEXT1 RTS        
;                 
UDIFF             
;ZAEHL*TXTLEN     
; => ERG          
;                 
LDA <ZAEHL        
STA <MND          
LDA <TXTLEN       
STA <MOR          
LDA #0            
STA <MND+1        
JMP UMULTI        
;                 
UTADR             
;ADR.[A/Y]=> ERG  
;                 
STA <MND          
STY <MND+1        
LDA <TXTLEN       
STA <MOR          
JSR UMULTI        
CLC               
LDA <ERG          
ADC <BASIS        
STA <ERG          
LDA <ERG+1        
ADC <BASIS+1      
STA <ERG+1        
RTS               
;                 
INDADR            
;ADRESSE[A/Y]     
;=> <IND          
;                 
JSR UTADR         
LDA <ERG          
STA <IND          
LDA <ERG+1        
STA <IND+1        
RTS               
;                 
TPADR             
;ADRESSE[A/Y]     
;=> <TP           
;                 
JSR UTADR         
LDA <ERG          
STA <TP           
LDA <ERG+1        
STA <TP+1         
RTS               
;                 
UINSA             
;X ZEILEN NACH    
;[A/Y] EINFUEGEN  
;C=1 =>KEIN PLATZ 
;[FEHLER#2]       
;                 
CLC               
ADC #1            
BCC UINSB         
INY               
;                 
UINSB             
;DSGL. VOR [A/Y]  
;                 
STX <ZAEHL        
STA <TZEIL        
STY <TZEIL+1      
JSR UTADR         
LDA <ERG          
STA <ABANF        
LDA <ERG+1        
STA <ABANF+1      
LDA <ENDE         
STA <ABEND        
LDA <ENDE+1       
STA <ABEND+1      
JSR UDIFF         
CLC               
LDA <ENDE         
ADC <ERG          
TAX               
LDA <ENDE+1       
ADC <ERG+1        
BCS EINF9         
CMP <TMEM+1       
BCC EINF2         
BNE EINF9         
CPX <TMEM         
BCS EINF9         
EINF2             
STX <ENDE         
STA <ENDE+1       
STX <NBEND        
STA <NBEND+1      
LDX #<AXIND       
EINF4 LDA FLAG,X  
BEQ EINF6         
LDA ZNRH,X        
CMP <TZEIL+1      
BCC EINF6         
BNE EINF5         
LDA ZNRL,X        
CMP <TZEIL        
BCC EINF6         
EINF5 LDA ZNRL,X  
CLC               
ADC <ZAEHL        
STA ZNRL,X        
BCC EINF6         
INC ZNRH,X        
EINF6 DEX         
BPL EINF4         
JSR BLOCK         
CLC               
RTS               
;                 
;**OUT OF MEMORY  
;                 
EINF9 LDA #130    
STA <FEHLER       
SEC               
RTS               
;                 
ULOE              
;X ZEILEN         
;LOESCHEN         
;A/Y = 1. ZEILE   
;                 
STX <ZAEHL        
STA <TZEIL        
STY <TZEIL+1      
JSR TPADR         
JSR UDIFF         
CLC               
LDA <TP           
ADC <ERG          
STA <IND          
LDA <TP+1         
ADC <ERG+1        
STA <IND+1        
SEC               
LDA <ENDE         
SBC <ERG          
STA <ENDE         
LDA <ENDE+1       
SBC <ERG+1        
STA <ENDE+1       
LOE2 JSR UCOPY    
JSR UINEXT        
JSR UTNEXT        
LDA <TP+1         
CMP <ENDE+1       
BCC LOE2          
LDA <TP           
CMP <ENDE         
BCC LOE2          
LDX #<AXIND       
LOE3 LDA FLAG,X   
BEQ LOE7          
SEC               
LDA ZNRL,X        
SBC <TZEIL        
TAY               
LDA ZNRH,X        
SBC <TZEIL+1      
BCC LOE7          
BNE LOE4          
TYA               
CMP <ZAEHL        
BCC LOE6          
LOE4 LDA ZNRL,X   
SBC <ZAEHL        
STA ZNRL,X        
BCS LOE5          
DEC ZNRH,X        
LOE5 JMP LOE7     
LOE6 LDA <TZEIL   
STA ZNRL,X        
LDA <TZEIL+1      
STA ZNRH,X        
LOE7 DEX          
BPL LOE3          
RTS               
;                 
UFILL             
;X ZEILEN MIT     
;ZEILE [<IND]     
;FUELLEN          
;1.ZEILE = A/Y    
;[GESAMTE ZEILE]  
;                 
STX <ZAEHL        
JSR TPADR         
LDX <ZAEHL        
BEQ FILL2         
FILL1             
JSR UCOPY         
JSR UTNEXT        
DEX               
BNE FILL1         
;                 
FILL2 RTS         
;                 
UTRANS            
;X ZEILEN VON     
;<IND NACH A/Y    
;KOPIEREN         
;[GESAMTE ZEILE]  
;                 
STX <ZAEHL        
JSR TPADR         
LDX <ZAEHL        
BEQ TRANS2        
TRANS1 JSR UCOPY  
JSR UTNEXT        
JSR UINEXT        
DEX               
BNE TRANS1        
TRANS2 RTS        
;                 
;                 
UOVER             
;ZEILE  VON       
;<IND NACH A/Y    
;MIT OVERLAY      
;KOPIEREN         
;**VON LBND**     
;**BIS RBND**     
;                 
LDY <RBND         
OVER3             
DEY               
CPY <LBND         
BEQ OVER4         
LDA (<TP),Y       
CMP #32;   SPACE  
BNE OVER3         
LDA (<IND),Y      
STA (<TP),Y       
JMP OVER3         
OVER4             
LDA (<TP),Y       
CMP #32;   SPACE  
BNE OVER5         
LDA (<IND),Y      
STA (<TP),Y       
OVER5 RTS         
;                 
UCOPY             
;KOPIERT EINE     
;ZEILE VON        
;<IND NACH <TP    
;                 
LDY <TXTLEN       
BEQ COPY9         
DEY               
COPY1 LDA (<IND),Y
STA (<TP),Y       
DEY               
BNE COPY1         
LDA (<IND),Y      
STA (<TP),Y       
COPY9 RTS         
;                 
OFFSET            
;                 
;A <= DIFFERENZ   
;PARAMETER ORDNEN 
;                 
;===============  
;FALLS WENIGER    
;ALS 2 PARAMETER  
;ODER DIFF. >255  
;PLA/PLA          
;===============  
LDA FLAG,X        
BEQ OFF9          
LDA FLAG+1,X      
BEQ OFF9          
;                 
LDA ZNRH+1,X      
CMP ZNRH,X        
BCC OFF1          
BNE OFF2          
LDA ZNRL+1,X      
CMP ZNRL,X        
BCS OFF2          
OFF1              
;**TAUSCH**       
LDA ZNRH+1,X      
TAY               
LDA ZNRH,X        
STA ZNRH+1,X      
TYA               
STA ZNRH,X        
;                 
LDA ZNRL+1,X      
TAY               
LDA ZNRL,X        
STA ZNRL+1,X      
TYA               
STA ZNRL,X        
OFF2 SEC          
LDA ZNRL+1,X      
SBC ZNRL,X        
TAY               
LDA ZNRH+1,X      
SBC ZNRH,X        
BNE OFF8          
TYA               
CMP #255          
BCS OFF8          
RTS               
;                 
;**BLOCK TOO LONG 
;                 
OFF8 LDA #131     
STA <FEHLER       
PLA               
PLA               
SEC               
RTS               
;                 
OFF9 PLA          
PLA               
CLC               
RTS               
;                 
UN                
;HOLT N           
;(BEI RR...)      
LDA FLAG+1,X      
AND #127          
CMP #1            
BNE UN1           
LDA FLAG,X        
AND #127          
UN1 RTS           
;                 
QI                
;                 
LDX #16           
LDA FLAG,X        
BEQ QXX           
BPL QI1           
AND #127          
STA <ZAEHL        
TAX               
LDA #0            
TAY               
JSR UINSB         
BCS ERR           
BCC QI2           
QI1 STA <ZAEHL    
LDA ZNRL+16       
LDY ZNRH+16       
LDX <ZAEHL        
JSR UINSA         
BCS ERR           
QI2 LDA MASK      
STA <IND          
LDA MASK+<MXIND   
STA <IND+1        
LDA #0            
STA FLAG+16       
LDA <TZEIL        
LDY <TZEIL+1      
LDX <ZAEHL        
JSR UFILL         
;                 
QXX CLC           
RTS               
;                 
QD                
;                 
LDX #0            
JSR OFFSET        
STA <LFD          
LDA ZNRL          
LDY ZNRH          
LDX <LFD          
INX               
JSR ULOE          
LDX #0            
JMP QEND          
;                 
QR                
;                 
LDX #2            
JSR OFFSET        
STA <LFD          
INC <LFD          
JSR UN            
STA <YREG         
QR1 LDA ZNRL+2    
LDY ZNRH+2        
LDX <LFD          
JSR UINSB         
BCS ERR           
DEC <YREG         
BNE QR1           
LDX #2            
JMP QEND          
;                 
ERR SEC           
RTS               
;                 
QM                
LDX #14           
JSR OFFSET        
STA <LFD          
LDA FLAG+12       
BEQ QM4           
LDA FLAG+13       
BEQ QM4           
;** CC O **       
LDX #12           
JSR OFFSET        
STA <YREG         
INC <YREG         
INC <LFD          
LDA ZNRL+12       
LDY ZNRH+12       
JSR TPADR         
QO1               
LDA ZNRL+14       
LDY ZNRH+14       
JSR INDADR        
LDX <LFD          
QO2 JSR UOVER     
DEC <YREG         
BEQ QMQ           
JSR UTNEXT        
JSR UINEXT        
DEX               
BNE QO2           
BEQ QO1           
;                 
QM4               
LDA FLAG+17       
BEQ QM9           
SEC               
LDA ZNRL+17       
SBC ZNRL+14       
TAY               
LDA ZNRH+17       
SBC ZNRH+14       
BNE QM5           
CPY <LFD          
BCS QM5           
;*CONFLICT        
LDA #129          
STA <FEHLER       
ERR2 SEC          
RTS               
;                 
QM5 LDA FLAG+17   
CMP #2            
LDA ZNRL+17       
LDY ZNRH+17       
LDX <LFD          
INX               
BCS QM6           
;**CC A**         
JSR UINSA         
JMP QM7           
;**CC B**         
QM6 JSR UINSB     
QM7 BCS ERR2      
LDA ZNRL+14       
LDY ZNRH+14       
JSR INDADR        
LDA <TZEIL        
LDY <TZEIL+1      
INC <LFD          
LDX <LFD          
JSR UTRANS        
QMQ               
;                 
;TEST AUF MOVE    
;                 
LDA FLAG+14       
AND #127          
CMP #2            
BCS QM8           
;**LOESCHEN**     
LDA ZNRL+14       
LDY ZNRH+14       
LDX <LFD          
JSR ULOE          
QM8               
;                 
LDA #0            
STA FLAG+12       
STA FLAG+13       
STA FLAG+14       
STA FLAG+15       
STA FLAG+17       
QM9 CLC           
RTS               
;                 
QKLZU             
;                 
LDX #4            
JSR OFFSET        
JSR QINIT         
;                 
QKLZU1            
LDX <LFD          
JSR UINSE         
JSR UTNEXT        
DEC <ZAEHL        
BNE QKLZU1        
LDX #4            
;                 
QEND              
LDA #0            
STA FLAG,X        
STA FLAG+1,X      
RTS               
;                 
QKLAUF            
;                 
LDX #6            
JSR OFFSET        
JSR QINIT         
;                 
QKLAU1            
LDX <LFD          
JSR UDELE         
JSR UTNEXT        
DEC <ZAEHL        
BNE QKLAU1        
LDX #6            
JMP QEND          
;                 
QGR               
LDX #8            
JSR OFFSET        
JSR QINIT         
;                 
QGR1              
JSR UFRE          
CPX <LFD          
BCS QGR2          
LDA #133          
STA <FEHLER       
JMP QGR3          
QGR2 LDX <LFD     
JSR UINSE         
QGR3 JSR UTNEXT   
DEC <ZAEHL        
BNE QGR1          
LDX #8            
JMP QEND          
;                 
QKL               
LDX #10           
JSR OFFSET        
JSR QINIT         
QKL0              
LDX #0            
LDY <LBND         
QKL1              
LDA (<TP),Y       
CMP #" "          
BNE QKL2          
INX               
INY               
BNE QKL1          
QKL2 CPX <LFD     
BCS QKL3          
LDA #133          
STA <FEHLER       
JMP QKL4          
QKL3 LDX <LFD     
JSR UDELE         
QKL4 JSR UTNEXT   
DEC <ZAEHL        
BNE QKL0          
LDX #10           
JMP QEND          
;                 
QINIT             
;                 
STA <ZAEHL        
INC <ZAEHL        
JSR UN            
STA <LFD          
LDA ZNRL,X        
LDY ZNRH,X        
JSR TPADR         
LDY <LBND         
STY <TSPAL        
RTS