;================ 
; SCREEN-EDITOR   
; (TEIL 1 C-64)   
;                 
;14.6.1985        
;                 
ORG $8000         
;                 
;================ 
;                 
;***KONSTANTEN*** 
;                 
<MXCOL EQU 40     
<MXLIN EQU 25     
<ZAHL  EQU 4      
<SCRLC EQU 36     
<SCRLL EQU 0      
<MZEIL EQU 4      
<MSPAL EQU 4      
;                 
;***  Z-PAGE  *** 
;                 
<SP    EQU $FE    
<TP    EQU 2      
<IND   EQU 4      
;                 
<BASIS EQU 43     
<ENDE  EQU 45     
<TMEM  EQU 55     
;*** TABELLEN *** 
;                 
TAB    EQU $7FA0  
;                 
;=1=              
FLAG   EQU $7F20  
APOS   EQU $7F32  
;                 
;=2=              
ZNRL   EQU $7F40  
AZEIL  EQU $7F52  
ANFZEI EQU $7F53  
TXTBOT EQU $7F54  
MASK   EQU $7F55  
BNDS   EQU $7F56  
TABU   EQU $7F57  
;                 
;=3=              
ZNRH   EQU $7F60  
;                 
<CXIND EQU $11    
<AXIND EQU $14    
<MXIND EQU $20    
;[ZNRH-ZNRL]      
;                 
;**TEXT-SPALTEN** 
;                 
<TZEIL  EQU $6    
<TSPAL  EQU $8    
<ASPAL  EQU $9    
<ANFSPA EQU $A    
<TXTLEN EQU $B    
<LBND   EQU $C    
<RBND   EQU $D    
;                 
;**BILD-ZEIGER*** 
;                 
<SSPAL  EQU $E    
<SZEIL  EQU $F    
<XSPAL  EQU $10   
<XZEIL  EQU $11   
;                 
<SCLEN  EQU $12   
;                 
;**BILD-ZEILEN*** 
;                 
<SCTOP  EQU $13   
<SCBOT  EQU $14   
;                 
<MSKFLG EQU $15   
<BNDFLG EQU $16   
<TABFLG EQU $17   
<COLFLG EQU $18   
<TOPFLG EQU $19   
;                 
;**HILFSREGISTER* 
;                 
<MMFLAG EQU $1A   
<XREG   EQU $1B   
<YREG   EQU $1C   
<ZAEHL  EQU $1D   
<LFD    EQU $1E   
;                 
<SCRLH  EQU $1F   
<SCRLV  EQU $20   
<SCRLM  EQU $21   
;                 
<CODE   EQU $23   
<TEFLAG EQU $24   
<FEHLER EQU $25   
<ENDFLG EQU $26   
<COMFLG EQU $27   
<FNDFLG EQU $28   
;***RECHENREG.*** 
;                 
<MOR    EQU $43   
<MND    EQU $44   
;                 
<ERG    EQU $46   
;                 
<ZL     EQU $48   
<ZH     EQU $49   
<NL     EQU $4A   
<NH     EQU $4B   
<HL     EQU $4C   
<HH     EQU $4D   
;===============  
;                 
GETIN  EQU $FFE4  
;                 
;===============  
VICREG EQU 53280  
SCREEN EQU $400   
COLOR  EQU $D800  
;                 
<COL00 EQU 3      
<COL01 EQU 5      
;RAND:CYAN/GRUEN  
<COL1  EQU 1      
;COMMANDOS:WEISS  
<COL2  EQU 6      
;TEXT: BLAU       
;===============  
;*AUFRUFADRESSE*  
JMP UMULTI        
;===============  
UMULTI            
;MOR*MND=>ERG/MOR 
;(16*8)BIT        
;                 
LDY #0            
STY <ERG          
STY <ERG+1        
LDY #8            
MULTI1 ASL <ERG   
ROL <ERG+1        
ROL <MOR          
BCC MULTI2        
CLC               
LDA <ERG          
ADC <MND          
STA <ERG          
LDA <ERG+1        
ADC <MND+1        
STA <ERG+1        
BCC MULTI2        
INC <MOR          
MULTI2 DEY        
BNE MULTI1        
RTS               
;                 
UDIV              
;DIVISION         
;ZL&ZH/NL&NH      
;=> ZL&ZH         
;(16/16)BIT       
;                 
LDY #16           
LDA #0            
STA <HL           
STA <HH           
DIV2 ROL <ZL      
ROL <ZH           
ROL <HL           
ROL <HH           
SEC               
LDA <HL           
SBC <NL           
TAX               
LDA <HH           
SBC <NH           
BCC DIV3          
STA <HH           
STX <HL           
DIV3 DEY          
BNE DIV2          
ROL <ZL           
ROL <ZH           
RTS               
;                 
;UZAHL            
;SCHREIBT ZAHL    
;L=>A             
;H=>X             
;4-STELLIG        
NLT               
DFD 232,100,10,1  
NHT DFD 3,0,0,0   
;                 
UZAHL             
STX <ZH           
STA <ZL           
LDY #0            
ZLOOP             
LDA NLT,Y         
STA <NL           
LDA NHT,Y         
STA <NH           
STY <YREG         
JSR UDIV          
LDY <YREG         
CLC               
LDA <ZL           
ADC #48           
JSR USET_         
LDA <HL           
STA <ZL           
LDA <HH           
STA <ZH           
INY               
CPY #<ZAHL        
BNE ZLOOP         
RTS               
;                 
USET_             
;SCHREIBT ASCII   
;AN LFD. POSITION 
;AENDERT NUR      
;SZEIL/SSPAL      
;UNTERER RAND!!   
;==============   
;                 
STY <YREG         
LDY <SSPAL        
JSR USET          
INY               
CPY #<MXCOL       
BCC SET_1         
INC <SZEIL        
JSR UNEXT         
LDY #0            
SET_1 STY <SSPAL  
LDY <YREG         
RTS               
;                 
USADR             
;SETZT [<SP]      
;FUER SCHIRM      
;                 
LDA #0            
STA <MND+1        
LDA <SZEIL        
STA <MOR          
LDA #<MXCOL       
STA <MND          
JSR UMULTI        
LDA <ERG          
CLC               
ADC #[SCREEN      
STA <SP           
LDA <ERG+1        
ADC #]SCREEN      
STA <SP+1         
RTS               
;                 
GRENZE            
;SCBOT/SCLEN      
;BESTIMMEN        
;                 
SEC               
LDA TXTBOT        
SBC ANFZEI        
PHA               
LDA TXTBOT+<MXIND 
SBC ANFZEI+<MXIND 
TAX               
PLA               
CLC               
ADC <SCTOP        
BCC GRENZ1        
INX               
GRENZ1 CPX #0     
BEQ GRENZ2        
LDA #$FF          
GRENZ2            
STA <SCBOT        
;                 
LDA <TXTLEN       
SEC               
SBC <ANFSPA       
CLC               
ADC #<ZAHL        
BCC GRENZ3        
LDA #$FF          
GRENZ3 STA <SCLEN 
RTS               
;                 
;                 
UNEXT             
;SETZT ZEIGER     
;FUER SCHIRM AUF  
;NAECHSTE ZEILE   
;                 
LDA <SP           
CLC               
ADC #<MXCOL       
STA <SP           
BCC NEXT1         
INC <SP+1         
NEXT1 RTS         
;                 
UPREV             
;SETZT ZEIGER     
;FUER SCHIRM AUF  
;VORHERIGE ZEILE  
;                 
LDA <SP           
SEC               
SBC #<MXCOL       
STA <SP           
BCS PREV1         
DEC <SP+1         
PREV1 RTS         
;                 
USET              
;SETZT ASCII      
;AUF POSITION     
;                 
CMP #$80          
BCC SET1          
AND #$7F          
CMP #$20          
BCC SET8          
ORA #$40          
BNE SET3          
SET1 CMP #$20     
BCC SET9          
CMP #$60          
BCC SET2          
AND #$DF          
BNE SET3          
SET2 AND #$3F     
SET3 STA (<SP),Y  
RTS               
;-------------    
;"" BEI CTRL.    
;-------------    
SET8 ORA #$40     
SET9 ORA #$80     
STA (<SP),Y       
RTS               
;                 
UTSPAL            
;WANDELT SPALTE   
;AUF SCHIRM IN    
;SPALTE IM TEXT   
;                 
SEC               
LDA <SSPAL        
SBC #<ZAHL        
CLC               
ADC <ANFSPA       
TAY               
STY <TSPAL        
RTS               
;                 
UTZEIL            
;WANDELT ZEILE    
;AUF SCHIRM IN    
;ZEILE IM TEXT    
;                 
SEC               
LDA <SZEIL        
SBC <SCTOP        
CLC               
ADC ANFZEI        
STA <TZEIL        
LDA ANFZEI+<MXIND 
ADC #0            
STA <TZEIL+1      
RTS               
;                 
UTP               
;SETZT ZEIGER     
;IN TEXT          
;                 
LDA <TXTLEN       
STA <MOR          
LDA <TZEIL        
STA <MND          
LDA <TZEIL+1      
STA <MND+1        
JSR UMULTI        
LDA <ERG          
CLC               
ADC <BASIS        
STA <TP           
LDA <ERG+1        
ADC <BASIS+1      
STA <TP+1         
RTS               
;                 
UDELE             
;LOESCHT X-ZEI-   
;CHEN IM TEXT     
;AB (<TP)         
;                 
CPX #0            
BEQ DELE9         
DELE1 LDY <TSPAL  
DELE2 INY         
CPY <RBND         
BCS DELE3         
LDA (<TP),Y       
DEY               
STA (<TP),Y       
INY               
BNE DELE2         
DELE3 BNE DELE9   
DEY               
LDA #" "          
STA (<TP),Y       
DEX               
BNE DELE1         
DELE9 RTS         
;                 
UINSE             
;X-ZEICHEN NACH   
;(<TP) EINFUEGEN  
;ZEILENENDE EVTL. 
;LOESCHEN         
;                 
CPX #0            
BEQ INSE9         
INSE0             
LDY <RBND         
INSE1 DEY         
CPY <TSPAL        
BEQ INSE2         
DEY               
LDA (<TP),Y       
INY               
STA (<TP),Y       
JMP INSE1         
INSE2             
LDA (<TP),Y       
INY               
STA (<TP),Y       
DEY               
LDA #" "          
STA (<TP),Y       
DEX               
BNE INSE0         
INSE9 RTS         
;                 
UFRE              
;X =>ANZAHL DER   
;BLANKS AM ZEI-   
;LENENDE          
;BIS TSPAL !!     
LDX #0            
LDY <RBND         
FRE1 CPY <TSPAL   
BEQ FRE9          
DEY               
LDA (<TP),Y       
CMP #" "          
BNE FRE9          
INX               
BNE FRE1          
FRE9 RTS          
;                 
TXT1              
DFD "    ******"  
DFD "*****  TOP"  
DFD "  ********"  
DFD "**********",0
TXT2              
DFD "    ******"  
DFD "****  BOTT"  
DFD "OM  ******"  
DFD "**********",0
TXT3              
DFD "          "  
DFD "          "  
DFD "          "  
DFD "          ",0
TXT4              
DFD "          "  
DFD "          "  
DFD "          "  
DFD "      ",0    
;                 
TEXT              
;SCHREIBT TEXT    
;[IND] AUF DEN    
;SCHIRM BIS 0     
;AB LFD. POSITION 
;                 
LDY #0            
TEXT1             
LDA (<IND),Y      
BEQ TEXT9         
JSR USET_         
INY               
BNE TEXT1         
TEXT9 RTS         
;                 
;                 
ZEILE             
;SCHREIBT ZEILE   
;AUS TEXT AUF     
;DEN SCHIRM       
;NUR LFD. ZEILE!! 
;================ 
LDA #<ZAHL        
STA <SSPAL        
JSR UTSPAL        
ZEILE1            
LDY <TSPAL        
CPY <TXTLEN       
BCS ZEILE2        
INC <TSPAL        
LDA (<TP),Y       
BCC ZEILE3        
ZEILE2            
LDA #" "          
;-----------      
;" " AM RAND      
;-----------      
ZEILE3 LDY <SSPAL 
JSR USET          
INY               
STY <SSPAL        
CPY #<MXCOL       
BCC ZEILE1        
RTS               
;                 
UZEILE            
;SCHREIBT ZEILE   
;(AKKU)           
;INITIALISIERT    
;ALLE ZEIGER      
;                 
STA <SZEIL        
JSR USADR         
JSR UTZEIL        
JSR UTP           
LDA #0            
STA <SSPAL        
LDA <TZEIL+1      
CMP TXTBOT+<MXIND 
BCC ZLE3          
BNE ZLE2          
LDA <TZEIL        
CMP TXTBOT        
BCC ZLE3          
BNE ZLE2          
LDA #[TXT2        
STA <IND          
LDA #]TXT2        
STA <IND+1        
JMP TEXT          
ZLE2 LDA #[TXT3   
STA <IND          
LDA #]TXT3        
STA <IND+1        
JMP TEXT          
ZLE3 JSR UZNR     
JMP ZEILE         
;                 
UBILD             
;BILDAUFBAU       
;KOMPLETT OHNE    
;KOPF. XREG.      
;ENTHAELT WERT    
;FUER 1. ZEILE    
;                 
STX <SCTOP        
LDA #0            
STA <TOPFLG       
LDA ANFZEI        
ORA ANFZEI+<MXIND 
BNE BILD0         
INX               
STX <SCTOP        
LDA #0            
DEX               
STX <TOPFLG       
JSR UCSPR         
LDA #[TXT1        
STA <IND          
LDA #]TXT1        
STA <IND+1        
JSR TEXT          
BILD0 JSR GRENZE  
LDA <SCTOP        
STA <ZAEHL        
BILD1             
JSR UZEILE        
INC <ZAEHL        
LDA <ZAEHL        
CMP #<MXLIN       
BNE BILD1         
RTS               
;                 
UCOLOR            
;INITIALISIERT    
;FARBEN FUER      
;SCHIRM           
;                 
LDA #<COL00       
STA VICREG        
LDA #<COL01       
STA VICREG+1      
LDA #[COLOR       
STA <IND          
LDA #]COLOR       
STA <IND+1        
LDX #1            
LDY #<MXCOL-1     
LDA #<COL1        
COLOR1            
STA (<IND),Y      
DEY               
BPL COLOR1        
;                 
COLOR2            
LDA <IND          
CLC               
ADC #<MXCOL       
STA <IND          
BCC COLOR3        
INC <IND+1        
COLOR3            
LDY #<MXCOL-1     
LDA #<COL2        
COLOR4            
STA (<IND),Y      
DEY               
CPY #<ZAHL        
BCS COLOR4        
LDA #<COL1        
COLOR5            
STA (<IND),Y      
DEY               
BPL COLOR5        
INX               
CPX #<MXLIN       
BNE COLOR2        
RTS               
;                 
UCSPR             
;SPRUNG AN BILD-  
;SCHIRMPOSITION   
;SPALTE=>A        
;ZEILE=>X         
;KEINE TESTS      
;===========      
;                 
STA <SSPAL        
STX <SZEIL        
JMP USADR         
;                 
UCURSR            
;CURSOR SETZEN    
;UND LOESCHEN     
;AN LFD. POS.     
;                 
JSR USADR         
LDY <SSPAL        
LDA (<SP),Y       
EOR #$80          
STA (<SP),Y       
RTS               
;                 
UP                
;                 
LDA <SZEIL        
BEQ UP1           
DEC <SZEIL        
JMP UPREV         
UP1 LDX #<MXLIN   
DEX               
LDA <SSPAL        
JMP UCSPR         
;                 
DOWN              
;                 
INC <SZEIL        
LDA <SZEIL        
CMP #<MXLIN       
BEQ DOWN1         
JMP UNEXT         
DOWN1 LDX #0      
LDA <SSPAL        
JMP UCSPR         
;                 
LEFT              
;                 
LDA <SSPAL        
BEQ LEFT1         
DEC <SSPAL        
RTS               
LEFT1 LDX #<MXCOL 
DEX               
STX <SSPAL        
RTS               
;                 
RIGHT             
;                 
INC <SSPAL        
LDA <SSPAL        
CMP #<MXCOL       
BNE RIGHT1        
LDX #0            
STX <SSPAL        
RIGHT1 RTS        
;                 
RETRN             
;                 
JSR UTEST         
BCC RETRN1        
BIT <TEFLAG       
BMI UCRLF         
RETRN1 LDA #0     
STA <SSPAL        
JMP DOWN          
;                 
UCRLF             
JSR UAPOS         
LDA APOS          
BEQ UCRLF1        
JSR CRLF          
JSR UMOVE         
UCRLF1 JMP UNPOS  
;                 
CRLF              
;ASPAL AUF DEN    
;NAECHSTEN        
;ZEILENBEGINN     
;                 
LDY <LBND         
STY <ASPAL        
LDY AZEIL+<MXIND  
LDX AZEIL         
INX               
BNE CRLF1         
INY               
CRLF1 CPX TXTBOT  
BNE CRLF2         
CPY TXTBOT        
BNE CRLF2         
LDX #0            
LDY #0            
CRLF2 STX AZEIL   
STY AZEIL+<MXIND  
RTS               
;                 
SCNCLR            
;                 
JSR HOME1         
LDA #[TXT4        
STA <IND          
LDA #]TXT4        
STA <IND+1        
JSR TEXT          
LDA #255          
STA <COMFLG       
;                 
;                 
HOME              
;                 
LDA <SSPAL        
ORA <SZEIL        
BNE HOME1         
LDA #<SCRLC       
LDX #<SCRLL       
JMP UCSPR         
HOME1 LDA #0      
TAX               
JMP UCSPR         
;                 
ZEICH             
;SETZT ZEICHEN    
;VON TASTATUR     
;AN LFD. POS.     
;UND IN TEXT,     
;FALLS MOEGLICH   
;                 
STA <LFD          
LDY <SSPAL        
JSR UTEST         
BCC ZEICH1        
;*****IN TEXT     
LDA <LFD          
JSR USET          
JSR UTZEIL        
JSR UTSPAL        
JSR UTP           
LDA <LFD          
LDY <TSPAL        
STA (<TP),Y       
BIT <TEFLAG       
BPL ZEICHQ        
;**TEXT ENTRY**   
INY               
CPY <RBND         
BEQ ZEICH0        
LDY <SSPAL        
CPY #<MXCOL-1     
BNE ZEICHQ        
JSR QRIGHT        
ZEICHQ JMP RIGHT  
;                 
ZEICH0 JMP RETRN  
;                 
ZEICH1            
LDA <SZEIL        
BEQ ZEICH9        
CPY #<ZAHL        
BCS ZEICH4        
CMP <TOPFLG       
BEQ ZEICH2        
CMP <SCTOP        
BCC ZEICHA        
CMP <SCBOT        
BCC ZEICH2        
ZEICHA RTS        
;*****LINE COMM.  
;                 
ZEICH2 LDA <LFD   
JSR USET          
INY               
CPY #<ZAHL        
BCS ZEICH3        
LDA #" "          
JSR USET          
ZEICH3            
JMP RIGHT         
;                 
ZEICH4 CPY <SCLEN 
BCS ZEICHX        
CMP <MSKFLG       
BNE ZEICH5        
;****MASKE        
LDA MASK          
LDX MASK+<MXIND   
JMP ZEICH7        
ZEICH5 CMP <BNDFLG
BNE ZEICH6        
;****BNDS         
LDA BNDS          
LDX BNDS+<MXIND   
JMP ZEICH7        
ZEICH6 CMP <TABFLG
BNE ZEICHX        
;****TABS         
;                 
LDA TABU          
LDX TABU+<MXIND   
;                 
ZEICH7 STA <TP    
STX <TP+1         
LDA <LFD          
JSR USET          
JSR UTSPAL        
LDA <LFD          
LDY <TSPAL        
STA (<TP),Y       
JMP RIGHT         
;                 
ZEICH9 LDY <SSPAL 
CPY #<SCRLC       
BCC ZEI10         
;**SCROLL         
LDA <LFD          
JSR USET          
JMP RIGHT         
;                 
ZEI10             
;**COMMAND        
LDA <COMFLG       
BNE ZEI11         
JSR SCNCLR        
LDY <SSPAL        
ZEI11 LDA <LFD    
JSR USET          
JMP RIGHT         
;                 
ZEICHX            
;***ILLEGAL       
RTS               
;                 
UTEST             
;PRUEFT, OB       
;POSITION IM      
;TEXT             
;C=1 => JA        
;                 
LDA <SSPAL        
CMP #<ZAHL        
BCC TEST1         
CMP <SCLEN        
BCS TEST1         
LDA <SZEIL        
CMP <SCTOP        
BCC TEST1         
CMP <SCBOT        
BCS TEST1         
;IM BEREICH:      
SEC               
RTS               
TEST1 CLC         
RTS               
;                 
UONSCR            
;TESTET,OB DIE    
;ALTE POSITION    
;AUF LFD. BILD    
;IST ,            
;                 
;SPALTE =>A       
;ZEILE  =>X       
;Y=>CODE FUER     
;  AUSSERHALB     
;                 
;C=1 => JA        
;                 
LDY #0            
SEC               
LDA <ASPAL        
SBC <ANFSPA       
BCC ONSCR1        
CLC               
ADC #<ZAHL        
BCS ONSCR1        
CMP #<MXCOL       
BCC ONSCR2        
ONSCR1 INY        
ONSCR2 STA <LFD   
SEC               
LDA AZEIL         
SBC ANFZEI        
TAX               
LDA AZEIL+<MXIND  
SBC ANFZEI+<MXIND 
BCC ONSCR3        
BNE ONSCR3        
TXA               
CLC               
ADC <SCTOP        
BCS ONSCR3        
CMP #<MXLIN       
BCC ONSCR4        
ONSCR3 INY        
INY               
ONSCR4 CPY #0     
BNE ONSCR5        
TAX               
LDA <LFD          
SEC               
RTS               
ONSCR5            
;                 
;**AUSSERHALB     
;                 
LDA #0            
TAX               
CLC               
RTS               
;                 
UMOVE             
;SETZT ANFZEI     
;UND ANFSPA FUER  
;TEXTPOSITION     
;                 
JSR UONSCR        
TYA               
AND #1            
BEQ MOVE2         
SEC               
LDA <ASPAL        
SBC #<MSPAL       
BCS MOVE1         
LDA #0            
MOVE1             
STA <ANFSPA       
;                 
MOVE2 TYA         
AND #2            
BEQ MOVE4         
SEC               
LDA AZEIL         
SBC #<MZEIL       
TAX               
LDA AZEIL+<MXIND  
SBC #0            
BCS MOVE3         
LDA #0            
TAX               
MOVE3             
STX ANFZEI        
STA ANFZEI+<MXIND 
;                 
MOVE4             
RTS               
;                 
UAPOS             
;APOS = 255:      
;CURSORPOSITION   
;STEHT IN ASPAL   
;UND AZEIL(L/H)   
;APOS = 0:        
;CURSOR WAR       
;NICHT IM TEXT    
;                 
;BILD KOMPLETT    
;AUSWERTEN!       
;A<>0, FALLS FIND 
JSR UTEST         
BCC APOS1         
JSR UTZEIL        
JSR UTSPAL        
JSR UTP           
LDA <TSPAL        
STA <ASPAL        
LDA <TZEIL        
STA AZEIL         
LDA <TZEIL+1      
STA AZEIL+<MXIND  
LDA #255          
JMP APOS2         
APOS1             
LDA <SZEIL        
STA <XZEIL        
LDA #0            
STA <XSPAL        
APOS2 STA APOS    
LDA #0            
STA <FEHLER       
STA <FNDFLG       
;=============    
;SPRUNG  NACH     
;*** U1 ***       
;=============    
NOP               
NOP               
NOP               
LDA <FNDFLG       
RTS               
;                 
UNPOS             
;DER CURSOR       
;SPRINGT AUF      
;ALTE TEXTPOS.,   
;FALLS DIESE      
;NOCH AUF DEM     
;NEUEN BILD       
;IST. SONST AN    
;DIE LINKE        
;OBERE ECKE       
;                 
;BIDLDAUFBAU      
;===========      
LDA #0            
STA <COMFLG       
;============     
;SPRUNG  NACH     
;*** UTOP ***     
;============     
NOP               
NOP               
NOP               
JSR UBILD         
LDA APOS          
BEQ NPOS1         
JSR UONSCR        
JMP UCSPR         
NPOS1 LDA <XSPAL  
LDX <XZEIL        
JMP UCSPR         
;                 
SRETRN            
;SHIFT RETURN     
;FALLS NICHT FIND-
;BEFEHL GEFUNDEN  
JSR UAPOS         
BNE SRETR9        
BIT <TEFLAG       
BPL SRETR9        
LDA APOS          
BEQ SRETR9        
LDA TABU          
STA <IND          
LDA TABU+<MXIND   
STA <IND+1        
LDY <ASPAL        
SRETR1 INY        
CPY <RBND         
BCS SRETR2        
LDA (<IND),Y      
CMP #" "          
BEQ SRETR1        
STY <ASPAL        
JMP SRETR3        
SRETR2            
JSR CRLF          
SRETR3            
JSR UMOVE         
SRETR9            
JMP UNPOS         
;                 
QUP               
JSR UAPOS         
SEC               
LDA ANFZEI        
SBC <SCRLV        
TAX               
LDA ANFZEI+<MXIND 
SBC #0            
BCS QUP1          
LDA #0            
TAX               
QUP1              
STA ANFZEI+<MXIND 
STX ANFZEI        
JMP UNPOS         
;                 
QDOWN             
JSR UAPOS         
CLC               
LDA ANFZEI        
ADC <SCRLV        
TAX               
LDA ANFZEI+<MXIND 
ADC #0            
CMP TXTBOT+<MXIND 
BCC QDOWN1        
BNE QDOWN0        
CPX TXTBOT        
BCC QDOWN1        
QDOWN0            
LDX TXTBOT        
LDA TXTBOT+<MXIND 
QDOWN1            
STX ANFZEI        
STA ANFZEI+<MXIND 
JMP UNPOS         
;                 
QLEFT             
JSR UAPOS         
SEC               
LDA <ANFSPA       
SBC <SCRLH        
BCS QLEFT1        
LDA #0            
QLEFT1 STA <ANFSPA
JMP UNPOS         
;                 
QRIGHT            
JSR UAPOS         
CLC               
LDA <ANFSPA       
ADC <SCRLH        
BCS QRGHT1        
CMP <TXTLEN       
BCC QRGHT2        
QRGHT1 LDX <TXTLEN
DEX               
TXA               
QRGHT2            
STA <ANFSPA       
JMP UNPOS         
;                 
;                 
FUNKT             
;WARTE AUF EINE   
;TASTE. SETZE     
;ZEICHEN ODER     
;FUEHRE EINE      
;FUNKTION AUS     
;                 
JSR UCURSR        
FUNKT1            
JSR GETIN         
BEQ FUNKT1        
STA <LFD          
JSR UCURSR        
LDA <LFD          
;                 
LDX #15           
;**LAENGE         
;**KEYTAB         
FUNKT2            
CMP KEYTAB,X      
BEQ FUNKT3        
DEX               
BPL FUNKT2        
JMP ZEICH         
FUNKT3            
TXA               
ASL               
TAX               
LDA SPRTAB,X      
STA <IND          
LDA SPRTAB+1,X    
STA <IND+1        
JMP (<IND)        
KEYTAB            
;TABELLE ALLER    
;ASCII-CODES      
;DER FUNKTIONS-   
;TASTEN;          
DFD 141,13,20,148 
DFD "“‘?…†‡ˆ‰Š"
;                 
SPRTAB            
DFD SRETRN,RETRN  
DFD DELETE,INSERT 
DFD HOME,SCNCLR   
DFD UP,DOWN       
DFD LEFT,RIGHT    
DFD QUP,QDOWN     
DFD QLEFT,QRIGHT  
DFD QUP,QDOWN     
DELETE            
;                 
JSR UTEST         
BCC DELETX        
LDY <SSPAL        
CPY #<ZAHL        
BEQ DELETX        
DEY               
STY <SSPAL        
JSR UAXPOS        
LDA <TSPAL        
CMP <RBND         
BCS DELETX        
CMP <LBND         
BCC DELETX        
LDX #1            
JSR UDELE         
JMP UNXPOS        
DELETX RTS        
;                 
UAXPOS            
;MERKT CURSOR     
;FUER ZEILEN-     
;KORREKTUR        
LDA <SSPAL        
STA <XSPAL        
LDA <SZEIL        
STA <XZEIL        
JSR UTZEIL        
JSR UTSPAL        
JMP UTP           
;                 
UNXPOS            
;NACH ZEILEN-     
;KORREKTUR        
;                 
LDA <XZEIL        
JSR ZEILE         
LDA <XSPAL        
LDX <XZEIL        
JMP UCSPR         
;                 
INSERT            
;                 
JSR UTEST         
BCC INSER1        
JSR UAXPOS        
LDA <TSPAL        
CMP <LBND         
BCC INSER1        
CMP <RBND         
BCS INSER1        
JSR UFRE          
TXA               
BEQ INSER1        
LDX #1            
JSR UINSE         
JMP UNXPOS        
INSER1 RTS        
;                 
UZNR              
;SCHREIBT ZNR     
;ODER ZEILEN-     
;BEFEHL FUER      
;<TZEIL           
;                 
LDA #0            
STA <MMFLAG       
LDX #<CXIND       
ZNR1 LDA FLAG,X   
BEQ ZNR4          
LDA ZNRL,X        
CMP <TZEIL        
BNE ZNR4          
LDA ZNRH,X        
CMP <TZEIL+1      
BNE ZNR4          
LDA <MMFLAG       
BNE ZNR45         
JSR UMWNDL        
LDA CODE,Y        
JSR USET_         
LDA FLAG,X        
BMI ZNR2          
LDA #" "          
BNE ZNR3          
ZNR2 LDA CODE,Y   
ZNR3 JSR USET_    
LDA #" "          
JSR USET_         
LDA #" "          
JSR USET_         
INC <MMFLAG       
ZNR45 LDA #0      
STA FLAG,X        
;                 
ZNR4 DEX          
BPL ZNR1          
;                 
LDA <MMFLAG       
BNE ZNR5          
LDA <TZEIL        
LDX <TZEIL+1      
JSR UZAHL         
ZNR5 RTS          
;                 
UMWNDL            
;Y<= INDEX CODE-  
;TABELLE AUS X    
;                 
CPX #14           
BCS UMWND1        
TXA               
LSR               
TAY               
RTS               
UMWND1 CPX #16    
BCS UMWND2        
LDA FLAG,X        
AND #127          
CLC               
ADC #6            
TAY               
RTS               
UMWND2            
BNE UMWND3        
LDY #9            
RTS               
UMWND3            
LDA FLAG,X        
CLC               
ADC #9            
TAY               
RTS               
;                 
;TABELLE ALLER    
;LINE-COMMANDS    
;                 
CODE              
DFD "DR)(><OMCIAB"