;=================
;INITIALISIERUNG  
; PASCALCOMPILER  
; >>   C-64   <<  
;                 
;   24.11.1985    
;=================
ORG 5611          
;(=START)         
;-----------------
TRENN   EQU $6000 
;OBJECT<->SOURCE  
EDITOR  EQU $7F00 
;ENDE OBJECT      
;                 
<SELECT EQU 1     
<P1     EQU 47    
<P2     EQU 49    
;                 
BUFFER  EQU 907   
RETURN  EQU 16421 
PC      EQU 16497 
;                 
MENUE   EQU 40682 
;=RETURN IM EDITOR
COMPILE EQU $4000 
;-----------------
MEMTOP  EQU $FF99 
MEMBOT  EQU $FF9C 
;-----------------
START             
DFD 826,8,BOOT,22 
;STACK            
;LDC BOOT         
;SYS              
;-----------------
BOOT              
;SYSTEMSTART:     
;BUFFER KOPIEREN  
;EDITOR KOPIEREN  
;MEMBOT:=TRENN    
;<TMEM :=TRENN    
;MEMTOP:=EDITOR   
;PC    :=START    
;==>RETURN        
LDX #LAST-TEMPFLG 
BOOT0             
LDA TEMPFLG,X     
STA BUFFER,X      
DEX               
BPL BOOT0         
;                 
;$2000..$3FFF =>  
;$E000..$FFFF     
;                 
SEI               
LDA <SELECT       
AND #%11111000    
STA <SELECT       
LDA #$20          
STA <P1+1         
LDA #$E0          
STA <P2+1         
LDY #0            
STY <P1           
STY <P2           
LDX #$20          
;$20 SEITEN       
BOOT2             
LDA (<P1),Y       
STA (<P2),Y       
INY               
BNE BOOT2         
INC <P1+1         
INC <P2+1         
DEX               
BNE BOOT2         
LDA <SELECT       
ORA #%00000111    
STA <SELECT       
CLI               
;                 
LDX #[TRENN       
LDY #]TRENN       
CLC               
JSR MEMBOT        
LDX #[EDITOR      
LDY #]EDITOR      
JSR MEMTOP        
LDA #[START       
STA PC            
LDA #]START       
STA PC+1          
JMP RETURN        
;-----------------
;DIE FOLGENDEN    
;BYTES WERDEN IN  
;DEN CASSETTEN-   
;PUFFER KOPIERT:  
;(907..985)       
;-----------------
TEMPFLG DFD 0     
;> 0,FALLS EINE   
;TEMPORAERE DATEI 
;ERZEUGT WURDE    
RSMEFLG DFD 0     
;=0, FALLS RESUME 
;GESPERRT (EDITOR)
PNT               
;BASIC POINTER    
DFD 1,8           
DFD START         
DFD START         
DFD START         
DFD EDITOR        
DFD EDITOR        
DFD EDITOR        
;-----------------
;                 
COMP              
;<- EINSPRUNG     
;   ZUM COMPILER  
JSR 935;USWAP     
JMP COMPILE       
;                 
RET               
;-> RUECKKEHR     
;   VOM COMPILER  
JSR 935;USWAP     
JMP MENUE         
;                 
USWAP             
;TAUSCHE BLOECKE  
;$4000...$9FFF <=>
;$A000...$FFFF    
SEI               
LDA <SELECT       
AND #%11111000    
STA <SELECT       
LDA #$40          
STA <P1+1         
LDA #$A0          
STA <P2+1         
LDY #0            
STY <P1           
STY <P2           
LDX #$60          
;$60 SEITEN       
USWAP1            
LDA (<P1),Y       
PHA               
LDA (<P2),Y       
STA (<P1),Y       
PLA               
STA (<P2),Y       
INY               
BNE USWAP1        
INC <P1+1         
INC <P2+1         
DEX               
BNE USWAP1        
LDA <SELECT       
ORA #%00000111    
STA <SELECT       
CLI               
RTS               
LAST