PROGRAM INF51(INPUT,OUTPUT);                                
 CONST MAXN=1000;                                           
 TYPE TINDEX=1..MAXN;                                       
 VAR L:ARRAY[TINDEX]OF INTEGER;                             
       (*LISTE DER ERSTEN N ELEMENTE DER MENGE:           *)
       (*A[I]<A[I+1] FUER 1 <=I< LEND                     *)
     LZWEI,LDREI,LEND,N:TINDEX;                             
       (*LZWEI INDIZIERT DAS LETZTE ELEMENT, DAS NOCH     *)
       (*NICHT UEBER 2*X+1 ENTICKELT WURDE, DAS HEISST:   *)
       (*I<=LZWEI  <=> L[I]*2+1 HAT INDEX > LEND          *)
       (*ANALOG FUER LDREI:                               *)
       (*I<=LDREI  <=> L[I]*3+1 HAT INDEX > LEND          *)
       (*LEND INDIZIERT DIE LETZTE BELEGTE POSITION       *)
       (*ANZAHL DER BIS JETZT ERZEUGTEN ELEMENTE          *)
     NZWEI,NDREI:INTEGER;                                   
       (*NZWEI = L[LZWEI]*2+1                             *)
       (*NDREI = L[LDREI]*2+1                             *)
BEGIN                                                       
 READLN(N);                                                 
                                                            
 (*BEGINNE MIT DEM ELEMENT 1. INITIALISIERE TABELLENZEIGER*)
 LZWEI:=1;LDREI:=1;LEND:=1;                                 
 L[1]:=1;NZWEI:=3;NDREI:=4;                                 
                                                            
 WHILE LEND<N DO (*SOLANGE NOCH ELEMENTE ZU ERZEUGEN*)      
 BEGIN                                                      
  IF NZWEI<=NDREI THEN                                      
   BEGIN (*ENTWICKELE UEBER 2*X+1*)                         
    IF NZWEI=NDREI THEN(*ELEMENT DOPPELT VORHANDEN*)        
      BEGIN LDREI:=LDREI+1;NDREI:=L[LDREI]*3+1 END;         
    LZWEI:=LZWEI+1;(*DIESES ELEMENT DARF NICHT MEHR UEBER *)
                   (*2*X+1 ENTWICKELT WERDEN              *)
                   (*ZEIGE AUF DAS NAECHST GROESSERE ELEM.*)
    LEND:=LEND+1;L[LEND]:=NZWEI;(*TRAGE NEUES ELEMENT EIN *)
    NZWEI:=L[LZWEI]*2+1 (*KORRIGIERE ERGEBNIS             *)
   END                                                      
  ELSE                                                      
   BEGIN (*ANALOG FUER ENTWICKLUNG UEBER 3*X+1*)            
    LDREI:=LDREI+1;LEND:=LEND+1;L[LEND]:=NDREI;             
    NDREI:=L[LDREI]*3+1                                     
   END                                                      
  END;                                                      
                                                            
 (*DRUCKE ELEMENTE*)                                        
 FOR LEND:=1 TO N DO                                        
  BEGIN NZWEI:=L[LEND];                                     
   IF NZWEI<10 THEN WRITE(" ");                             
   IF NZWEI<100 THEN WRITE(" ");                            
   WRITE(NZWEI);                                            
  END;                                                      
 WRITELN;WRITELN;                                           
END.